Azure Kubernetes Service (AKS) für erweiterte Zonen

Sie verwenden den extendedLocation-Parameter, um die gewünschte erweiterte Azure-Zone in einer ARM-Vorlage anzugeben.

"extendedLocation": {
    "name": "<extended-zone-id>",
    "type": "EdgeZone",
},

Die folgende ARM-Vorlage stellt einen neuen Cluster in einer erweiterten Azure-Zone bereit.

{
  "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentTemplate.json#",
  "contentVersion": "1.0.0.0",
  "metadata": {
    "_generator": {
      "name": "bicep",
      "version": "0.9.1.41621",
      "templateHash": "2637152180661081755"
    }
  },
  "parameters": {
    "clusterName": {
      "type": "string",
      "defaultValue": "myAKSCluster",
      "metadata": {
        "description": "The name of the Managed Cluster resource."
      }
    },
    "location": {
      "type": "string",
      "defaultValue": "[resourceGroup().location]",
      "metadata": {
        "description": "The location of the Managed Cluster resource."
      }
    },
    "edgeZoneName": {
      "type": "String",
      "metadata": {
        "description": "The name of the Azure Extended Zone"
      }
    },
    "dnsPrefix": {
      "type": "string",
      "metadata": {
        "description": "Optional DNS prefix to use with hosted Kubernetes API server FQDN."
      }
    },
    "osDiskSizeGB": {
      "type": "int",
      "defaultValue": 0,
      "maxValue": 1023,
      "minValue": 0,
      "metadata": {
        "description": "Disk size (in GB) to provision for each of the agent pool nodes. This value ranges from 0 to 1023. Specifying 0 will apply the default disk size for that agentVMSize."
      }
    },
    "agentCount": {
      "type": "int",
      "defaultValue": 3,
      "maxValue": 50,
      "minValue": 1,
      "metadata": {
        "description": "The number of nodes for the cluster."
      }
    },
    "agentVMSize": {
      "type": "string",
      "defaultValue": "standard_d2s_v3",
      "metadata": {
        "description": "The size of the Virtual Machine."
      }
    },
    "linuxAdminUsername": {
      "type": "string",
      "metadata": {
        "description": "User name for the Linux Virtual Machines."
      }
    },
    "sshRSAPublicKey": {
      "type": "string",
      "metadata": {
        "description": "Configure all linux machines with the SSH RSA public key string. Your key should include three parts, for example 'ssh-rsa AAAAB...snip...UcyupgH azureuser@linuxvm'"
      }
    }
  },
  "resources": [
    {
      "type": "Microsoft.ContainerService/managedClusters",
      "apiVersion": "2024-09-01",
      "name": "[parameters('clusterName')]",
      "location": "[parameters('location')]",
      "extendedLocation": {
        "name": "[parameters('edgeZoneName')]",
        "type": "EdgeZone"
      },
      "identity": {
        "type": "SystemAssigned"
      },
      "properties": {
        "dnsPrefix": "[parameters('dnsPrefix')]",
        "agentPoolProfiles": [
          {
            "name": "agentpool",
            "osDiskSizeGB": "[parameters('osDiskSizeGB')]",
            "count": "[parameters('agentCount')]",
            "vmSize": "[parameters('agentVMSize')]",
            "osType": "Linux",
            "mode": "System"
          }
        ],
        "linuxProfile": {
          "adminUsername": "[parameters('linuxAdminUsername')]",
          "ssh": {
            "publicKeys": [
              {
                "keyData": "[parameters('sshRSAPublicKey')]"
              }
            ]
          }
        }
      }
    }
  ],
  "outputs": {
    "controlPlaneFQDN": {
      "type": "string",
      "value": "[reference(resourceId('Microsoft.ContainerService/managedClusters', parameters('clusterName'))).fqdn]"
    }
  }
}

Wenn Sie mit ARM-Vorlagen nicht vertraut sind, lesen Sie das Tutorial zum Bereitstellen einer lokalen ARM-Vorlage.

Bereiten sie die folgenden Variablen vor, um einen AKS-Cluster mithilfe der Azure CLI in einer erweiterten Azure-Zone bereitzustellen:

SUBSCRIPTION="<your-subscription>"
RG_NAME="<your-resource-group>"
CLUSTER_NAME="<your-cluster>"
EXTENDED_ZONE_NAME="<extended-zone-id>"
LOCATION="<parent-region>" # Ensure this location corresponds to the parent region for your targeted Azure Extended Zone

