Überwachen von Azure Functions und Event Hubs

Die Überwachung bietet Einblicke in das Verhalten und die Integrität Ihrer Systeme. Es hilft Ihnen, einen ganzheitlichen Überblick über die Umwelt und historische Trends zu erhalten, verschiedene Faktoren zu korrelieren und Änderungen der Leistung, des Verbrauchs oder der Fehlerrate zu messen.

Azure Functions bietet integrierte Integration in Application Insights. Aus Application Insights können Sie Informationen wie die Anzahl der Funktions-App-Instanzen oder -Anforderungen und die Abhängigkeits-Telemetrie einer Funktion abrufen. Wenn Sie Funktionen zusammen mit Azure Event Hubs verwenden, kann Application Insights auch die ausgehenden Abhängigkeits-Telemetriedaten an den Event Hub nachverfolgen, die Verarbeitungszeit berechnen und den End-to-End-Fluss des Systems anzeigen, das über Event Hubs verbunden ist.

In diesem Artikel werden nützliche Features und Einblicke vorgestellt, die Sie aus Application Insights für Ihre Lösung abrufen können, die Event Hubs zusammen mit Funktionen verwendet.

Anwendungsübersicht

Die Anwendungszuordnung zeigt, wie die Komponenten in einem System miteinander interagieren. Da Application Insights Abhängigkeits-Telemetrie bereitstellt, kann sie den Ereignisfluss zwischen Azure Functions und Event Hubs zuordnen, einschließlich der durchschnittlichen Anzahl von Aufrufen für jede Funktion und der durchschnittliche Dauer eines Ereignisses in Event Hubs. Außerdem werden Transaktionen angezeigt, die Fehler in Rot enthalten.

Nachdem Sie die erwartete Auslastung an Ihr System gesendet haben, können Sie im Azure Portal zu Application Insights wechseln und im Navigationsbereich die Anwendungszuordnung auswählen. Die folgende Karte zeigt drei Funktionen, drei Event Hubs und augenscheinlich fehlgeschlagene Schreibvorgänge in eine nachgelagerte Datenbank.

Screenshot einer Anwendungszuordnung, die drei Funktionen, drei Event Hubs und offensichtliche Fehler während der Schreibvorgänge in eine nachgeschaltete Datenbank zeigt.

End-to-End-Transaktionsdetails

End-to-End-Transaktionsdetails zeigen in chronologischer Reihenfolge, wie Ihre Systemkomponenten miteinander interagieren. In dieser Ansicht wird auch gezeigt, wie lange ein Ereignis verarbeitet wurde. Sie können einen Drilldown in die Telemetrie jeder Komponente in dieser Ansicht ausführen. Dies hilft Ihnen bei der Problembehandlung bei Komponenten innerhalb derselben Anforderung, wenn ein Problem auftritt.

Screenshot der Detailansicht der End-to-End-Transaktion in Application Insights. Es zeigt die Zeitachse einer Funktionsanforderung, eine ausgehende Abhängigkeit von einem Event Hub, die in der Warteschlange aufgewendete Zeit und die nachfolgende Ausführung.

Plattformmetriken und Telemetriedaten

Sie können plattformgenerierte Metriken in Azure Monitor für Event Hubs und Azure Functions verwenden, um das Verhalten und die Integrität einer Lösung zu überwachen:

Azure Functions integriert sich in Application Insights, um erweiterte und detaillierte Telemetriedaten und Erkenntnisse über den Functions-Host und die Funktionsausführungen bereitzustellen. Weitere Informationen finden Sie unter Analysieren von Azure Functions-Telemetriedaten in Application Insights. Wenn Sie Application Insights verwenden, um eine Topologie zu überwachen, ist eine Vielzahl von Konfigurationen verfügbar. Weitere Informationen finden Sie unter Konfigurieren der Überwachung für Azure Functions.

Das folgende Beispiel zeigt zusätzliche Telemetrie für Funktionen, die von Event Hubs ausgelöst werden. Sie wird in der Tabelle traces generiert:

Trigger Details: PartitionId: 6, Offset: 3985758552064-3985758624640, EnqueueTimeUtc: 2025-10-31T12:51:58.1750000+00:00-2025-10-31T12:52:03.8160000+00:00, SequenceNumber: 3712266-3712275, Count: 10

