Erstellen Sie ein virtuelles Netzwerk-Flussprotokoll mit Terraform

Virtuelle Netzwerk-Flussprotokolle speichern Informationen über IP-Verkehr, der durch ein virtuelles Netzwerk fließt. In diesem Artikel verwenden Sie Terraform, um ein virtuelles Netzwerk-Flow-Log und ein dediziertes Speicherkonto für ein bestehendes virtuelles Netzwerk zu erstellen. Weitere Informationen finden Sie unter Übersicht über virtuelle Netzwerkflussprotokolle.

Die Terraform-Konfiguration verwendet die regionale Network Watcher-Instanz, die Azure automatisch erstellt, wenn Network Watcher aktiviert ist. Sie erstellen das Flow-Log und das Speicherkonto in der Network Watcher-Ressourcengruppe.

Prerequisites

  • Ein Azure-Konto mit einem aktiven Abonnement. Kostenlos ein Konto erstellen.
  • Installieren und konfigurieren Sie Terraform.
  • Ein vorhandenes virtuelles Netzwerk. Um eines zu erstellen, siehe Create a virtual network.
  • Network Watcher ist im Bereich des virtuellen Netzwerks aktiviert. Network Watcher ist standardmäßig aktiviert, es sei denn, du deaktivierst es ausdrücklich.
  • Der Ressourcenanbieter Microsoft.Insights wurde in Ihrer Subscription registriert. Weitere Informationen finden Sie unter Register des Insights-Anbieters.
  • Berechtigungen, um ein Flow-Log und ein Speicherkonto in der Ressourcengruppe zu erstellen, die die regionale Network Watcher-Instanz enthält.

Überprüfen Sie die Terraform-Konfiguration

Die Beispielkonfiguration für diesen Artikel findest du im Azure Terraform GitHub-Repository.

Die Konfiguration erzeugt folgende Ressourcen:

