Verwenden Sie Parameter in Real-Time Dashboard-Abfragen

Parameter sind die Bausteine für Filter in Real-Time Dashboards. Sie verwalten sie auf Dashboardebene und fügen sie Abfragen hinzu, um die in einem visuellen Element angezeigten Daten zu filtern. Eine Abfrage kann einen oder mehrere Parameter verwenden.

In diesem Artikel wird erläutert, wie Sie Parameter, Kreuzfilter und Drillthroughs in Dashboards erstellen und verwenden. Sie können Dashboard-Visualisierungen entweder filtern, indem Sie Parameterwerte in der Filterleiste auswählen oder Querfilter verwenden.

Die in diesem Artikel verwendeten Abfragebeispiele basieren auf der Tabelle StormEvents in den Beispieldaten der Wetteranalyse, die im Beispielkatalog verfügbar sind.

Hinweis

Sie können Parameter nur im Bearbeitungsmodus für Dashboard-Editoren verwalten. Dashboard-Parameter filtern Visualisierungen, deren Abfragen diese Parameter verwenden. Parameter filtern die Fabric Maps-Kacheln nicht und ändern sie auch nicht anderweitig.

Voraussetzungen

Verwenden von Parametern in Ihrer Abfrage

Ein Parameter muss in der Abfrage verwendet werden, bevor sich der Filter auf dieses visuelle Element auswirkt. Nachdem Sie einen Parameter definiert haben, können Sie ihn in der Filterleiste auf der Seite Query und in der IntelliSense für Abfragen sehen.

Hinweis

Wenn die Abfrage den Parameter nicht verwendet, bleibt der Filter inaktiv. Wenn Sie den Parameter zur Abfrage hinzufügen, wird der Filter aktiv.

Parametertypen

Das Dashboard unterstützt die folgenden Parametertypen:

In den folgenden Beispielen wird beschrieben, wie Parameter in einer Abfrage für verschiedene Parametertypen verwendet werden.

Standardparameter „Zeitbereich“

Jedes Dashboard enthält standardmäßig einen Parameter für den Zeitraum . Sie wird nur dann als Filter angezeigt, wenn Sie ihn in einer Abfrage verwenden. Verwenden Sie die Schlüsselwörter _startTime und _endTime, um den Standardparameter für den Zeitbereich anzuwenden, wie im folgenden Beispiel gezeigt:

StormEvents
| where StartTime between (_startTime.._endTime)
| summarize TotalEvents = count() by State
| top 5 by TotalEvents

Wenn Sie die Abfrage speichern, wird der Zeitbereichsfilter im Dashboard angezeigt. Anschließend können Sie das visuelle Element filtern, indem Sie eine Voreinstellung im Zeitraum auswählen oder einen benutzerdefinierten Zeitraum auswählen.

Screenshot des Zeitbereichsfilters mit ausgewähltem benutzerdefiniertem Bereich.

Parameter mit festen Werten für die Einzelauswahl

Feste Wertparameter basieren auf vordefinierten Werten, die Sie angeben. Das folgende Beispiel zeigt, wie Sie einen Parameter mit einer einzelnen Auswahl, festem Wert erstellen.

Erstellen eines Parameters mit festem Wert für Einfachauswahl

  1. Wählen Sie "Parameter" aus, um den Bereich "Parameter " zu öffnen, und wählen Sie dann " Neuer Parameter" aus.

  2. Geben Sie die folgenden Details ein:

    • Bezeichnung: Ereignistyp

    • Parametertyp: Einzelauswahl

    • Variablenname: _eventType

    • Datentyp: Zeichenfolge

    • Als Filter im Dashboard anheften: Ausgewählt

    • Quelle: Feste Werte

      Verwenden Sie in diesem Beispiel folgende Werte:

      Wert Anzeigename des Parameters
      Gewitterwind Gewitterwind
      Hagel Hagel
      Überschwemmung Überschwemmung
      Dürre Dürre
      Winterwetter Winterwetter
    • Fügen Sie einen Alle auswählen-Wert hinzu: Deaktiviert

    • Standardwert: Gewitterwind

  3. Wählen Sie Fertig aus, um den Parameter zu erstellen.

Der Parameter erscheint im Bereich „Parameter“, wird jedoch bisher in keinen Visualisierungen verwendet.

