Método Application.AddSiteColumn (Project)

Agrega una columna que está disponible para la lista de tareas del sitio SharePoint sincronizado para el proyecto activo.

Sintaxis

más sencilla.AddSiteColumn (ProjectField, SharePointName)

expresión Variable que representa un objeto Application.

Parámetros

Valor devuelto

Boolean

Verdadero si se agrega la columna.

Comentarios

El método AddSiteColumn da el error en tiempo de ejecución 1004, "error definido por la aplicación o definido por el objeto", en los siguientes casos:

• El proyecto activo no está asociado a una lista de tareas sincronizadas de SharePoint. Si el proyecto es local, puede usar el método LinkToTaskList para crear una lista de tareas sincronizada de SharePoint.

• El nombre de la columna ya existe en la lista de tareas de SharePoint. Para ver la lista de nombres de columna, abra la lista de tareas en SharePoint y, a continuación, elija Modificar vista en la pestaña LISTA . La página Configuración > Editar vista muestra todos los nombres de columna que están disponibles para la lista de tareas.

• El valor ProjectField es un campo que no es de tarea, como pjResourceActualCost. Una lista de tareas de SharePoint muestra los campos de tareas, no los campos de recursos.

• El valor ProjectField es un campo personalizado de empresa como pjTaskEnterpriseProjectText1 o un campo de tabla de búsqueda como pjTaskResourceEnterpriseRBS. Los campos personalizados de tarea local, como pjTaskText1, son válidos.

• El valor ProjectField es uno de los campos prohibidos de la Tabla 1. Estos campos se suman a los campos de recursos prohibidos y los campos personalizados de empresa. Estos campos están prohibidos porque están relacionados con otros campos prohibidos o tienen tipos de valor que no se admiten en una lista predeterminada de tareas de SharePoint.

Aunque los campos prohibidos mostrados en la tabla siguiente pueden parecer una lista larga, de las 1.338 constantes de PjField, hay 357, incluidos los campos personalizados de tareas locales, que se pueden usar con el método AddSiteColumn .

Campos prohibidos adicionales

Es posible agregar un campo que ya existe en la lista de tareas si usa un nombre único para el parámetro SharePointName , aunque el valor de hacerlo es cuestionable.

Ejemplo

Para usar la macro AddDurationColumns, cree una lista de tareas en un sitio de SharePoint, cree un proyecto en Project Professional y, a continuación, use el método LinkToTaskList para importar la lista de tareas. Defina una línea base para el proyecto activo con el comando Establecer línea base de la pestaña PROYECTO de la cinta de opciones y cambie la duración de algunas tareas.

La macro AddDurationColumns agrega la duración de la tarea y la duración de la línea base a la lista de columnas disponibles en la lista de tareas de SharePoint (vea la figura 1).

Sub AddDurationColumns()
    Dim success As Boolean
    Dim results As String
    Dim columnName As String
    Dim fieldName As PjField
    results = ""
    
    ' Add the first column.
    fieldName = pjTaskBaselineDurationText
    columnName = "Baseline duration"
    
    ' If the field name exists in the SharePoint tasks list, or fieldName
    ' is one of the prohibited fields, the AddSiteColumn method
    ' returns error 1100.
    On Error Resume Next
    
    success = AddSiteColumn(fieldName, columnName)
    
    If success Then
        results = "Added site column: " & columnName
    Else
        results = "Error in AddSiteColumn: " & columnName
    End If
    
    ' Add the second column.
    fieldName = pjTaskDurationText
    columnName = "Current duration"
    
    success = AddSiteColumn(fieldName, columnName)
    
    If success Then
        results = results & vbCrLf & "Added site column: " & columnName
    Else
        results = results & vbCrLf & "Error in AddSiteColumn: " & columnName
    End If
    
    Debug.Print results
End Sub

Después de guardar el proyecto, vaya a la lista de tareas en SharePoint. En la pestaña LISTA, seleccione el comando Modificar vista. En la página Configuración - Editar vista, seleccione el campo Duración prevista y el campo Duración actual que agregó la macro AddDurationColumns . En la figura 1 se muestra la lista de tareas con los dos nuevos campos.

Figura 1. Adición de campos a una lista de tareas sincronizada de SharePoint

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.