Opret et Gantt-diagram i Power BI (eksempelvisning)

Opret et Gantt-diagram for at få vist opgavevarighed, fremdrift og milepæle på en tidslinje. Denne artikel indeholder eksempeldata og installationsvejledninger. Du kan se formateringsindstillinger og -begrænsninger under Gantt-visualisering i Power BI.

Vigtig

Gantt-visualiseringen er en prøveversion. Du kan få oplysninger om eksempelstatus under Vis visualiseringer.

Skærmbillede af en Gantt-visualisering med projektopgaver grupperet efter fase fra januar til april 2025, statuslinjer, milepælsmærker og ruden Formatér visualisering.

Forudsætninger

  • Installér Power BI Desktop for at bruge TMDL-eksempelscriptet.
  • Start med en tom rapport til eksemplet, eller brug dine egne opgavedata.

Kom i gang med eksempeldata

Brug dette TMDL-script (Tabular Model Definition Language) til at oprette en eksempeltabel med 13 softwareprojektopgaver, der er grupperet i Planlægning, Udvikling, Test og Installation. Scriptet indeholder start- og slutdatoer, status, afhængigheder og målinger for Gantt-visualiseringen. Du behøver ikke en ekstern datakilde.

Alarm

Scriptet createOrReplace erstatter alle eksisterende tabeller, der er navngivet Gantt software project i din semantiske model. Brug en tom rapport for at undgå at erstatte dine data.

  1. Åbn en tom rapport i Power BI Desktop.
  2. Åbn TMDL-visningen, og indsæt følgende script på en scriptfane.
  3. Vælg Anvend.
  4. Opdater den semantiske model for at udfylde den beregnede tabel.

Du kan få flere oplysninger i Brug TMDL-visning i Power BI.

createOrReplace

	/// Sample data of software-project tasks (start, end, progress, dependencies) for Gantt visual demos.
	table 'Gantt software project'

		/// Marker measure used for the Gantt chart demo.
		measure FabCon = DATE(2025, 3, 15)
			formatString: General Date

		/// The start date of the task, rolling up to start date of category or entire project.
		measure 'Start date' = MIN('Gantt software project'[Start])
			formatString: dd mmm yyyy

			annotation PBI_FormatHint = {"isCustom":true}

		/// For the task to show as a milestone, the end date should return blank.
		measure 'End date' =
				IF(
					[Start date] == MAX('Gantt software project'[End]),
					BLANK(),
					MAX('Gantt software project'[End])
				)
			formatString: dd mmm yyyy

			annotation PBI_FormatHint = {"isCustom":true}

		/// The percentage of the task that is completed.
		measure 'Progress %' =
				DIVIDE(
					AVERAGE('Gantt software project'[Progress]),
					100
				)
			formatString: #,0%;-#,0%;#,0%

		column 'Task ID'
			formatString: 0
			summarizeBy: count
			isNameInferred
			sourceColumn: [Task ID]

			annotation SummarizationSetBy = Automatic

		column Task
			summarizeBy: none
			isNameInferred
			sourceColumn: [Task]

			annotation SummarizationSetBy = Automatic

		column Category
			summarizeBy: none
			isNameInferred
			sourceColumn: [Category]

			annotation SummarizationSetBy = Automatic

		column Start
			formatString: General Date
			summarizeBy: none
			isNameInferred
			sourceColumn: [Start]

			annotation SummarizationSetBy = Automatic

		column End
			formatString: General Date
			summarizeBy: none
			isNameInferred
			sourceColumn: [End]

			annotation SummarizationSetBy = Automatic

		column Progress
			formatString: 0
			summarizeBy: sum
			isNameInferred
			sourceColumn: [Progress]

			annotation SummarizationSetBy = Automatic

		column Dependencies
			summarizeBy: none
			isNameInferred
			sourceColumn: [Dependencies]

			annotation SummarizationSetBy = Automatic

		partition 'Gantt software project' = calculated
			mode: import
			source = ```
					VAR TaskTable =
					    {
					        ( 1, "Project Kickoff", "Planning", DATE(2025,1,6), DATE(2025,1,6), 100, "" ),
					        ( 2, "Requirements Gathering", "Planning", DATE(2025,1,7), DATE(2025,1,17), 100, "1" ),
					        ( 3, "Technical Specification", "Planning", DATE(2025,1,13), DATE(2025,1,24), 75, "2" ),
					        ( 4, "Architecture Review", "Planning", DATE(2025,1,27), DATE(2025,1,27), 0, "3" ),
					        ( 5, "Database Design", "Development", DATE(2025,1,28), DATE(2025,2,7), 50, "4" ),
					        ( 6, "API Development", "Development", DATE(2025,2,3), DATE(2025,2,21), 25, "5" ),
					        ( 7, "Frontend Development", "Development", DATE(2025,2,10), DATE(2025,2,28), 10, "5" ),
					        ( 8, "Integration", "Development", DATE(2025,2,24), DATE(2025,3,7), 0, "6,7" ),
					        ( 9, "Unit Testing", "Testing", DATE(2025,2,17), DATE(2025,3,7), 0, "6" ),
					        ( 10, "Integration Testing", "Testing", DATE(2025,3,10), DATE(2025,3,21), 0, "8,9" ),
					        ( 11, "User Acceptance Testing", "Testing", DATE(2025,3,24), DATE(2025,4,4), 0, "10" ),
					        ( 12, "Production Deployment", "Deployment", DATE(2025,4,7), DATE(2025,4,11), 0, "11" ),
					        ( 13, "Go Live", "Deployment", DATE(2025,4,14), DATE(2025,4,14), 0, "12" )
					    }
					RETURN
					    SELECTCOLUMNS(
					        TaskTable,
					        "Task ID", [Value1],
					        "Task", [Value2],
					        "Category", [Value3],
					        "Start", [Value4],
					        "End", [Value5],
					        "Progress", [Value6],
					        "Dependencies", [Value7]
					    )
					```

		annotation PBI_Id = 657a62e9dd4d4163b3e3542df33e4502

Opret et Gantt-diagram

Det eneste obligatoriske felt er navnet på hver række eller opgave. Tilføj andre felter for at få vist datoer, status, grupper og opgavedetaljer.

  1. Mens der ikke er valgt noget på rapportlærredet, skal du vælge Gantt-visualiseringen i ruden Visualiseringer .
  2. I ruden Opret visualisering skal du tilføje det felt, der indeholder mærkaten for hver række eller opgave.
  3. Føj felter til Start og Slut for at få vist varighedslinjer. Angiv en startdato for milepæle, og lad Slut være tom.
  4. Du kan også tilføje en måling, der beregner den fuldførte procentdel for hver række for at få vist status på søjlerne.
  5. Tilføj op til tre niveauer af kategorier for at gruppere opgaver.
  6. Tilføj kolonner for opgavedetaljer og yderligere felter med værktøjstip i ruden Opret visualisering .

Hvis du bruger eksempeltabellen, skal du tildele disse felter fra Gantt software project:

  1. Bruges Task som mærkat for hver række.
  2. Føj målingen Start date til Start og målingen End date til Slut.
  3. Bruges Progress % til at få vist status på søjlerne.
  4. Bruges Category til at gruppere opgaver.
  5. Du kan også tilføje Progress % som en detaljekolonne og som feltet for rækker>Datamærkater i ruden Formatér visualisering .

Målingen for eksemplet End date returnerer tom, når en opgaves start- og slutdatoer stemmer overens, så disse opgaver vises som milepæle. Målingen Progress % beregner gennemsnittet af opgavefremdriften, hvilket giver hver opgave samme vægt i stedet for vægtning efter varighed.