Die Konfiguration verwendet außerdem die Network Watcher-Datenquelle, um auf die bestehende regionale Network Watcher-Instanz zu referenzieren.

  1. Erstelle ein Verzeichnis, um die Beispiel-Terraform-Konfiguration zu testen, und mache es zum aktuellen Verzeichnis.

  2. Erstellen Sie eine Datei namens providers.tf, und fügen Sie den folgenden Code ein:

    terraform {
      required_version = ">= 1.5.0"
    
      required_providers {
        azurerm = {
          source  = "hashicorp/azurerm"
          version = "~> 5.0"
        }
        random = {
          source  = "hashicorp/random"
          version = "~> 3.7"
        }
      }
    }
    
    provider "azurerm" {
      features {}
    }
    
  3. Erstellen Sie eine Datei namens main.tf, und fügen Sie den folgenden Code ein:

    data "azurerm_network_watcher" "network_watcher" {
      name                = var.network_watcher_name
      resource_group_name = var.network_watcher_resource_group_name
    }
    
    resource "random_string" "storage_account_suffix" {
      length  = 8
      lower   = true
      numeric = true
      special = false
      upper   = false
    }
    
    resource "azurerm_storage_account" "flow_logs" {
      name                     = "flowlogs${random_string.storage_account_suffix.result}"
      resource_group_name      = data.azurerm_network_watcher.network_watcher.resource_group_name
      location                 = data.azurerm_network_watcher.network_watcher.location
      account_tier             = "Standard"
      account_kind             = "StorageV2"
      account_replication_type = var.storage_account_replication_type
    }
    
    resource "azurerm_network_watcher_flow_log" "vnet_flow_log" {
      name                 = var.flow_log_name
      network_watcher_name = data.azurerm_network_watcher.network_watcher.name
      resource_group_name  = data.azurerm_network_watcher.network_watcher.resource_group_name
      location             = data.azurerm_network_watcher.network_watcher.location
    
      target_resource_id = var.virtual_network_id
      storage_account_id = azurerm_storage_account.flow_logs.id
      enabled            = true
      version            = var.flow_log_version
    
      retention_policy {
        enabled = var.retention_days > 0
        days    = var.retention_days
      }
    }
    
  4. Erstellen Sie eine Datei namens variables.tf, und fügen Sie den folgenden Code ein:

    variable "network_watcher_name" {
      type        = string
      default     = "NetworkWatcher_eastus"
      description = "Name of the existing regional Network Watcher instance."
    }
    
    variable "network_watcher_resource_group_name" {
      type        = string
      default     = "NetworkWatcherRG"
      description = "Name of the resource group that contains the Network Watcher instance."
    }
    
    variable "virtual_network_id" {
      type        = string
      description = "Resource ID of the existing virtual network to monitor."
    
      validation {
        condition     = can(regex("(?i)^/subscriptions/[^/]+/resourceGroups/[^/]+/providers/Microsoft.Network/virtualNetworks/[^/]+$", var.virtual_network_id))
        error_message = "The virtual_network_id value must be a full Azure virtual network resource ID."
      }
    }
    
    variable "flow_log_name" {
      type        = string
      default     = "vnet-flow-log"
      description = "Name of the virtual network flow log."
    }
    
    variable "flow_log_version" {
      type        = number
      default     = 2
      description = "Flow log format version. Valid values are 1 and 2."
    
      validation {
        condition     = contains([1, 2], var.flow_log_version)
        error_message = "The flow_log_version value must be 1 or 2."
      }
    }
    
    variable "retention_days" {
      type        = number
      default     = 0
      description = "Number of days to retain flow log data. Use 0 to retain data indefinitely."
    
      validation {
        condition     = var.retention_days >= 0 && var.retention_days <= 365
        error_message = "The retention_days value must be between 0 and 365."
      }
    }
    
    variable "storage_account_replication_type" {
      type        = string
      default     = "LRS"
      description = "Replication type for the flow log storage account."
    
      validation {
        condition     = contains(["LRS", "GRS", "ZRS"], var.storage_account_replication_type)
        error_message = "The storage_account_replication_type value must be LRS, GRS, or ZRS."
      }
    }
    
  5. Erstellen Sie eine Datei namens outputs.tf, und fügen Sie den folgenden Code ein:

    output "flow_log_id" {
      description = "Resource ID of the virtual network flow log."
      value       = azurerm_network_watcher_flow_log.vnet_flow_log.id
    }
    
    output "flow_log_name" {
      description = "Name of the virtual network flow log."
      value       = azurerm_network_watcher_flow_log.vnet_flow_log.name
    }
    
    output "storage_account_name" {
      description = "Name of the storage account that contains the flow log data."
      value       = azurerm_storage_account.flow_logs.name
    }
    

Setze die vorhandenen Ressourcenwerte

Erstellen Sie eine Datei mit dem Namen terraform.tfvars. Ersetzen Sie die Platzhalter durch Werte für Ihr bestehendes virtuelles Netzwerk und die regionale Network Watcher-Instanz.

network_watcher_name                = "NetworkWatcher_eastus"
network_watcher_resource_group_name = "NetworkWatcherRG"
virtual_network_id                  = "/subscriptions/<subscription-id>/resourceGroups/<resource-group-name>/providers/Microsoft.Network/virtualNetworks/<virtual-network-name>"

Das virtuelle Netzwerk und die Network Watcher-Instanz müssen sich in derselben Azure-Region befinden. Wenn Ihre Network Watcher-Instanz einen benutzerdefinierten Namen oder eine Ressourcengruppe verwendet, aktualisieren Sie beide Network Watcher-Werte.

Terraform initialisieren

Führen Sie terraform init aus, um die Terraform-Bereitstellung zu initialisieren. Dieser Befehl lädt den Azure-Anbieter herunter, der zum Verwalten Ihrer Azure-Ressourcen erforderlich ist.

