Objetos visuales específicos del panel

Todas las visualizaciones que cree en el contexto del operador render están disponibles en las visualizaciones del panel. Sin embargo, las visualizaciones siguientes solo están disponibles en los paneles de Azure Data Explorer, paneles de control en tiempo real, o en la interfaz de usuario web de Azure Data Explorer, y no están disponibles mediante el operador render.

Para obtener información sobre cómo personalizar cualquier objeto visual de panel, consulte Personalización de objetos visuales de panel Azure Data Explorer.

Para obtener información general sobre los paneles de Azure Data Explorer, consulte Visualización de datos con paneles de Azure Data Explorer.

Stat

Puedes usar Stat en Azure Data Explorer paneles y Fabric Real-Time paneles. Muestra un único valor escalar. Seleccionarlo desde el selector visual del tablero.

Ejemplo de consulta

StormEvents
| summarize TotalEvents = count()

Selecciona Estadística como tipo visual.

Estadísticas múltiples

Multi Stat muestra varios valores en una cuadrícula de ranuras. Selecciona el visual desde el selector visual del tablero.

La consulta debe devolver una columna de etiqueta y una columna de valor. Puedes seleccionar explícitamente la columna Etiqueta y la columna Valor en la configuración visual.

Ejemplo de consulta

datatable(Status:string, Count:long)
[
    "Active", 42,
    "Mitigated", 18,
    "Resolved", 73
]

En la configuración visual, selecciona la primera columna de salida como la columna de Etiqueta y la segunda columna de salida como la columna de Valor.

Gráfico de embudo

Los gráficos de embudo visualizan un proceso lineal con fases secuenciales conectadas. Cada fase del embudo representa un porcentaje del total. Por lo tanto, en la mayoría de los casos, un gráfico de embudo tiene la forma de embudo: la primera fase es la más grande y cada fase posterior es menor que su predecesora.

En el ejemplo siguiente se usan datos de la base de datos ContosoSales del clúster de ayuda disponible públicamente para mostrar el número de ventas de lavadoras y secadoras en Canadá fuera de la suma total de ventas en 2007.

Ejemplo de consulta

let interestingSales = SalesTable
| where DateKey between (datetime(2007) .. datetime(2008))
| join kind=inner Products on ProductKey;
let totalSales = interestingSales
| summarize sum(SalesAmount)
| extend Name="Total";
//totalSales
let homeAppliancesSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| summarize sum(SalesAmount)
| extend Name="Home Appliances";
//homeAppliancesSales
let washersAndDryersSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| where ProductSubcategoryName == "Washers & Dryers"
| summarize sum(SalesAmount)
| extend Name="Washers & Dryers";
//washersAndDryersSales
let canadaSales = interestingSales
| where ProductCategoryName == "Home Appliances"
| where ProductSubcategoryName == "Washers & Dryers"
| where Country == "Canada"
| summarize sum(SalesAmount)
| extend Name="Canada";
//canadaSales
totalSales
| union homeAppliancesSales
| union washersAndDryersSales
| union canadaSales
| project Name, SalesAmount=sum_SalesAmount
| sort by SalesAmount desc

Mapa térmico

Un mapa térmico muestra los valores de una variable principal de interés en dos variables de eje como una cuadrícula de cuadrados coloreados.

Para representar un mapa térmico, la consulta debe generar una tabla con tres columnas. Los datos usados para el campo valor deben ser numéricos. Las columnas que se usarán para los valores x e y usan las reglas siguientes:

• Si los valores de la columna x tienen el formato string, los valores de la columna y deben tener el formato string.
• Si los valores de la columna x tienen el formato datetime, los valores de la columna y deben ser numéricos.

Ejemplo de consulta

StormEvents
| summarize count(EventId) by State, EventType