References.ItemRemoved-Ereignis (Access)

Das ItemRemoved-Ereignis tritt auf, wenn ein Verweis aus dem Projekt entfernt wird.

Syntax

Ausdruck verwendet werden. ItemRemoved (Reference)

Ausdruck Eine Variable, die ein References-Objekt darstellt.

Parameter

Hinweise

Das ItemRemoved-Ereignis gilt für die References-Auflistung . Es ist nicht mit einem Steuerelement, Formular oder Bericht verknüpft, wie die meisten anderen Ereignisse. Daher müssen Sie eine spezielle Syntax verwenden, um eine Prozedurdefinition für die ItemRemoved-Ereignisprozedur zu erstellen.

Das ItemRemoved-Ereignis kann nur eine Ereignisprozedur ausführen, wenn es auftritt. Ein Makro kann nicht ausgeführt werden.

Dieses Ereignis tritt nur auf, wenn Sie einen Verweis aus dem Code entfernen. Es tritt nicht auf, wenn Sie einen Verweis aus dem Dialogfeld Verweise entfernen, verfügbar durch Auswahl von Verweise im Menü Extras , wenn das Modulfenster das aktive Fenster ist.

Beispiel

Das folgende Beispiel enthält Ereignisprozeduren für die Ereignisse ItemAdded und ItemRemoved . Erstellen Sie in diesem Beispiel zunächst ein neues Klassenmodul, indem Sie im Menü Einfügen die Option Klassenmodul auswählen. Fügen Sie den folgenden Code in das Klassenmodul ein, und speichern Sie das Modul als RefEvents.

' Declare object variable to represent References collection. 
Public WithEvents evtReferences As References 
 
' When instance of class is created, initialize evtReferences 
' variable. 
Private Sub Class_Initialize() 
 Set evtReferences = Application.References 
End Sub 
 
' When instance is removed, set evtReferences to Nothing. 
Private Sub Class_Terminate() 
 Set evtReferences = Nothing 
End Sub 
 
' Display message when reference is added. 
Private Sub evtReferences_ItemAdded(ByVal Reference As _ 
 Access.Reference) 
 MsgBox "Reference to " & Reference.Name & " added." 
End Sub 
 
' Display message when reference is removed. 
Private Sub evtReferences_ItemRemoved(ByVal Reference As _ 
 Access.Reference) 
 MsgBox "Reference to " & Reference.Name & " removed." 
End Sub

Die folgende Funktionsprozedur entfernt einen angegebenen Verweis. Wenn ein Verweis entfernt wird, wird die in der RefEvents-Klasse definierte ItemRemoved-Ereignisprozedur ausgeführt.

Um beispielsweise einen Verweis auf das Kalender-Steuerelement zu entfernen, können Sie die Zeichenfolge "CalendarObjects" übergeben; das ist der Name des Reference-Objekts, der das Kalender-Steuerelement darstellt.

Function RemoveReference(strRefName As String) As Boolean 
 Dim ref As Reference 
 
 On Error GoTo Error_RemoveReference 
 ' Return object representing existing reference. 
 Set ref = objRefEvents.evtReferences(strRefName) 
 ' Remove reference from collection. 
 objRefEvents.evtReferences.Remove ref 
 RemoveReference = True 
 
Exit_RemoveReference: 
 Exit Function 
 
Error_RemoveReference: 
 MsgBox Err & ": " & Err.Description 
 RemoveReference = False 
 Resume Exit_RemoveReference 
End Function

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.