terraform init -upgrade

Wichtige Punkte:

  • Der Parameter -upgrade aktualisiert die erforderlichen Anbieter-Plug-Ins auf die neueste Version, die den Versionseinschränkungen der Konfiguration entspricht.

Terraform-Ausführungsplan erstellen

Führen Sie terraform plan aus, um einen Ausführungsplan zu erstellen.

terraform plan -out main.tfplan

Wichtige Punkte:

  • Der Befehl terraform plan erstellt einen Ausführungsplan, führt ihn aber nicht aus. Stattdessen wird bestimmt, welche Aktionen erforderlich sind, um die in Ihren Konfigurationsdateien angegebene Konfiguration zu erstellen. Mit diesem Muster können Sie überprüfen, ob der Ausführungsplan Ihren Erwartungen entspricht, bevor Sie Änderungen an tatsächlichen Ressourcen vornehmen.
  • Mit dem optionalen -out-Parameter können Sie eine Ausgabedatei für den Plan angeben. Durch die Verwendung des Parameters -out wird sichergestellt, dass genau der von Ihnen überprüfte Plan angewendet wird.

Anwendung des Terraform-Ausführungsplans

Führen Sie terraform apply aus, um den Ausführungsplan auf Ihre Cloudinfrastruktur anzuwenden.

terraform apply main.tfplan

Wichtige Punkte:

  • Der Beispielbefehl terraform apply setzt voraus, dass Sie zuvor terraform plan -out main.tfplan ausgeführt haben.
  • Wenn Sie einen anderen Dateinamen für den Parameter -out angegeben haben, verwenden Sie denselben Dateinamen im Aufruf von terraform apply.
  • Wenn Sie den Parameter -out nicht verwendet haben, rufen Sie terraform apply ohne Parameter auf.

Überprüfen Sie das Flussprotokoll

  1. Melden Sie sich im Azure-Portal an.

  2. Suchen Sie nach der Option Network Watcher, und wählen Sie sie aus.

  3. Wählen Sie unter Protokolle die Option Datenflussprotokolle aus.

  4. Bestätigen Sie, dass das Flow-Log aktiviert ist und dass die Zielressource Ihr virtuelles Netzwerk ist.

Du kannst auch das Flow-Log und die Speicherkontonamen aus den Terraform-Ausgaben anzeigen:

terraform output flow_log_name
terraform output storage_account_name

Bereinigen von Ressourcen

Wenn Sie die über Terraform erstellten Ressourcen nicht mehr benötigen, führen Sie die folgenden Schritte aus:

  1. Führen Sie terraform plan aus, und geben Sie das Flag destroy an.

    terraform plan -destroy -out main.destroy.tfplan
    

    Wichtige Punkte:

    • Der Befehl terraform plan erstellt einen Ausführungsplan, führt ihn aber nicht aus. Stattdessen wird bestimmt, welche Aktionen erforderlich sind, um die in Ihren Konfigurationsdateien angegebene Konfiguration zu erstellen. Mit diesem Muster können Sie überprüfen, ob der Ausführungsplan Ihren Erwartungen entspricht, bevor Sie Änderungen an tatsächlichen Ressourcen vornehmen.
    • Mit dem optionalen -out-Parameter können Sie eine Ausgabedatei für den Plan angeben. Durch die Verwendung des Parameters -out wird sichergestellt, dass genau der von Ihnen überprüfte Plan angewendet wird.
  2. Führen Sie den Befehl terraform apply aus, um den Ausführungsplan anzuwenden.

    terraform apply main.destroy.tfplan
    

Die Zerstörungsoperation löscht das Flow-Log und das durch diese Konfiguration erstellte Speicherkonto. Es löscht nicht das bestehende virtuelle Netzwerk oder die Network Watcher-Instanz.

Problembehandlung von Terraform auf Azure

Behebung häufiger Probleme bei der Verwendung von Terraform in Azure