Hinweis
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, sich anzumelden oder das Verzeichnis zu wechseln.
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, das Verzeichnis zu wechseln.
Exportiert Kalenderinformationen aus dem übergeordneten Ordner des CalendarSharing-Objekts als iCalendar-Kalenderdatei (.ics).
Syntax
Ausdruck.
SaveAsICal( _Path_ )
expression Ein Ausdruck, durch den ein CalendarSharing-Objekt zurückgegeben wird.
Parameter
| Name | Erforderlich/Optional | Datentyp | Beschreibung |
|---|---|---|---|
| Path | Erforderlich | String | Der Pfad und Dateiname der iCalendar-Datei. |
Hinweise
Die in der iCalendar-Datei bereitgestellte Detailebene, die durch eine Kombination aus Werten in den folgenden CalendarSharing-Eigenschaften bestimmt wird:
Sie können die IncludeWholeCalendar-Eigenschaft auf TRUE festlegen, um alle im Ordner enthaltenen Elemente zu exportieren, oder Sie können die StartDate- und EndDate-Eigenschaften festlegen, um die exportierten Elemente auf einen Datumsbereich zwischen einem angegebenen Start- bzw. Enddatum zu beschränken.
Beispiel
Im folgenden Visual Basic for Applications-Beispiel (VBA) wird ein CalendarSharing-Objekt für den Ordner Calendar erstellt und dann der Inhalt des gesamten Ordners (einschließlich Anlagen und privater Elemente) in eine iCalendar-Kalenderdatei (.ics) exportiert.
Public Sub ExportEntireCalendar()
Dim oNamespace As NameSpace
Dim oFolder As Folder
Dim oCalendarSharing As CalendarSharing
On Error GoTo ErrRoutine
' Get a reference to the Calendar default folder
Set oNamespace = Application.GetNamespace("MAPI")
Set oFolder = oNamespace.GetDefaultFolder(olFolderCalendar)
' Get a CalendarSharing object for the Calendar default folder.
Set oCalendarSharing = oFolder.GetCalendarExporter
' Set the CalendarSharing object to export the contents of
' the entire Calendar folder, including attachments and
' private items, in full detail.
With oCalendarSharing
.CalendarDetail = olFullDetails
.IncludeWholeCalendar = True
.IncludeAttachments = True
.IncludePrivateDetails = True
.RestrictToWorkingHours = False
End With
' Export calendar to an iCalendar calendar (.ics) file.
oCalendarSharing.SaveAsICal "C:\SampleCalendar.ics"
EndRoutine:
On Error GoTo 0
Set oCalendarSharing = Nothing
Set oFolder = Nothing
Set oNamespace = Nothing
Exit Sub
ErrRoutine:
Select Case Err.Number
Case 287 ' &H0000011F
' The user denied access to the Address Book.
' This error occurs if the code is run by an
' untrusted application, and the user chose not to
' allow access.
MsgBox "Access to Outlook was denied by the user.", _
vbOKOnly, _
Err.Number & " - " & Err.Source
Case -2147467259 ' &H80004005
' Export failed.
' This error typically occurs if the CalendarSharing
' method cannot export the calendar information because
' of conflicting property settings.
MsgBox Err.Description, _
vbOKOnly, _
Err.Number & " - " & Err.Source
Case -2147221233 ' &H8004010F
' Operation failed.
' This error typically occurs if the GetCalendarExporter method
' is called on a folder that doesn't contain calendar items.
MsgBox Err.Description, _
vbOKOnly, _
Err.Number & " - " & Err.Source
Case Else
' Any other error that may occur.
MsgBox Err.Description, _
vbOKOnly, _
Err.Number & " - " & Err.Source
End Select
GoTo EndRoutine
End Sub
Siehe auch
Support und Feedback
Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.