Diese Daten sind nützlich, da sie Informationen zu der Nachricht enthält, die die Funktion ausgelöst hat und für Abfragen und Erkenntnisse verwendet werden kann. Sie enthalten die folgenden Daten für jede Auslösung der Funktion:

  • Die Partitions-ID (6)
  • Bereich des Partitionsoffsets (3985758552064-3985758624640)
  • Der Zeitbereich der Einreihung in UTC (2025-10-31T12:51:58.1750000+00:00-2025-10-31T12:52:03.8160000+00:00)
  • Der Sequenznummernbereich beträgt 3712266-3712275.
  • Die Anzahl der Nachrichten (10)

Beispiele für die Verwendung dieser Telemetrie finden Sie im Abschnitt " Beispielanwendungserkenntnisse"-Abfragen in diesem Artikel.

Sie können auch benutzerdefinierte Telemetrie für verschiedene Sprachen verwenden (C#-Klassenbibliothek, C# isoliert, C#-Skript, JavaScript, Java, PowerShell und Python). Diese Protokollierung wird in der Tabelle traces in Application Insights angezeigt. Sie können eigene Einträge in Application Insights erstellen und benutzerdefinierte Dimensionen hinzufügen, die Sie zum Abfragen von Daten und erstellen benutzerdefinierte Dashboards verwenden können.

Schließlich werden, wenn Ihre Funktions-App über eine Ausgabebindung eine Verbindung mit einem Event Hub herstellt, Einträge auch in die Application Insights-Tabelle „Dependencies“ geschrieben.

Screenshot der Tabelle

Für Event Hubs wird die Korrelation in die Ereignisnutzdaten eingefügt, und Sie sehen eine Eigenschaft Diagnostic-Id in den Ereignissen:

Screenshot einer Ereignisnutzlast, die eine Diagnostic-Id Eigenschaft im Properties-Objekt zusammen mit Systemeigenschaften wie Sequenznummer, Offset und Queue-Zeit zeigt.

Diese Eigenschaft verwendet das W3C Trace Context-Format, das in von Functions erzeugten Telemetriedaten auch als Vorgangs-ID und Vorgangslinks verwendet wird. Mit diesem Format kann Application Insights die Korrelation zwischen Event Hub-Ereignissen und Funktionsausführungen erstellen, auch wenn sie verteilt werden.

Diagramm, das zeigt, wie Application Insights Telemetrie in zwei Funktionen korreliert, die einen Batch von Ereignissen verarbeiten.

Application Insights-Beispielabfragen

Die folgende Liste enthält Application Insights-Abfragen, mit denen Sie eine Lösung überwachen können, die Event Hubs zusammen mit Azure Functions verwendet. Diese Abfragen zeigen detaillierte Informationen für Funktionen an, die von Event Hubs ausgelöst werden, die Telemetrie verwenden, die von der Event Hubs-Erweiterung ausgegeben wird.

Wenn das Sampling in Application Insights aktiviert ist, gibt es möglicherweise Lücken in den Daten.

Ausführliche Informationen zur Ereignisverarbeitung

Die Daten werden nur im richtigen Format ausgegeben, wenn Batchversand verwendet wird. Wenn Sie die Batchverteilung verwenden, akzeptiert die Funktion für jede Ausführung mehrere Ereignisse. Wir empfehlen diesen Modus , um die Leistung zu verbessern. Beachten Sie dabei die folgenden Aspekte:

  • Der Wert dispatchTimeMilliseconds nähert die Zeitspanne an, wie lange es dauert, bis das Ereignis in den Event Hub geschrieben wird und von der Function App zur Verarbeitung übernommen wird.
  • dispatchTimeMilliseconds kann aufgrund von Uhrzeitabweichungen zwischen dem Event Hub-Server und der Funktion-App negativ oder anderweitig ungenau sein.
  • Event Hubs-Partitionen werden sequenziell verarbeitet. Eine Nachricht wird erst zur Verarbeitung an den Funktionscode weitergeleitet, wenn alle vorherigen Nachrichten verarbeitet wurden. Überwachen Sie die Ausführungszeit Ihrer Funktionen, da längere Ausführungszeiten zu Verteilerverzögerungen führen.
  • Die Berechnung verwendet die „enqueueTime“ der ersten Nachricht im Batch. Die Versandzeiten für andere Nachrichten im Batch könnten kürzer sein.
  • dispatchTimeMilliseconds basiert auf dem Zeitpunkt.
  • Sequenznummern gelten pro Partition, und eine doppelte Verarbeitung ist möglich, da Event Hubs keine Exactly-once-Nachrichtenzustellung garantiert.
traces
| where message startswith "Trigger Details: Parti"
| parse message with * "tionId: " partitionId:string ", Offset: "
offsetStart:string "-" offsetEnd:string", EnqueueTimeUtc: "
enqueueTimeStart:datetime "+00:00-" enqueueTimeEnd:datetime "+00:00, SequenceNumber: "
sequenceNumberStart:string "-" sequenceNumberEnd:string ", Count: "
messageCount:int
| extend dispatchTimeMilliseconds = (timestamp - enqueueTimeStart) / 1ms
| project timestamp, cloud_RoleInstance, operation_Name, processId =
customDimensions.ProcessId, partitionId, messageCount, sequenceNumberStart,
sequenceNumberEnd, enqueueTimeStart, enqueueTimeEnd, dispatchTimeMilliseconds

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot der Ergebnisse der Application Insights-Abfrage für die detaillierte Ereignisverarbeitungsabfrage.

Visualisierung der Versandlatenz

Diese Abfrage visualisiert die Event-Dispatch-Latenz im 50. und 90. Perzentil für eine bestimmte Funktion, die durch einen Event Hub ausgelöst wird. Weitere Informationen und Hinweise finden Sie in der vorherigen Abfrage.

traces
| where operation_Name == "<enter the name of your function here>"
| where message startswith "Trigger Details: Parti"
| parse message with * "tionId: " partitionId:string ", Offset: "
offsetStart:string "-" offsetEnd:string", EnqueueTimeUtc: "
enqueueTimeStart:datetime "+00:00-" enqueueTimeEnd:datetime "+00:00, SequenceNumber: "
sequenceNumberStart:string "-" sequenceNumberEnd:string ", Count: "
messageCount:int
| extend dispatchTimeMilliseconds = (timestamp - enqueueTimeStart) / 1ms
| summarize percentiles(dispatchTimeMilliseconds, 50, 90) by bin(timestamp, 5m)
| render timechart

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot eines Zeitdiagramms, das die Dispatchlatenz im 50. und 90. Perzentil in Millisekunden im Verlauf von 24 Stunden zeigt. Die Linie für das 50. Perzentil bleibt nahe 25 ms. Die Linie für das 90. Perzentil schwankt zwischen etwa 50 ms und 460 ms.

Zusammenfassung der Versandlatenz

Diese Abfrage ähnelt der vorherigen Abfrage, zeigt aber eine Zusammenfassungsansicht an.

traces
| where message startswith "Trigger Details: Parti"
| parse message with * "tionId: " partitionId:string ", Offset: "
offsetStart:string "-" offsetEnd:string", EnqueueTimeUtc: "
enqueueTimeStart:datetime "+00:00-" enqueueTimeEnd:datetime "+00:00, SequenceNumber: "
sequenceNumberStart:string "-" sequenceNumberEnd:string ", Count: "
messageCount:int
| extend dispatchTimeMilliseconds = (timestamp - enqueueTimeStart) / 1ms
| summarize messageCount = sum(messageCount),
percentiles(dispatchTimeMilliseconds, 50, 90, 99, 99.9, 99.99) by operation_Name

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot der Ergebnisse der Application Insights-Abfrage für die Zusammenfassung der Verteilerlatenz. Es zeigt eine Nachrichtenanzahl und Verteilerlatenz-Quantile an.

Verteilung von Nachrichten auf Partitionen

Diese Abfrage zeigt, wie die Verteilung von Nachrichten auf Partitionen visualisiert wird.

traces
| where message startswith "Trigger Details: Parti"
| parse message with * "tionId: " partitionId:string ", Offset: "
offsetStart:string "-" offsetEnd:string", EnqueueTimeUtc: "
enqueueTimeStart:datetime "+00:00-" enqueueTimeEnd:datetime "+00:00, SequenceNumber: "
sequenceNumberStart:string "-" sequenceNumberEnd:string ", Count: "
messageCount:int
| summarize messageCount = sum(messageCount) by cloud_RoleInstance,
bin(timestamp, 5m)
| render areachart kind=stacked

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot der Ergebnisse der Application Insights-Abfrage für die Nachrichtenverteilung über partitionsübergreifende Abfrage.

Nachrichtenverteilung zwischen Instanzen

Diese Abfrage zeigt, wie die Verteilung von Nachrichten auf Instanzen visualisiert wird.

traces
| where message startswith "Trigger Details: Parti"
| parse message with * "tionId: " partitionId:string ", Offset: "
offsetStart:string "-" offsetEnd:string", EnqueueTimeUtc: "
enqueueTimeStart:datetime "+00:00-" enqueueTimeEnd:datetime "+00:00, SequenceNumber: "
sequenceNumberStart:string "-" sequenceNumberEnd:string ", Count: "
messageCount:int
| summarize messageCount = sum(messageCount) by cloud_RoleInstance,
bin(timestamp, 5m)
| render areachart kind=stacked

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot der Ergebnisse der Application Insights-Abfrage für die Nachrichtenverteilung über Instanzen hinweg.

Ausgeführte Instanzen und zugewiesene Instanzen

Diese Abfrage zeigt, wie man die Anzahl der Azure Functions-Instanzen, die Ereignisse aus Event Hubs verarbeiten, und die Gesamtzahl der Instanzen (sowohl verarbeitend als auch auf Leasing wartend) darstellen kann. Die beiden Zahlen sollten in der Regel übereinstimmen.

traces
| where message startswith "Trigger Details: Parti"
| summarize type = "Executing Instances", Count = dcount(cloud_RoleInstance) by
bin(timestamp, 60s)
| union (
    traces
    | summarize type = "Allocated Instances", Count = dcount(cloud_RoleInstance) by
bin(timestamp, 60s)
)
| project timestamp, type, Count
| render timechart

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot der Ergebnisse der Application Insights-Abfrage für die ausgeführten Instanzen und die zugeordneten Instanzenabfrage.

Alle Telemetriedaten für eine bestimmte Funktionsausführung

Sie können das feld operation_Id in den verschiedenen Tabellen in Application Insights verwenden. Bei Azure funktionen, die von Event Hubs ausgelöst werden, gibt die folgende Abfrage z. B. die Triggerinformationen, Telemetriedaten aus Protokollen im Funktionscode sowie Abhängigkeiten und Ausnahmen zurück:

union isfuzzy=true requests, exceptions, traces, dependencies
| where * has "<enter the operation_Id of your function execution here>"
| order by timestamp asc

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot des Ergebnisses einer Application Insights-Abfrage. Es zeigt alle Telemetriedaten für eine einzelne Vorgangs-ID an.

End-to-End-Latenz für ein Ereignis

Die enqueueTimeUtc-Eigenschaft in der Triggerdetailablaufverfolgung zeigt die Queue-Zeit nur des ersten Ereignisses jedes Batches an, den die Funktion verarbeitet hat. Sie können eine komplexere Abfrage verwenden, um die End-to-End-Latenz für Ereignisse zu berechnen, die über zwei Funktionen übergeben werden, die von einem Ereignishub verbunden sind. Diese Abfrage erweitert die Operationsverknüpfungen (sofern vorhanden) in der Anfrage der zweiten Funktion und ordnet ihre Abschlusszeit der Operations-ID zu, die der Startzeit der ersten Funktion entspricht.

let start = view(){
requests
| where operation_Name == "FirstFunction"
| project start_t = timestamp, first_operation_Id = operation_Id
};
let link = view(){
requests
| where operation_Name == "SecondFunction"
| mv-expand ex = parse_json(tostring(customDimensions["_MS.links"]))
| extend parent = case(isnotempty(ex.operation_Id), ex.operation_Id, operation_Id )
| project first_operation_Id = parent, second_operation_Id = operation_Id
};
let finish = view(){
traces
| where customDimensions["EventName"] == "FunctionCompleted" and operation_Name
== "SecondFunction"
| project end_t = timestamp, second_operation_Id = operation_Id
};
start
| join kind=inner (
link
| join kind=inner finish on second_operation_Id
) on first_operation_Id
| project start_t, end_t, first_operation_Id, second_operation_Id
| summarize avg(datetime_diff('second', end_t, start_t))

Der folgende Screenshot zeigt die Abfrageergebnisse.

Screenshot der Ergebnisse der Application Insights-Abfrage für die End-to-End-Latenzabfrage.

Beitragende

Microsoft verwaltet diesen Artikel. Die folgenden Mitwirkenden haben diesen Artikel geschrieben.

Hauptautor:

Um nicht öffentliche LinkedIn-Profile zu sehen, melden Sie sich bei LinkedIn an.

Nächste Schritte