ShapeRange.LockAspectRatio-Eigenschaft (Projekt)

Ruft einen Wert ab, der angibt, ob der Formbereich seine ursprünglichen Proportionen beibehält, wenn Sie die Größe ändern; Das heißt, das Seitenverhältnis des Formbereichs ist gesperrt. MsoTriState mit Lese-/Schreibzugriff.

Syntax

Ausdruck verwendet werden. LockAspectRatio

Ausdruck Eine Variable, die ein 'ShapeRange'-Objekt darstellt.

Hinweise

Der LockAspectRatio-Wert ist msoTrue , wenn der Formbereich seine ursprünglichen Proportionen beibehält, wenn die Größe geändert wird. Wenn Sie Höhe und Breite des Formbereichs unabhängig voneinander ändern können, lautet der Wert "msoFalse".

Beispiel

Im folgenden Beispiel werden zwei Formenbereiche erstellt, mit einem Dreieck und einem Zahnrad gleicher Größe in jedem Formbereich. Im linken Formbereich ist das Seitenverhältnis freigeschaltet, und im rechten Formbereich ist das Seitenverhältnis gesperrt. Abbildung 1 zeigt das Ergebnis, wenn die Größe jedes Formbereichs um den gleichen Betrag geändert wird.

Änderungen an einem Formbereich werden auf jedes Shape im Bereich angewendet.

Sub ResizeShapeRanges()
    Dim shapeReport As Report
    Dim reportName As String
    Dim triangle1 As shape
    Dim triangle2 As shape
    Dim gear1 As shape
    Dim gear2 As shape
    Dim sRange1 As ShapeRange
    Dim sRange2 As ShapeRange
    
    reportName = "ShapeRange resize report"
    Set shapeReport = ActiveProject.Reports.Add(reportName)
    
    With shapeReport.Shapes
        Set triangle1 = .AddShape(msoShapeIsoscelesTriangle, 10, 10, 100, 100)
        Set gear1 = .AddShape(msoShapeGear6, 10, 120, 100, 100)
        Set triangle2 = .AddShape(msoShapeIsoscelesTriangle, 150, 10, 100, 100)
        Set gear2 = .AddShape(msoShapeGear6, 150, 120, 100, 100)
        
        gear2.BackgroundStyle = msoBackgroundStylePreset3
        
        Set sRange1 = .Range(Array(1, 2))
        Set sRange2 = .Range(Array(3, 4))
    End With
       
    sRange1.LockAspectRatio = msoFalse
    sRange1.height = 200
    
    ' Set a yellow shape style for gear1.
    sRange1(2).ShapeStyle = msoShapeStylePreset26
    
    sRange2.LockAspectRatio = msoTrue
    sRange2.height = 200
    
    sRange2.Select
End Sub

In Abbildung 1 ist der rechte Formbereich mit dem gesperrten Seitenverhältnis ausgewählt.

Abbildung 1: Ändern der Größe eines Formbereichs, wenn das Seitenverhältnis entsperrt oder gesperrt ist

Eigenschaftswert

MSOTRISTATE

Siehe auch

ShapeRange-ObjektShape.LockAspectRatio-EigenschaftMsoTriState

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.