Range.Rows-Eigenschaft (Excel)

Gibt ein Range-Objekt zurück, das die Zeilen im angegebenen Bereich darstellt.

Syntax

Ausdruck verwendet werden. Zeilen

Ausdruck Eine Variable, die ein Range-Objekt darstellt.

Hinweise

Um eine einzelne Zeile zurückzugeben, verwenden Sie die Item-Eigenschaft oder schließen Sie entsprechend einen Index in Klammern ein. Beispielsweise beide Selection.Rows(1) und Selection.Rows.Item(1) die erste Zeile der Auswahl zurückgeben.

Wenn diese Eigenschaft auf ein Range-Objekt angewendet wird, bei dem es sich um eine Mehrfachauswahl handelt, gibt sie nur Zeilen aus dem ersten Bereich des Bereichs zurück. Wenn das Range-ObjektsomeRange beispielsweise zwei Bereiche hat – A1:B2 und C3:D4 –,someRange.Rows.Count gibt es 2 und nicht 4 zurück. Wenn Sie diese Eigenschaft auf einen Bereich anwenden möchten, der möglicherweise eine Mehrfachmarkierung darstellt, prüfen Sie mit Areas.Count, ob dies der Fall ist. Wenn dies der Fall, durchlaufen Sie jeden Abschnitt in dem Bereich, wie im dritten Beispiel dargestellt.

Der zurückgegebene Bereich befindet sich möglicherweise außerhalb des angegebenen Bereichs. Im vorherigen Beispiel gibt Range("A1:B2").Rows(5) die Zellen A5:B5 zurück. Weitere Informationen finden Sie unter der Item-Eigenschaft .

Die Verwendung der Rows-Eigenschaft ohne einen Objektqualifizierer entspricht der Verwendung von ActiveSheet.Rows. Weitere Informationen finden Sie unter der Worksheet.Rows-Eigenschaft .

Beispiel

In diesem Beispiel wird der Bereich B4:Z4 in Tabelle1 der aktiven Arbeitsmappe gelöscht.

Worksheets("Sheet1").Range("B2:Z44").Rows(3).Delete

Dieses Beispiel löscht Zeilen im aktuellen Bereich auf Arbeitsblatt eins der aktiven Arbeitsmappe, in denen der Wert von Zelle eins in der Zeile mit dem Wert von Zelle eins in der vorherigen Zeile übereinstimmt.

For Each rw In Worksheets(1).Cells(1, 1).CurrentRegion.Rows
   this = rw.Cells(1, 1).Value 
   If this = last Then rw.Delete 
   last = this 
Next

In diesem Beispiel wird die Anzahl der Zeilen in der Markierung in Tabelle1 angezeigt. Liegt eine Mehrfachmarkierung vor, werden alle Teile der Mehrfachmarkierung in einer Schleife bearbeitet.

Public Sub ShowNumberOfRowsInSheet1Selection
   Worksheets("Sheet1").Activate 
   
   Dim selectedRange As Excel.Range
   Set selectedRange = Selection
   
   Dim areaCount As Long
   areaCount = Selection.Areas.Count 
   
   If areaCount <= 1 Then 
      MsgBox "The selection contains " & _ 
             Selection.Rows.Count & " rows." 
   Else 
      Dim areaIndex As Long
      areaIndex = 1 
      For Each area In Selection.Areas 
         MsgBox "Area " & areaIndex & " of the selection contains " & _ 
                area.Rows.Count & " rows." 
         areaIndex = areaIndex + 1 
      Next 
   End If
End Sub

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.