SharePoint.Contents

Sintaxis

SharePoint.Contents(url as text, optional options as nullable record) as table

Acerca de

Devuelve una tabla jerárquica que contiene las carpetas y los archivos que se encuentran en el sitio de SharePoint especificado, url. La tabla muestra los elementos en el nivel actual y no devuelve recursivamente todos los archivos del sitio. En el caso de las carpetas, la Content columna contiene una tabla anidada que se puede usar para navegar al contenido de la carpeta. En el caso de los archivos, la Content columna contiene el contenido del archivo como un valor binario. Para devolver una tabla plana de todos los archivos del sitio y sus subcarpetas, use SharePoint.Files. Cada fila también contiene las Namecolumnas , Extension, Date accessedDate modified, Date created, , Attributes, y Folder Path . Las filas de carpeta tienen un valor vacío Extension . Date accessed es null para carpetas y archivos. El Folder Path valor es la dirección URL absoluta de la carpeta que contiene el elemento. La dirección URL del sitio no puede contener una cadena de consulta ni un fragmento. Se puede especificar options para controlar las siguientes opciones:

• ApiVersion: un número (14 o 15), o bien el texto Auto que especifica la versión de la API de SharePoint que se va a usar para este sitio. Cuando no se especifica, se usa la versión 14 de la API. Cuando se especifica Auto, la versión del servidor se detectará de forma automática si es posible; de lo contrario, el valor predeterminado de la versión es 14. Los sitios de SharePoint que no están en inglés requieren al menos la versión 15.
• Implementation: opcional. Especifica la versión del conector de SharePoint que se va a usar. Los valores aceptados son "2.0" o null. Si el valor es "2.0", se usa la implementación 2.0 del conector de SharePoint. Si el valor es NULL, se usa la implementación original del conector de SharePoint.

Para SharePoint.Contents, la implementación original admite ApiVersion valores 14, 15 y "Auto". Si ApiVersion no se especifica, se usa la versión 14. Con la implementación 2.0, ApiVersion no es necesario especificarla porque la versión 15 de la API se usa automáticamente. La versión 14 de la API no se admite con la implementación 2.0.

Ejemplo 1

Devuelve el contenido de SharePoint de nivel superior mediante la implementación original. Dado que no se especifica ninguna opción, se usa la versión 14 de la API.

Uso

SharePoint.Contents("https://contoso.sharepoint.com/sites/Contoso")

Output

A hierarchical table containing the top-level folders and files in the site.

Ejemplo 2

Use la implementación original con selección automática de API para devolver todos los .xlsx archivos de la biblioteca de documentos compartidos. La comparación de extensiones no distingue mayúsculas de minúsculas.

Uso

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    ExcelWorkbooks = Table.SelectRows(
        SharedDocuments,
        each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
in
    ExcelWorkbooks

Output

A table containing only the files in the Shared Documents library whose Extension value is .xlsx.

Ejemplo 3

Use la implementación 2.0 para devolver el contenido inmediato de la carpeta Informes de la biblioteca documentos compartidos. La implementación 2.0 usa la versión 15 de la API de forma predeterminada.

Uso

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content]
in
    Reports

Output

A hierarchical table containing the immediate folders and files in the Reports folder.

Ejemplo 4

Devuelve el contenido binario de Budget.xlsx navegando por el contenido jerárquico del sitio.

Uso

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content],
    Budget = Reports{[Name = "Budget.xlsx"]}[Content]
in
    Budget

Output

The binary content of Budget.xlsx.