AddIn-Objekt (Excel)

Stellt ein einzelnes installiertes oder nicht installiertes Add-In dar.

Hinweise

Das AddIn -Objekt ist ein Mitglied der AddIns -Auflistung. Die AddIns -Auflistung enthält eine Liste aller installierten und nicht installierten Add-Ins, die in Microsoft Excel zur Verfügung stehen. Diese Liste entspricht der im Dialogfeld Add-Ins angezeigten Liste.

Beispiel

Verwenden Sie AddIns (Index), wobei index der Titel oder die Indexnummer des Add-Ins ist, um ein einzelnes AddIn-Objekt zurückzugeben. Im folgenden Beispiel wird das Analysis Toolpak-Add-In installiert.

AddIns("analysis toolpak").Installed = True

Verwechseln Sie nicht den Add-In-Titel, der im Dialogfeld "Add-Ins" angezeigt wird, mit dem Add-In-Namen, der der Dateiname des Add-Ins ist. Die Schreibweise des Add-In-Titels, nicht jedoch die Groß-/Kleinschreibung, muss mit der Schreibweise im Dialogfeld Add-Ins übereinstimmen.

Die Indexzahl stellt die Position des Add-Ins im Feld Verfügbare Add-Ins im Dialogfeld Add-Ins dar. Mit dem folgenden Beispiel wird eine Liste erstellt, die die angegebenen Eigenschaften der verfügbaren Add-Ins enthält.

With Worksheets("sheet1") 
 .Rows(1).Font.Bold = True 
 .Range("a1:d1").Value = _ 
 Array("Name", "Full Name", "Title", "Installed") 
 For i = 1 To AddIns.Count 
 .Cells(i + 1, 1) = AddIns(i).Name 
 .Cells(i + 1, 2) = AddIns(i).FullName 
 .Cells(i + 1, 3) = AddIns(i).Title 
 .Cells(i + 1, 4) = AddIns(i).Installed 
 Next 
 .Range("a1").CurrentRegion.Columns.AutoFit 
End With

Die Add-In-Methode fügt der Liste der verfügbaren Add-Ins ein Add-In hinzu, installiert jedoch nicht das Add-In. Legen Sie die Installed -Eigenschaft des Add-Ins auf True fest, um das Add-In zu installieren.

Wenn Sie ein Add-In installieren möchten, das nicht in der Liste verfügbarer Add-Ins angezeigt wird, müssen Sie zuerst die Add -Methode verwenden und anschließend die Installed -Eigenschaft festlegen. Dies ist in einem einzigen Arbeitsschritt möglich, wie im folgenden Beispiel veranschaulicht wird (Sie müssen bei der Add -Methode den Namen des Add-Ins verwenden und nicht den Titel).

AddIns.Add("generic.xll").Installed = True

Verwenden Sie Arbeitsmappen (index), wobei index der Dateiname des Add-Ins (nicht der Titel) ist, um einen Verweis auf die Arbeitsmappe zurückzugeben, die einem geladenen Add-In entspricht. Sie müssen den Dateinamen verwenden, da geladene Add-Ins normalerweise nicht in der Arbeitsmappen-Auflistung angezeigt werden. In diesem Beispiel wird die Variable wb auf die Arbeitsmappe für Myaddin.xla festgelegt.

Set wb = Workbooks("myaddin.xla")

Im folgenden Beispiel wird die Variable wb der Arbeitsmappe für das Add-In analysis toolpak (Analyse-Funktionen) festgelegt.

Set wb = Workbooks(AddIns("analysis toolpak").Name)

Wenn die Installed-Eigenschaft"True" zurückgibt, die Aufrufe von Funktionen im Add-In aber trotzdem fehlschlagen, wird das Add-In möglicherweise nicht tatsächlich geladen. Dies liegt daran, dass das Add-In-Objekt die Existenz und den Installationsstatus des Add-Ins darstellt, nicht jedoch den tatsächlichen Inhalt der Add-In-Arbeitsmappe. Öffnen Sie die Add-In-Arbeitsmappe, um sicherzustellen, dass ein installiertes Add-In geladen wird.

Im folgenden Beispiel wird die Arbeitsmappe für das Add-In mit dem Namen "Mein Add-In" geöffnet, wenn das Add-In nicht bereits in der Arbeitsmappen-Auflistung vorhanden ist.

On Error Resume Next ' turn off error checking 
Set wbMyAddin = Workbooks(AddIns("My Addin").Name) 
lastError = Err 
On Error Goto 0 ' restore error checking 
If lastError <> 0 Then 
 ' the add-in workbook isn't currently open. Manually open it. 
 Set wbMyAddin = Workbooks.Open(AddIns("My Addin").FullName) 
End If

Eigenschaften

Siehe auch

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.

  • Last updated on