IconSetCondition-Objekt (Excel)

Stellt eine Regel zur bedingten Formatierung von Symbolsätzen dar.

Hinweise

Alle Objekte der bedingten Formatierung sind in einem FormatConditions-Auflistungsobjekt enthalten, das ein untergeordnetes Element einer Range-Auflistung ist.

Sie können eine Formatierungsregel für Symbolsätze erstellen, indem Sie entweder dieAdd-Methode oder die AddIconSetCondition-Methode der FormatConditions-Auflistung verwenden.

Jeder Symbolsatz enthält drei, vier oder fünf Symbole. Verwenden Sie die IconSets-Eigenschaft des Workbook-Objekts, um ein IconSets-Objekt zurückzugeben, mit dem Sie einen der integrierten Symbolsätze angeben können. Jedes einzelne Symbol im Symbolsatz wird dann von den Elementen des IconCriteria-Objekts einer Teilmenge der Werte des Bereichs zugewiesen. Der Typ des Schwellenwerts wird ebenfalls von diesem Objekt angegeben.

Beispiel

Im folgenden Codebeispiel wird ein Zahlenbereich erstellt, der Testergebnisse darstellt, und dann eine symbolfestgelegte Regel zur bedingten Formatierung auf diesen Bereich angewendet. Der Typ des Symbolsatzes wird dann von den Standardsymbolen in einen Symbolsatz mit fünf Pfeilen geändert. Schließlich wird der Schwellenwerttyp von einem Perzentil in eine hartcodierte Zahl geändert.

Sub CreateIconSetCF() 
 
    Dim cfIconSet As IconSetCondition 
     
    'Fill cells with sample data from 1 to 10 
    With ActiveSheet 
        .Range("C1") = 55 
        .Range("C2") = 92 
        .Range("C3") = 88 
        .Range("C4") = 77 
        .Range("C5") = 66 
        .Range("C6") = 93 
        .Range("C7") = 76 
        .Range("C8") = 80 
        .Range("C9") = 79 
        .Range("C10") = 83 
        .Range("C11") = 66 
        .Range("C12") = 74 
    End With 
     
    Range("C1:C12").Select 
         
    'Create an icon set conditional format for the created sample data range 
    Set cfIconSet = Selection.FormatConditions.AddIconSetCondition 
     
    'Change the icon set to a five-arrow icon set 
    cfIconSet.IconSet = ActiveWorkbook.IconSets(xl5Arrows) 
     
    'The IconCriterion collection contains all IconCriteria 
    'By indexing into the collection you can modify each criterion 
 
    With cfIconSet.IconCriteria(1) 
        .Type = xlConditionValueNumber 
        .Value = 0 
        .Operator = 7 
    End With 
    With cfIconSet.IconCriteria(2) 
        .Type = xlConditionValueNumber 
        .Value = 60 
        .Operator = 7 
    End With 
    With cfIconSet.IconCriteria(3) 
        .Type = xlConditionValueNumber 
        .Value = 70 
        .Operator = 7 
    End With 
    With cfIconSet.IconCriteria(4) 
        .Type = xlConditionValueNumber 
        .Value = 80 
        .Operator = 7 
    End With 
    With cfIconSet.IconCriteria(5) 
        .Type = xlConditionValueNumber 
        .Value = 90 
        .Operator = 7 
    End With 
         
End Sub

Methoden

Eigenschaften

Siehe auch

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.

  • Last updated on