Range.Text-Eigenschaft (Excel)

Gibt den formatierten Text für das angegebene Objekt zurück. Schreibgeschützte Zeichenfolge.

Syntax

Ausdruck verwendet werden. Text

Ausdruck Eine Variable, die ein Range-Objekt darstellt.

Hinweise

Die Text-Eigenschaft wird am häufigsten für einen Bereich von einer Zelle verwendet. Wenn der Bereich mehrere Zellen enthält, gibt die Text-EigenschaftNULL zurück, es sei denn, alle Zellen im Bereich weisen identische Inhalte und Formate auf.

Wenn der Inhalt der Zelle breiter als die zur Anzeige verfügbare Breite ist, ändert die Text-Eigenschaft den angezeigten Wert.

Beispiel für Unterschiede in Eigenschaft

Dieses Beispiel veranschaulicht den Unterschied zwischen den Text - und Werteigenschaften von Zellen, die formatierte Zahlen enthalten.

Option Explicit

Public Sub DifferencesBetweenValueAndTextProperties()
    Dim cell As Range
    Set cell = Worksheets("Sheet1").Range("A1")
    cell.Value = 1198.3
    cell.NumberFormat = "$#,##0_);($#,##0)"
    
    MsgBox "'" & cell.Value & "' is the value." 'Returns: "'1198.3' is the value."
    MsgBox "'" & cell.Text & "' is the text."    'Returns: "'$1,198' is the text."
End Sub

Unterschiede in der Textbreite

Der angezeigte Wert für Zellen mit numerischen Werten wird möglicherweise geändert, wenn die Spalte nicht breit genug ist. Das folgende Beispiel zeigt dies anhand von zwei Spalten. Die erste Spalte ist breit genug, um die Werte anzuzeigen. Es wird ein Format angewendet, und dann wird ein Wert mit dem vollständigen Wert eingegeben. Die Breite der zweiten Spalte ist so reduziert, dass sie beim Kopieren der Zellen zu schmal ist, wodurch der angezeigte Wert verschoben wird.

Public Sub TextWidthDifferences()
    
    Dim wideColumn As Range
    Set wideColumn = Sheet1.Range("B2")
    wideColumn.Value = "Wide Enough Column"
    wideColumn.Columns.AutoFit
    
    Sheet1.Range("B3").Value2 = 123456789
    
    Const CurrencyWith2DecimalsFormat As String = "$#,##0.00"
    Dim currencyCell As Range
    Set currencyCell = Sheet1.Range("B4")
    currencyCell.Value2 = 1234.56
    currencyCell.NumberFormat = CurrencyWith2DecimalsFormat
    
    Dim narrowColumn As Range
    Set narrowColumn = Sheet1.Range("C2")
    narrowColumn.Value = "Reduced Width Column"
    narrowColumn.ColumnWidth = 7.5
    
    Sheet1.Range("B3:B4").AutoFill Destination:=Sheet1.Range("B3:C4"), Type:=XlAutoFillType.xlFillDefault
    Debug.Print Sheet1.Range("C3").Text
    Debug.Print Sheet1.Range("C4").Text
End Sub

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.