Verwenden Sie einen Parameter mit festen Werten für die Einzelauswahl

  1. Führen Sie eine Beispielabfrage aus, die den neuen Ereignistypparameter verwendet, indem Sie den _eventType Variablennamen verwenden:

    StormEvents
    | where StartTime between (_startTime.._endTime)
    | where EventType == _eventType
    | summarize TotalEvents = count() by State
    | top 5 by TotalEvents
    

    Der neue Parameter wird in der Parameterliste oben im Dashboard angezeigt.

  2. Wählen Sie unterschiedliche Werte aus, um die visuellen Elemente zu aktualisieren.

    Screenshot der fünf wichtigsten Ereignistypen nach Status.

Parameter mit festen Werten für die Mehrfachauswahl

Feste Wertparameter basieren auf vordefinierten Werten, die Sie angeben. Das folgende Beispiel zeigt, wie Sie einen Festwertparameter mit mehrfacher Auswahl erstellen und verwenden.

Parameter mit festem Wert für Mehrfachauswahl erstellen

  1. Wählen Sie "Parameter" aus, um den Bereich "Parameter " zu öffnen, und wählen Sie dann " Neuer Parameter" aus.

  2. Geben Sie die Details wie in Erstellen eines Parameters mit Einzelauswahl und festen Werten beschrieben ein, mit den folgenden Änderungen:

    • Bezeichnung: Ereignistyp
    • Parametertyp: Mehrfachauswahl
    • Variablenname: _eventType
  3. Wählen Sie Fertig aus, um den Parameter zu erstellen.

Der neue Parameter erscheint im Bereich Parameter, wird jedoch bisher in keiner Visualisierung verwendet.

Verwenden Sie einen Parameter mit festen Werten für die Mehrfachauswahl

  1. Führen Sie eine Beispielabfrage aus, die den neuen Parameter "Ereignistyp " und die _eventType Variable verwendet.

    StormEvents
    | where StartTime between (_startTime.._endTime)
    | where EventType in (_eventType) or isempty(_eventType)
    | summarize TotalEvents = count() by State
    | top 5 by TotalEvents
    

    Der neue Parameter wird in der Parameterliste oben im Dashboard angezeigt.

  2. Wählen Sie einen oder mehrere unterschiedliche Werte aus, um die visuellen Elemente zu aktualisieren.

    Screenshot der Auswahl mehrerer Ereignistypen im Filter.

Abfragebasierte Parameter für Einzelauswahl

Abfragebasierte Parameterwerte werden beim Laden des Dashboards durch Ausführen der Parameterabfrage abgerufen. Im folgenden Beispiel wird gezeigt, wie Sie einen abfragebasierten Parameter für Einfachauswahl erstellen und verwenden.

Um einen fragebasierten Parameter als Kindfilter zu verwenden, dessen Werte von einem anderen Parameter abhängen, siehe Kaskadierende Parameter erstellen.

Erstellen Sie einen abfragebasierten Parameter für die Einfachauswahl

  1. Wählen Sie "Parameter" aus, um den Bereich "Parameter " zu öffnen, und wählen Sie dann " Neuer Parameter" aus.

  2. Geben Sie die Details wie in Erstellen eines Parameters mit Einzelauswahl und festen Werten beschrieben ein, mit den folgenden Änderungen:

    • Bezeichnung: Status

    • Variablenname: _state

    • Quelle: Abfrage

    • Datenquelle: StormEventsSample

    • Wählen Sie Abfrage bearbeiten aus, und geben Sie die folgende Abfrage ein. Wählen Sie Fertig aus.

      StormEvents
      | where StartTime between (_startTime.._endTime)
      | where EventType in (_eventType) or isempty(_eventType)
      | summarize TotalEvents = count() by State
      | top 5 by TotalEvents
      | project State
      
    • Wert: Zustand

    • Anzeigename: Zustand

    • Standardwert: Wählen Sie einen Standardwert aus.

  3. Wählen Sie Fertig aus, um den Parameter zu erstellen.

Verwenden Sie einen abfragebasierten Parameter für die Einfachauswahl

  1. Die folgende Beispielabfrage mit dem neuen Parameter Status verwendet die Variable _state:

    StormEvents
    | where StartTime between (_startTime.._endTime)
    | where EventType in (_eventType) or isempty(_eventType)
    | where State == _state
    | summarize TotalEvents = count() by State
    | top 5 by TotalEvents
    

    Der neue Parameter wird in der Parameterliste oben im Dashboard angezeigt.

  2. Wählen Sie unterschiedliche Werte aus, um die visuellen Elemente zu aktualisieren.

Abfragebasierte Parameter für Mehrfachauswahl

