Curve.Start-Eigenschaft (Visio)

Gibt den Anfang der Parameterdomäne eines Curve-Objekts zurück. Schreibgeschützt.

Syntax

Ausdruck verwendet werden. Starten

Ausdruck Eine Variable, die ein Curve-Objekt darstellt.

Rückgabewert

Gleitkommawert mit doppelter Genauigkeit

Hinweise

Die Start-Eigenschaft eines Curve-Objekts gibt den Wert des Startpunkts in der Parameterdomäne der Kurve zurück. Ein Curve-Objekt beschreibt sich selbst anhand seiner Parameterdomäne, bei der es sich um den Bereich [Start(),End()] handelt, in dem Start() den Ausgangspunkt der Kurve erzeugt. Beachten Sie, dass der Startwert kein Koordinatenpaar ist. Vielmehr stellt sie die relative Position entlang der Kurve des Startpunkts dar. Für eine Linie ist beispielsweise der Wert von Start in der Regel 0, der Wert von End ist 1, und Sie können die Point-Methode des Curve-Objekts verwenden, um die Koordinaten eines beliebigen Punktes entlang der Kurve zu bestimmen, indem Sie die relative Position des Punktes zwischen dem Start und den Endpunkten bestimmen.

Beispiel

Dieses Microsoft Visual Basic for Applications (VBA)-Makro zeigt, wie Sie die Start-Eigenschaft verwenden, um den Wert des Startpunkts einer Kurve anzuzeigen. Es wird die Point-Methode verwendet, um den mittleren Punkt der Kurve zu ermitteln.

 
Sub Start_Example() 
 
 Dim vsoShape As Visio.Shape 
 Dim vsoPaths As Visio.Paths 
 Dim vsoPath As Visio.Path 
 Dim vsoCurve As Visio.Curve 
 Dim dblStartpoint As Double 
 Dim dblEndpoint As Double 
 Dim dblX As Double 
 Dim dblY As Double 
 Dim intOuterLoopCounter As Integer 
 Dim intInnerLoopCounter As Integer 
 
 'Draw a shape and get its Paths collection. 
 Set vsoPaths = ActivePage.DrawOval(1, 1, 4, 4).Paths 
 
 'Iterate through the Path objects in the Paths collection. 
 For intOuterLoopCounter = 1 To vsoPaths.Count 
 
 Set vsoPath = vsoPaths.Item(intOuterLoopCounter) 
 Debug.Print "Path object " & intOuterLoopCounter 
 
 'Iterate through the curves in a Path object. 
 For intInnerLoopCounter = 1 To vsoPath.Count 
 
 Set vsoCurve = vsoPath(intInnerLoopCounter) 
 Debug.Print "Curve number " & intInnerLoopCounter 
 
 'Display the start point of the curve. 
 dblStartpoint = vsoCurve.Start 
 Debug.Print "Startpoint = " & dblStartpoint 
 
 'Display the endpoint of the curve. 
 dblEndpoint = vsoCurve.End 
 Debug.Print "Endpoint = " & dblEndpoint 
 
 'Find the midpoint of the curve. 
 vsoCurve.Point ((dblEndpoint - dblStartpoint) / 2), dblX, dblY 
 Debug.Print "Midpoint: x = " & dblx; ", y = " & dblY 
 
 Next intInnerLoopCounter 
 Debug.Print "This path has " & intInnerLoopCounter - 1 & " curve object(s)." 
 
 Next intOuterLoopCounter 
 Debug.Print "This shape has " & intOuterLoopCounter - 1 & " path object(s)." 
 
End Sub

Support und Feedback

Haben Sie Fragen oder Feedback zu Office VBA oder zu dieser Dokumentation? Unter Office VBA-Support und Feedback finden Sie Hilfestellung zu den Möglichkeiten, wie Sie Support erhalten und Feedback abgeben können.