Shapes.AddCallout-Methode (Projekt)

Erstellt eine randlose Linienbeschriftung in einem Bericht. Gibt ein Shape-Objekt zurück, das den neuen Text mit Zusatzinformationen darstellt.

Syntax

Ausdruck. AddCallout (Typ,Links,Oben,Breite,Höhe)

expression Eine Variable, die ein Shapes-Objekt darstellt.

Parameter

Name Erforderlich/Optional Datentyp Beschreibung
Typ Erforderlich MsoCalloutType Der Legendentyp.
Left Erforderlich Single Die Position (in Punkt) des linken Rands des Begrenzungsrahmens für die Legende.
Top Erforderlich Single Die Position (in Punkt) des oberen Rands des Begrenzungsrahmens für die Legende.
Width Erforderlich Single Die Breite des Begrenzungsrahmens für die Legende in Punkten.
Height Erforderlich Single Die Höhe des Begrenzungsrahmens für die Legende in Punkten.
Typ Erforderlich MSOCALLOUTTYPE
Left Erforderlich FLOAT
Top Erforderlich FLOAT
Width Erforderlich FLOAT
Height Erforderlich FLOAT

Rückgabewert

Shape

Hinweise

Der Parameter Type kann eine der folgenden MsoCalloutType-Konstanten sein:
msoCalloutOne: Eine Einsegment-Calloutline, die horizontal oder vertikal sein kann.
msoCalloutTwo: Eine Einsegment-Calloutline, die sich frei drehen lässt.
msoCalloutMixed: Ein Rückgabewert, der eine Kombination der anderen Zustände angibt.
msoCalloutThree: Eine Linie mit zwei Segmenten, bei der die Segmentenden an verschiedene Positionen gezogen werden können.
msoCalloutFour: Eine Linie mit drei Segmenten.

Mit der AddShape-Methode können Sie eine größere Auswahl an Legenden einfügen, z. B. Sprechblasen und Wolken.

Beispiel

Im folgenden Beispiel wird eine Legende mit einer Legendenlinie aus zwei Segmenten hinzugefügt, der Winkel des Endsegments auf 60 Grad von der Vertikalen festgelegt und der Legende Text hinzugefügt.

Sub AddCallout()
    Dim oReports As Reports
    Dim oReport As Report
    Dim calloutShape As shape
    Dim reportName As String
    
    reportName = "Report 1"
    Set oReports = ActiveProject.Reports

    If oReports.IsPresent(reportName) Then
        ' Make the report the active view.
        oReports(reportName).Apply
        
        Set oReport = oReports(reportName)
        
        Set calloutShape = oReport.Shapes.AddCallout(Type:=msoCalloutTwo, _
                                        left:=200, top:=5, width:=100, height:=50)
        With calloutShape
            .Callout.Type = msoCalloutThree
            .Callout.Angle = msoCalloutAngle60
            .BackgroundStyle = msoBackgroundStylePreset10
            .TextFrame2.TextRange.Text = "This is a test"
        End With
    Else
         MsgBox Prompt:="The requested report, '" & reportName _
            & "', does not exist.", Title:="Report error"
    End If
End Sub

Siehe auch

Shapes-ObjektShape-ObjektAddShape-Methode

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.

  • Last updated on