Nachdem Sie sichergestellt haben, dass Sie angemeldet sind und das richtige Abonnement verwenden, stellen Sie mithilfe von az aks create den Cluster bereit, indem Sie die erweiterte Microsoft Azure-Zielzone mit der Eigenschaft --edge-zone angeben.

Erstellen eines öffentlichen Clusters

# Log in to Azure
az login

# Set the subscription you want to create the cluster on
az account set --subscription $SUBSCRIPTION 

# Create the resource group
az group create --name $RG_NAME --location $LOCATION

# Deploy the cluster in your designated Azure Extended Zone
az aks create \
    --resource-group $RG_NAME \
    --name $CLUSTER_NAME \
    --edge-zone $EXTENDED_ZONE_NAME \
    --location $LOCATION \
    --generate-ssh-keys

Erstellen eines privaten Clusters

Um einen privaten AKS-Cluster in einer Azure erweiterten Zone bereitzustellen, fügen Sie das --enable-private-cluster Flag hinzu.

az aks create \
    --resource-group $RG_NAME \
    --name $CLUSTER_NAME \
    --edge-zone $EXTENDED_ZONE_NAME \
    --location $LOCATION \
    --enable-private-cluster \
    --generate-ssh-keys

Nach der Bereitstellung eines AKS-Clusters für erweiterte Azure-Zonen können Sie den Status überprüfen und die Metriken des Clusters mithilfe des Azure-Portals oder der Azure CLI überwachen.

Mit dem folgenden Code werden eine Ressourcengruppe und ein Kubernetes-Cluster in Azure mit aktivierter automatischer Skalierung und spezifischen Netzwerkeinstellungen mithilfe von Terraform erstellt.

1. Erstellen Sie ein Verzeichnis, in dem der Terraform-Beispielcode getestet und ausgeführt werden soll, und legen Sie es als aktuelles Verzeichnis fest.

2. Erstellen Sie eine Datei namens main.tf, und fügen Sie den folgenden Code ein:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   resource "random_pet" "azurerm_kubernetes_cluster_name" {
     prefix = "cluster"
   }
   
   resource "random_pet" "azurerm_kubernetes_cluster_dns_prefix" {
     prefix = "dns"
   }
   
   resource "azapi_resource" "aks" {
     type      = "Microsoft.ContainerService/ManagedClusters@2024-05-01"
     name      = random_pet.azurerm_kubernetes_cluster_name.id
     parent_id = azurerm_resource_group.rg.id
     location  = azurerm_resource_group.rg.location
     identity {
       type = "SystemAssigned"
     }
     body = {
       extendedLocation = {
         name = replace(lower(var.aks_extended_zone), " ", "")
         type = "EdgeZone"
       }
       sku = {
         name = "Base"
         tier = "Free"
       }
       properties = {
         dnsPrefix         = random_pet.azurerm_kubernetes_cluster_dns_prefix.id
         kubernetesVersion = "1.29"
         agentPoolProfiles = [
           {
             name                   = "agentpool"
             count                  = var.aks_node_count
             vmSize                 = var.aks_node_vm_size
             osDiskSizeGB           = 128
             kubeletDiskType        = "OS"
             maxPods                = 30
             type                   = "VirtualMachineScaleSets"
             enableAutoScaling      = false,
             scaleDownMode          = "Delete",
             orchestratorVersion    = "1.29"
             enableNodePublicIP     = false
             mode                   = "System"
             enableEncryptionAtHost = false
             enableUltraSSD         = false
             osType                 = "Linux"
             osSKU                  = "Ubuntu"
             upgradeSettings = {
               maxSurge = "10%"
             }
             enableFIPS = false
           }
         ]
         windowsProfile = {
           adminUsername  = var.admin_username
           adminPassword  = var.admin_password
           licenseType    = "None"
           enableCSIProxy = true
         }
         servicePrincipalProfile = {
           clientId = "msi"
         }
         enableRBAC  = true
         supportPlan = "KubernetesOfficial"
         networkProfile = {
           networkPlugin    = "azure"
           networkPolicy    = "none"
           networkDataplane = "azure"
           loadBalancerSku  = "standard"
           loadBalancerProfile = {
             managedOutboundIPs = {
               count = 1
             }
             backendPoolType = "nodeIPConfiguration"
           }
           serviceCidr  = "10.0.0.0/16"
           dnsServiceIP = "10.0.0.10"
           outboundType = "loadBalancer"
           serviceCidrs = [
             "10.0.0.0/16",
           ]
           ipFamilies = ["IPv4"]
         }
         autoUpgradeProfile = {
           upgradeChannel       = "none"
           nodeOSUpgradeChannel = "NodeImage"
         }
         disableLocalAccounts = false
         storageProfile = {
           diskCSIDriver = {
             enabled = true
           }
           fileCSIDriver = {
             enabled = true
           }
           snapshotController = {
             enabled = true
           }
         }
         oidcIssuerProfile = {
           enabled = false
         }
         azureMonitorProfile = {
           metrics = {
             enabled = false
           }
         }
       }
     }
     timeouts {
       create = "6h"
     }
   }
   

