Método Report.Circle (Access)

El método Círculo dibuja un círculo, una elipse o un arco en un objeto Informe cuando se produce el evento Imprimir .

Sintaxis

más sencilla.Círculo (paso (x, y), radio, color, inicio, fin, aspecto)

expresión Variable que representa un objeto Report .

Parameters

Nombre Tipo de datos Descripción
Paso Palabra clave Indica que el centro del círculo, la elipse o el arco es relativo a las coordenadas actuales proporcionadas por la configuración actual de las propiedades CurrentX y CurrentY del argumento Object .
(x, y) Single Indica las coordenadas del punto central del círculo, la elipse o el arco. Las propiedades de escala (ScaleMode, ScaleLeft, ScaleTop, ScaleHeight y ScaleWidth) del objeto Informe especificado por el argumento Object determinan la unidad de medida utilizada.
RADIUS Single Indica el radio del círculo, la elipse o el arco. Las propiedades de escala (ScaleMode, ScaleLeft, ScaleTop, ScaleHeight y ScaleWidth) del objeto Informe especificado por el argumento Object determinan la unidad de medida utilizada. De forma predeterminada, las distancias se miden en twips.
Color Long Indica el color RGB (rojo-verde-azul) del contorno del círculo. Si se omite este argumento, se usa el valor de la propiedad ForeColor. También puede usar la función RGB o QBColor para especificar el color.
Start Single Cuando se dibuja un círculo parcial o una elipse, el argumento Start especifica (en radianes) la posición inicial del arco. El valor predeterminado para el argumento Start es 0 radianes. El rango es de -2 pi radianes a 2 pi radianes.
End Single Cuando se dibuja un círculo parcial o una elipse, el argumento End especifica (en radianes) la posición final del arco. El valor predeterminado para el argumento End es 2 pi radianes. El rango es de -2 pi radianes a 2 pi radianes.
Aspecto Single Indica la relación de aspecto del círculo. El valor predeterminado es 1.0, que produce un círculo perfecto (no ovalado) en cualquier pantalla.

Comentarios

Use este método solo en un procedimiento de evento o una macro especificados por las propiedades de evento de una sección de informe, o la propiedad de evento OnPage de un informe.

Al dibujar un círculo parcial o una elipse, si el argumento Inicio es negativo, el método Círculo dibuja un radio a la posición especificada por el argumento Inicio y trata el ángulo como positivo. Si el argumento End es negativo, el método Circle dibuja un radio a la posición especificada por el argumento End y vuelve a tratar el ángulo como positivo. El método Circle siempre dibuja en el sentido contrario de las manecillas del reloj (dirección positiva).

Si desea rellenar un círculo, establezca las propiedades FillColor y FillStyle del informe. Sólo las figuras cerradas se pueden rellenar. Las figuras cerradas incluyen los círculos, elipses y sectores (arcos con líneas de radio dibujadas en ambos extremos).

Al dibujar rebanadas circulares, si necesita dibujar un radio con respecto al ángulo 0 para formar un segmento de línea horizontal a la derecha, especifique un valor negativo muy pequeño para el argumento Inicio en lugar de 0. Por ejemplo, puede especificar -.00000001 para el argumento Inicio .

Puede omitir un argumento en medio de la sintaxis, pero tiene que incluir la coma del argumento antes de incluir el siguiente argumento. Si omite un argumento final, no use ninguna coma después del último argumento que especifique.

El ancho de la línea utilizada para dibujar el círculo, la elipse o el arco depende del valor de la propiedad DrawWidth . La manera en que se dibuja el círculo en el fondo depende de la configuración de las propiedades DrawMode y DrawStyle .

Al aplicar el método Circle, las propiedades CurrentX y CurrentY se establecen como el centro especificado por los argumentos x e y.

Ejemplo

Este ejemplo usa el método Circle para dibujar un círculo y crear un sector circular de color rojo dentro del círculo.

Para probar este ejemplo en Microsoft Access, cree un nuevo informe. Establezca la propiedad AlImprimir (OnPrint) de la sección Detalles a [Procedimiento de evento]. Escriba el siguiente código en el módulo del informe y, a continuación, cambie a Vista previa de impresión.

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    Const conPI = 3.14159265359 
    Dim sngHCtr As Single, sngVCtr As Single 
    Dim sngRadius As Single 
    Dim sngStart As Single, sngEnd As Single 
 
    sngHCtr = Me.ScaleWidth / 2     ' Horizontal center. 
    sngVCtr = Me.ScaleHeight / 2     ' Vertical center. 
    sngRadius = Me.ScaleHeight / 3     ' Circle radius. 
    ' Draw circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius 
    sngStart = -0.00000001             ' Start of pie slice. 
    sngEnd = -2 * conPI / 3             ' End of pie slice. 
    Me.FillColor = RGB(255,0,0)     ' Color pie slice red. 
    Me.FillStyle = 0                     ' Fill pie slice. 
    ' Draw pie slice within circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius, , sngStart, sngEnd 
End Sub

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.

  • Last updated on