Método Shapes.AddCallout (Project)

Crea una llamada de línea sin borde en un informe. Devuelve un objeto Shape que representa la nueva llamada.

Sintaxis

expresión. AddCallout (Tipo,Izquierda,Superior,Ancho,Alto)

expresión Variable que representa un objeto Shapes.

Parameters

Nombre Obligatorio/opcional Tipo de datos Descripción
Type Obligatorio MsoCalloutType Tipo de llamada.
Left Obligatorio Single La posición, en puntos, del borde izquierdo del cuadro delimitador para la llamada.
Top Obligatorio Single La posición, en puntos, del borde superior del cuadro delimitador de la llamada.
Width Obligatorio Single Ancho, en puntos, del cuadro delimitador de la llamada.
Height Obligatorio Single El alto, en puntos, del cuadro delimitador de la llamada.
Tipo Obligatorio MSOCALLOUTTYPE
Left Obligatorio FLOAT
Top Obligatorio FLOAT
Width Obligatorio FLOAT
Height Obligatorio FLOAT

Valor devuelto

Shape

Comentarios

El parámetro Type puede ser una de las siguientes constantes MsoCalloutType :
msoCalloutOne: una línea de llamada de un solo segmento que puede ser horizontal o vertical.
msoCalloutTwo: una línea de llamada de un solo segmento que gira libremente.
msoCalloutMixed: Un valor devuelto que indica una combinación de los otros estados.
msoCalloutThree: Una línea de dos segmentos, donde los extremos del segmento se pueden arrastrar a diferentes posiciones.
msoCalloutFour: una línea de tres segmentos.

Puede insertar una mayor variedad de globos, como globos y nubes, mediante el método AddShape .

Ejemplo

En el ejemplo siguiente se agrega una llamada con una línea de llamada de dos segmentos, se establece el ángulo del segmento final a 60 grados con respecto a la vertical y se agrega texto a la llamada.

Sub AddCallout()
    Dim oReports As Reports
    Dim oReport As Report
    Dim calloutShape As shape
    Dim reportName As String
    
    reportName = "Report 1"
    Set oReports = ActiveProject.Reports

    If oReports.IsPresent(reportName) Then
        ' Make the report the active view.
        oReports(reportName).Apply
        
        Set oReport = oReports(reportName)
        
        Set calloutShape = oReport.Shapes.AddCallout(Type:=msoCalloutTwo, _
                                        left:=200, top:=5, width:=100, height:=50)
        With calloutShape
            .Callout.Type = msoCalloutThree
            .Callout.Angle = msoCalloutAngle60
            .BackgroundStyle = msoBackgroundStylePreset10
            .TextFrame2.TextRange.Text = "This is a test"
        End With
    Else
         MsgBox Prompt:="The requested report, '" & reportName _
            & "', does not exist.", Title:="Report error"
    End If
End Sub

Vea también

Formas ObjetoForma ObjetoAddShape Método

Soporte técnico y comentarios

¿Tiene preguntas o comentarios sobre VBA para Office o esta documentación? Vea Soporte técnico y comentarios sobre VBA para Office para obtener ayuda sobre las formas en las que puede recibir soporte técnico y enviar comentarios.

  • Last updated on