Abfragebasierte Parameterwerte stammen aus der Ausführung einer vom Benutzer angegebenen Abfrage, wenn das Dashboard geladen wird. Das folgende Beispiel zeigt, wie Sie einen abfragebasierten Parameter mit mehrfacher Auswahl erstellen.

Abfragebasierten Parameter für Mehrfachauswahl erstellen

  1. Wählen Sie "Parameter" aus, um den Bereich "Parameter " zu öffnen, und wählen Sie dann +Neuer Parameter aus.

  2. Geben Sie die Details ein, wie unter Erstellen eines abfragebasierten Einzelauswahlparameters beschrieben, mit den folgenden Änderungen:

    • Bezeichnung: Status
    • Parametertyp: Mehrfachauswahl
    • Variablenname: _state
  3. Wählen Sie Fertig aus, um den Parameter zu erstellen.

Verwenden eines abfragebasierten Parameters für Mehrfachauswahl

  1. Die folgende Beispielabfrage verwendet den neuen Parameter Status unter Verwendung der Variablen _state.

    StormEvents
    | where StartTime between (_startTime.._endTime)
    | where EventType in (_eventType) or isempty(_eventType)
    | where State in (_state) or isempty(_state)
    | summarize TotalEvents = count() by State
    | top 5 by TotalEvents
    

    Hinweis

    In diesem Beispiel wird die Option Alle auswählen verwendet, indem mit der Funktion isempty() auf leere Werte überprüft wird.

    Der neue Parameter wird in der Parameterliste oben im Dashboard angezeigt.

  2. Wählen Sie einen oder mehrere unterschiedliche Werte aus, um die visuellen Elemente zu aktualisieren.

Freitext-Parameter

Parameter für freien Text enthalten keine Werte. Sie ermöglichen Ihnen die Eingabe eines eigenen Werts.

Erstellen eines Parameters für freien Text

  1. Wählen Sie "Parameter" aus, um den Bereich "Parameter " zu öffnen, und wählen Sie dann +Neuer Parameter aus.
  2. Geben Sie die folgenden Details ein:
    • Bezeichnung: Status
    • Parametertyp: Freier Text
    • Variablenname: _state
    • Datentyp: Zeichenfolge
    • Standardwert: Kein Standardwert
  3. Wählen Sie Fertig aus, um den Parameter zu erstellen.

Einen freien Text-Parameter verwenden

  1. Führen Sie eine Beispielabfrage mit dem neuen Parameter Status aus, indem Sie den Variablennamen _state verwenden:

    StormEvents
    | where StartTime between (_startTime.._endTime)
    | where EventType in (_eventType) or isempty(_eventType)
    | where State contains _state
    | summarize TotalEvents = count() by State
    | top 5 by TotalEvents
    

Datenquellenparameter

Nachdem Sie Ihrem Dashboard Datenquellen hinzugefügt haben, können Sie einen Parameter erstellen, der eine oder mehrere der verfügbaren Datenquellen auswählt. Verwenden Sie diesen Parameter in Kacheln und anderen Parametern.

Erstellen eines Datenquellen-Parameters

  1. Wählen Sie "Parameter" aus, um den Bereich "Parameter " zu öffnen, und wählen Sie dann +Neuer Parameter aus.

  2. Geben Sie die folgenden Details ein:

    • Bezeichnung: Quelle
    • Parametertyp: Datenquelle
    • Auf Seiten anzeigen: Alle auswählen
    • Werte: Alle auswählen
    • Standardwert: StormEvents

    Screenshot der Datenquellen-Parameter.

  3. Wählen Sie Fertig aus.

Die Parameterliste oben im Dashboard zeigt nun den neuen Parameter an.

Verwenden eines Datenquellen-Parameters

  1. Wechseln Sie zur Abfrage für eine neue oder bestehende Kachel.

  2. Wählen Sie in Quelle den Namen des neuen Parameters unter Datenquellen-Parameter aus, z. B. den neuen Quellen-Parameter .

    Screenshot der Auswahl eines Datenquellen-Parameters in der Abfrage.

  3. Wählen Sie Änderungen übernehmen aus.

  4. Verwenden Sie den Parameter Quelle , um die Datenquelle für diese verbundene Abfrage zu ändern.

Verwenden Sie die Filtersuche für Einzelauswahl- und Mehrfachauswahlfilter

Geben Sie in Filter für die Einzelauswahl und mehrfachauswahl den gewünschten Wert ein. Der Filter wird aktualisiert, um nur Werte anzuzeigen, die dem Suchbegriff entsprechen.