3. Erstellen Sie eine Datei namens outputs.tf, und fügen Sie den folgenden Code ein:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "aks_cluster_name" {
     value = azapi_resource.aks.name
   }
   
   output "aks_extended_zone" {
     value = azapi_resource.aks.body.extendedLocation.name
   }
   

4. Erstellen Sie eine Datei namens providers.tf, und fügen Sie den folgenden Code ein:

   terraform {
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       azapi = {
         source  = "Azure/azapi"
         version = "2.0.1"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. Erstellen Sie eine Datei namens variables.tf, und fügen Sie den folgenden Code ein:

   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "resource_group_location" {
     type        = string
     default     = "West US"
     description = "Location of the resource group."
   }
   
   variable "virtual_network_name" {
     type        = string
     description = "Virtual network names"
     default     = "example-vnet"
   }
   
   variable "aks_node_count" {
     type        = number
     description = "AKS node count"
     default     = 3
   }
   
   variable "aks_node_vm_size" {
     type        = string
     description = "AKS node VM size"
     default     = "Standard_D2_v2"
   }
   
   variable "admin_username" {
     type        = string
     description = "The admin username for the Windows node pool."
     default     = "azureuser"
   }
   
   variable "admin_password" {
     type        = string
     description = "The admin password for the Windows node pool."
     default     = "Passw0rd1234Us!"
   }
   
   variable "aks_extended_zone" {
     type        = string
     description = "AKS extended zone"
     default     = "Los Angeles"
   }
   

6. Terraform initialisieren.

   Führen Sie terraform init aus, um die Terraform-Bereitstellung zu initialisieren. Dieser Befehl lädt den Azure-Anbieter herunter, der zum Verwalten Ihrer Azure-Ressourcen erforderlich ist.

   terraform init -upgrade
   

   Wichtige Punkte:

   • Der Parameter -upgrade aktualisiert die erforderlichen Anbieter-Plug-Ins auf die neueste Version, die den Versionseinschränkungen der Konfiguration entspricht.

7. Erstellen eines Terraform-Ausführungsplans.

   Führen Sie terraform plan aus, um einen Ausführungsplan zu erstellen.

   terraform plan -out main.tfplan
   

   Wichtige Punkte:

   • Der Befehl terraform plan erstellt einen Ausführungsplan, führt ihn aber nicht aus. Stattdessen wird bestimmt, welche Aktionen erforderlich sind, um die in Ihren Konfigurationsdateien angegebene Konfiguration zu erstellen. Mit diesem Muster können Sie überprüfen, ob der Ausführungsplan Ihren Erwartungen entspricht, bevor Sie Änderungen an tatsächlichen Ressourcen vornehmen.
   • Mit dem optionalen -out-Parameter können Sie eine Ausgabedatei für den Plan angeben. Durch die Verwendung des Parameters -out wird sichergestellt, dass genau der von Ihnen überprüfte Plan angewendet wird.

8. Wenden Sie einen Terraform-Ausführungsplan an.

   Führen Sie terraform apply aus, um den Ausführungsplan auf Ihre Cloudinfrastruktur anzuwenden.

   terraform apply main.tfplan
   

   Wichtige Punkte:

   • Der Beispielbefehl terraform apply setzt voraus, dass Sie zuvor terraform plan -out main.tfplan ausgeführt haben.
   • Wenn Sie einen anderen Dateinamen für den Parameter -out angegeben haben, verwenden Sie denselben Dateinamen im Aufruf von terraform apply.
   • Wenn Sie den Parameter -out nicht verwendet haben, rufen Sie terraform apply ohne Parameter auf.