Muistiinpano
Tämän sivun käyttö edellyttää valtuutusta. Voit yrittää kirjautua sisään tai vaihtaa hakemistoa.
Tämän sivun käyttö edellyttää valtuutusta. Voit yrittää vaihtaa hakemistoa.
Tämä artikkeli tarjoaa X++:n syntaksiviitteen.
X++ keywords
Seuraava taulukko listaa varatut X++-avainsanat. Et voi käyttää näitä avainsanoja mihinkään muuhun tarkoitukseen.
| Reserved word | Description | Related information |
|---|---|---|
| ! | Not. | Relational Operators |
| != | Epätasa-arvon operaattori (eri suuri kuin). | Relational Operators |
| # | Etuliite makrojen nimille. | Toimintatapa: #define ja #if käyttäminen makron testaamiseen |
| & | Binary AND. | Arithmetic Operators |
| && | Logical AND. | Relational Operators |
| ( | Funktiokutsuoperaattori, joka ilmaisee funktiokutsun alun. | |
| ) | Funktiokutsuoperaattori, joka ilmaisee funktiokutsun lopun. | |
| * | Multiply. Tähteä (*) käytetään myös X++ SQL:ssä. Yksi käyttötarkoitus on merkitä kaikki lausekkeen taulukoiden select kentät. Toinen käyttö on yleismerkki operaattorin like kanssa, mikä merkitsee 0-merkkiä moneen hahmoon. - like operaattori käyttää myös -merkkiä ? . |
Arithmetic Operators |
| ^ | Binary XOR. | Arithmetic Operators |
| | | Binary OR. | Arithmetic Operators |
| || | Logical OR. | Relational Operators |
| ~ | Not. | Arithmetic Operators |
| + | Plus. | Arithmetic Operators |
| ++ | Increment. | Assignment Operators |
| += | Additive assignment. | Assignment Operators |
| , | Comma operator. Pilkuilla erotellut lausekkeet arvioidaan järjestyksessä vasemmalta oikealle. | |
| - | Minus. | Arithmetic Operators |
| -- | Decrement operator. | Assignment Operators |
| -= | Subtractive assignment. | Assignment Operators |
| . | Esimerkiksi luokan jäsenen käyttöoikeusoperaattori formRun.run käyttää run luokkatyypin FormRunobjektin -menetelmää. |
|
| / | Divide. | Arithmetic Operators |
| \ | Tilanvaihto merkkijonoina. Välttää ylimääräiset lainausmerkit ja tietyt kirjaimet, kuten '\t' tab. |
|
| @ | Avainsanojen tilanvaihto. Esimerkiksi kääntäminen epäonnistuu ilman merkkiävar @str = 1@abstract;, @ joka aiheuttaa sen jälkeen olevan merkkijonon katsomisen tunnisteeksi. Se vaikuttaa myös literaalimerkkijonoon negoimalla \ escape -merkin vaikutuksen ja ottamalla käyttöön merkkijonon, joka kattaa useamman kuin yhden rivin lähdekoodissa. Uutta riviä edustaa yksi heksadesimaali 0x0A merkki, jota kutsutaan yleisesti viivasyötteeksi. Heksadesimaali 0x0D rivinvaihtomerkkiä ei sisällytetä, kuten 0x0D0A. |
|
| : | Kaksoispisteellä (:) merkkiä käytetään tapausarvojen rajaamiseen lauseessa switch . |
|
| :: | Käytetään kutsumaan staattisia (luokka) metodeja: ClassName::methodName() and to designate enumeration literals, like NoYes::Yes. |
|
| ; | Terminates statements. Käytetään silmukoissa for tai alustajan, päivityksen ja arvon tarkistuksen osien erottimena. |
|
| < | Less than. | Relational Operators |
| << | Left shift. | Arithmetic Operators |
| <= | Pienempi tai yhtä suuri kuin. | Arithmetic Operators |
| = | Assignment operator. ""-kohdan vasemmalla puolella= oleva argumentti asetetaan oikealla olevan argumentin arvoon. | Assignment Operators |
| == | Palauttaa arvon true, jos lausekkeet ovat yhtä suuret. | Relational Operators |
| > | Greater than. | Relational Operators |
| >= | Suurempi tai yhtä suuri kuin. | Relational Operators |
| >> | Bittisuunnassa oikea vaihto. Tämä operaattori siirtää bitit vasemmalla puolella oikealla puolella olevan määrän mukaan. Jokainen vaihto jakaa luvun tehokkaasti 2^n:lla, jossa n on siirrettyjen sijaintien määrä. | Arithmetic Operators |
| ?: | Ternary operator. Kysymysmerkkiä (?) käyttää myös operaattori like merkitsemään täsmälleen yhtä merkkiä mistä tahansa lajista. - like operaattori käyttää myös -merkkiä * . |
Ternäärioperaattori (?) |
| [ | Matriisin deklaraaattori, avaa. On käytettävä kohteen "]" kanssa. | |
| ] | Matriisin deklaraaattori, sulje. Tulee käyttää kohteen "[" kanssa. | |
| { | Käynnistää yhdistelmälausekkeen, joka voi puolestaan sisältää nolla lauseketta tai enemmän. Yhdistelmälauseke päättyy lähimpään vastaavaan "}"-merkkijonoon. | |
| } | Ilmaisee yllä kuvatun yhdistelmälausekkeen lopun. "{"-sanan on oltava näkyvissä ennen ensimmäistä näistä lausekkeista. | |
| abstract | Luokan ja menetelmän muokkaus.
Abstraktia luokkaa ei voi muodostaa uudella avainsanalla – vain siitä johdettuja luokkia voi.
Abstraktia menetelmää ei voi kutsua, vain sen ohittavat menetelmät voivat. Taulukkoa voidaan muokata abstraktiksi asettamalla sen Abstrakti ominaisuus AOT:ssa Kyllä tai käyttämällä luokkaa DictTable . Abstrakti ominaisuus on oletuksena No, eikä sitä voi asettaa, ellei taulukkoa laajenneta toisella taululla. Jokaisella abstraktin taulukon rivillä on oltava riippuvainen rivi johdetussa taulukossa. Tämä tarkoittaa, että jokaisella abstraktin taulukon rivin arvolla on InstanceRelationType-ominaisuuskentässään arvo, joka on suurempi kuin nolla. Taulukon merkitsemisestä abstraktiksi ei ole muita vaikutuksia. Epävirallisesti ohjelmoijat käyttävät usein termiä konkreettinen kuvaamaan ei-abstraktia luokkaa. |
Menetelmän muokkaajien taulukon periytymisen yleiskatsaus |
| anytype | Tyyppi, joka voi sisältää minkä tahansa tyyppisiä arvoja. | Anytype |
| as | Tarvitaan, kun määrität perusluokan muuttujan johdetulle luokkamuuttujalle. Jos luokalle on Derived esimerkiksi luokka, joka laajentaa luokkaaBase, lauseke myDerived = myBase as Derived; välttää kääntäjävirheen käyttämällä avainsanaa . Tätä avainsanaa käytetään myös, kun määrität perustaulukkomuuttujan johdetulle taulukkomuuttujalle. Jos arvo (myBase) ei ole määritettyä tyyppiä (Johdettu), lauseke palauttaa tyhjäarvon. |
Lausekeoperaattorit: On ja As periytymistä varten |
| asc | -lausekkeen taiorderby-groupbylausekkeen select vaihtoehto. Lajittelu on nousevassa järjestyksessä. |
Valitse lausekkeen syntaksi |
| at | Määrittää tulostusikkunan sijainnin osana lauseketta print . Tulostuslauseketta ei tule käyttää. |
Print Statements |
| avg | Palauttaa kenttien keskiarvon lausekkeen -lausekkeen group by määrittämältä riviltä select . |
Valitse lausekkeen syntaksi |
| break | Poistu välittömästi toistuvasta koodilohkosta. | Break Statements |
| breakpoint | Edustaa keskeytyskohtaa, joka on määritetty virheenkorjausta varten. Voit määrittää koodin keskeytyskohdan kirjoittamalla: breakpoint; |
|
| by | Tämä on osa varattua termiä, kuten ryhmittelyperuste ja lajitteluperuste. | |
| byref | Määrittelee, että kutsutulle metodille välitettävä parametri välitetään viitteellä (osoitteella), ei arvolla. Byrefiä käytetään X++:ssa kutsuttaessa .NET-menetelmää, joka ottaa parametrin viittauksella (esimerkiksi kun C#-avainsanat ovat poissa käytöstä tai viittaus). | Toimintatapa: Käytä byref-avainsanaa CLR Interopille. |
| case | Valinta lausekkeessa switch . |
Switch Statements |
| catch | Käytetään poikkeusten käsittelyssä. | Poikkeusten käsittely yrityksen kanssa ja avainsanojen tarttuminen |
| changeCompany | Muuttaa tietokanta-asetuksia toiseksi yritykseksi. | Muuta yrityksen suunnittelumallia |
| class | Julistaa luokan. | Luokat X++:ssa |
| container | Määrittää - container tyypin. Säilöt sisältävät atomisten arvojen ja muiden säilöjen sarjan. |
Containers |
| continue | Pakottaa silmukan seuraavan iteraation. | Continue Statements |
| count | Palauttaa lausekkeen -lausekkeen lausekkeen group byselect määrittämien rivien tietueiden määrän. |
Valitse lausekkeen syntaksi |
| crossCompany | Aiheuttaa lausekkeen palauttamaan select tiedot kaikille yrityksille, joista käyttäjällä on oikeus lukea tietoja. |
Yrityksenlaajuiset X++ Code Basics -perusteet |
| date | Määrittää muuttujan, jonka tyyppi dateon . |
Dates |
| default | Oletustapaus lausekkeissa switch . Oletusosan koodilohko suoritetaan, jos switch-arvo ei vastaa mitään case lauseessa annettuja lauseita switch . |
Switch Statements |
| delegate | Luokkajäsen, joka voi tallentaa useita viittauksia muiden luokkien metodeihin ja kutsua kaikkia näitä metodeja pyydettäessä. Edustaja voi tallentaa viittauksia erilaisiin metodeihin, mukaan lukien seuraavat: staattiset metodit X++-luokille; instanssimetodeille X++-luokille; metodit .NET Framework -luokille. | Tapahtumaterminologia ja avainsanat X++, C#-vertailu: tapahtuma |
| delete_from | Poistaa tietueet tietokannasta. | delete_from |
| desc | -lausekkeen tai order by -group bylausekkeen select vaihtoehto. Lajittelu on laskeva. |
Valitse lausekkeen syntaksi |
| display | Method modifier. Menetelmä näyttää lasketut display arvot lomakkeen ohjauksessa. Toisin kuin tavalliset kentät, näitä arvoja ei tallenneta tietokantaan, vaan ne lasketaan dynaamisesti. |
Method Modifiers |
| div | Integer division. | Arithmetic Operators |
| do | Silmukan do...while alku. |
Do...while Loops |
| edit | Method modifier.
edit X++:n menetelmän avulla käyttäjät voivat muokata lomakkeen ohjausobjektin arvoja mukautetun logiikan suorittamisen aikana. Toisin kuin display metodit, jotka näyttävät vain lasketut arvot, edit menetelmät mahdollistavat sekä katselun että muokkaamisen. |
Method Modifiers |
| else | Ehdollinen suoritus (if...else).
else Lauseen osa if suoritetaan, jos if-lauseen lauseke arvioidaan .false |
jos ja jos ... else-lausekkeet |
| eventHandler | On oltava käytössä aina, kun lisäät tai poistat menetelmäviittauksen edustajalta or-operaattorin +=-= avulla. Esimerkki: myDelegate += eventHandler(OtherClass::myStaticMethod); |
Tapahtumaterminologia ja avainsanat X++, C#-vertailu: tapahtuma |
| exists | Käytetään lausekkeiden kanssa join lausekkeissa select . |
Valitse lausekkeen syntaksi |
| extends | Luokan tai liittymän määrittelylause. Jos luokkasi ei nimenomaisesti laajenna toista luokkaa, luokkasi katsotaan laajentavan Object luokkaa (aivan kuin olisit kirjoittanut "laajentaa objektia"). |
Aliluokan luominen |
| false | Boolean literal. | Booleans |
| final | Luokan ja menetelmän muokkaus. Määrittää, että tätä menetelmää ei voi ohittaa. | Method Modifiers |
| firstFast | Käytetään lausekkeissa select nopeuttamaan ensimmäisen rivin noutoa. |
Valitse lausekkeen syntaksi |
| firstOnly | Käytetään lausekkeissa select vain ensimmäisen tietueen noutamiseen. Avainsana firstOnly ei takaa, että X++ SQL select -lauseke noutaa enintään yhden tietueen. Jos AOS pystyy käyttämään välimuistia EntireTable lausekkeen tietojen vaatimusten täyttämiseen select , firstOnly avainsana ohitetaan. |
Valitse lausekkeen syntaksijoukkopohjainen välimuistitallennus |
| firstOnly10 | Sama kuin firstOnly, mutta palauttaa kymmenen riviä yhden sijaan. | |
| firstOnly100 | Sama kuin firstOnly, paitsi palauttaa 100 riviä yhden sijaan. | |
| firstOnly1000 | Sama kuin firstOnly, paitsi palauttaa 1 000 riviä yhden sijaan. | |
| flush | Tyhjentää koko taulukon välimuistin. Tämä toiminto voi olla hyödyllinen, kun haluat varmistaa, että kaikki taulukossa tehdyt muutokset näkyvät välittömästi myöhemmissä operaatioissa. | Set-based Caching |
| for | silmukan iterointia varten. | For Loops |
| forceLiterals | Käytetään lausekkeissa select paljastamaan todelliset arvot, joita käytetään where Microsoft SQL Server -tietokannan lauseissa optimointihetkellä. |
Valitse lausekkeen syntaksi |
| forceNestedLoop | Pakottaa SQL Server -tietokannan käyttämään sisäkkäistä silmukan algoritmia tietyn SQL-lausekkeen käsittelemiseen, joka sisältää - joinkohteen. |
Valitse lausekkeen syntaksi |
| forcePlaceholders | -lausekkeissa select käytetään ytimen ohjeistamista olemaan paljastamatta Microsoft SQL Server -tietokannan lauseissa where käytettyjä todellisia arvoja optimoinnin aikana. |
Valitse lausekkeen syntaksi |
| forceSelectOrder | Pakottaa SQL Server -tietokannan käyttämään liitossa olevia taulukoita määritetyssä järjestyksessä. | Valitse lausekkeen syntaksi |
| forUpdate | Valitsee tietueita vain päivitystä varten. Haettujen tietueiden operaatio on päivitys. Riippuen taustalla olevasta tietokannasta, tietueet saattavat olla lukittuina muilta käyttäjiltä. | Valitse lausekkeen syntaksi |
| from | Osa lausuntoa select . Lauseke from määrittelee taulukon puskurin, jossa sarakkeet sijaitsevat. |
Valitse lausekkeen syntaksi |
| group | Osa lauseketta group by lausunnossa select . |
Valitse lausekkeen syntaksi |
| if | Conditional execution. | jos ja jos ... else-lausekkeet |
| implements | :n interfacetoteutus |
Interfaces Overview |
| insert_recordset | Kopioi tietoja yhdestä tai useammasta taulukosta yhdeksi tulokseksi saatavaksi kohdetaulukoksi yhdellä palvelinmatkalla. | insert_recordset |
| int | Määrittää muuttujan tyypin integer (32-bittinen). |
Integers |
| int64 | Määrittää muuttujan tyypin integer (64-bittinen). |
Integers |
| interface | Interface declaration. | Interfaces Overview |
| is | Kysyy, peritäänkö luokkamuuttujan viittaama objekti joko annetusta luokasta vai annetusta luokasta. Jos esimerkiksi luokalle, Derived joka laajentaa luokkaa Base , lauseke (myDerived is Base) palauttaa arvon true. Tämä avainsana koskee luokan periytymistä ja taulukon periytymistä. |
Lausekeoperaattorit: On ja As periytymistä varten |
| join | Taulukot liitetään sarakkeisiin, jotka ovat yhteisiä molemmille taulukoille. Liitoksia käyttämällä voit luoda yhden tulosjoukon, joka perustuu useisiin taulukoihin. | Valitse lausekkeen syntaksi |
| like | Testit vastaavuuksille kuvioittain yleismerkeillä *ja ?. | Relational Operators |
| maxof | Palauttaa kenttien enimmäismäärän -lauseen määrittämiltä group by riveiltä. |
Valitse lausekkeen syntaksi |
| minof | Palauttaa kenttien vähimmäismäärän -lausekkeen määrittämisriveiltä group by . |
Valitse lausekkeen syntaksi |
| mod | Palauttaa vasemmanpuoleisen lausekkeen1 kokonaisluvun jakojäännöksen jaettuna oikealla lausekkeella2. Epävirallisesti tätä kutsutaan joskus modulo-operaattoriksi.
(12 mod 7) == 5 on tosi. |
|
| new | Operator. Luo luokan esiintymän tai varaa muistia matriisille. | |
| next | Hakee taulukon seuraavan tietueen tai kutsuu komentosarjan seuraavaa menetelmää. | |
| noFetch | Ilmaisee, että mitään tietueita ei noudeta nyt. | Valitse lausekkeen syntaksi |
| notExists | Käytetään lausekkeiden kanssa join lausekkeissa select . |
Valitse lausekkeen syntaksi |
| null | Symbolic constant. | |
| optimisticLock | Pakottaa lausunnon toimimaan optimistisella samanaikaisuuden hallinnalla, vaikka pöydälle olisi määritetty eri arvo. | Valitse lausekkeen syntaksi |
| order | Osa lauseketta order by lausunnossa select . |
Valitse lausekkeen syntaksi |
| outer | outer join. | Valitse lausekkeen syntaksi |
| pause | Pysäyttää työn suorittamisen. Käyttäjää pyydetään tilaamaan, pitääkö suoritusta jatkaa. Tätä lauseketta ei kannata käyttää tuotantokoodissa. | Select Statements |
| pessimisticLock | Pakottaa lausekkeen suoritettavaksi autuaasti samanaikaisuuden hallinnalla, vaikka taulukossa olisi määritetty eri arvo. | Valitse lausekkeen syntaksi |
| Voit näyttää tuloksen näytössä. Tätä lauseketta ei kannata käyttää tuotantokoodissa. | Print Statements | |
| private | -menetelmän käyttömuunnin. -menetelmää voi käyttää vain luokassa, joka määrittää -menetelmän. | Menetelmän käyttöoikeuksien valvonta |
| protected | -menetelmän käyttömuunnin. -menetelmää voidaan käyttää menetelmät määrittävän luokan menetelmistä ja missä tahansa johdetuissa luokissa. | Menetelmän käyttöoikeuksien valvonta |
| public | -menetelmän käyttömuunnin. -menetelmä voidaan kutsua mistä tahansa luokasta. | Menetelmän käyttöoikeuksien valvonta |
| real |
real Määrittää tyypin, desimaalityypin ilman pyöristysvirheitä. |
Reals |
| repeatableRead | Määrittelee, ettei mikään muu transaktio voi muuttaa nykyisen transaktion lukemaa dataa ennen kuin nykyinen transaktio päättyy. Eksplisiittinen tapahtuma päättyy joko ttsAbortiin tai ulimpaan ttsCommitiin. Jos valitset erillisen lausekkeen, tapahtuman kesto on select-komennon kesto. Tietokanta kuitenkin käyttää toisinaan toistettavissa olevaa Luku-vastinetta yksittäisissä valintalausekkeissa myös ilman, että tämä avainsana näkyy X++-koodissasi (sen mukaan, miten tietokanta päättää skannata taulukot). | Lisätietoja on pohjana olevan relaatiotietokantatuotteen dokumentaatiossa. |
| retry | Käytetään poikkeusten käsittelyssä. | Poikkeusten käsittely yrityksen kanssa ja avainsanojen tarttuminen |
| return | Palauttaa -menetelmän. | Menetelmien määrittely |
| reverse | Tietueet palautetaan käänteisessä järjestyksessä. | Valitse lausekkeen syntaksi |
| select | -lause select määrittää, mitkä sarakkeet tai näkymät näytetään tulosjoukossa. |
Select Statements |
| setting | Käytetty komennon update_recordset kanssa. |
update_recordset |
| static | Staattiset menetelmät eivät voi viitata instanssimuuttujiin (vain staattisiin muuttujiin). Kutsu staattisia metodeja käyttämällä luokan nimeä sen sijaan, että käyttäisit luokan ("") instanssiaMyClass.aStaticProcedure. |
Method Modifiers |
| str | Määrittää - string tyypin. |
Strings |
| sum | Palauttaa kenttien summan lausekkeen -lauseen group byselect määrittäiltä riveiltä. |
Valitse lausekkeen syntaksi |
| super | Kutsuu metodia, jonka nykyinen metodi ohittaa. | Table Methods |
| switch | Switch statement. | Switch Statements |
| tableLock | Vanhentunut; tableLock ei ole enää käytettävissä. | |
| this | Viittaus luokan nykyiseen esiintymään. Käytetään X++-koodissa luokan esiintymämenetelmän sisällä. Käytetään viittaamaan -luokan -menetelmän jäseniin. | |
| throw | Käytetään poikkeusten käsittelyssä. | Poikkeusten käsittely yrityksen kanssa ja avainsanojen tarttuminen |
| true | Boolean literal. | Booleans |
| try | Käytetään poikkeusten käsittelyssä. | Poikkeusten käsittely yrityksen kanssa ja avainsanojen tarttuminen |
| ttsAbort | Peruuttaa (hylkää) kaikki muutokset nykyisessä tapahtumassa. | Transaction Integrity |
| ttsBegin | Merkitsee tapahtuman alun. | Transaction Integrity |
| ttsCommit | Merkitsee tapahtuman loppua, jolloin muutokset tehdään taulukoihin. | Transaction Integrity |
| update_recordset | Sallii rivijoukkojen käsittelyn yhdessä toiminnossa. | update_recordset |
| validTimeState | Suodattaa rivejä, jotka X++ SQL-lause select hakee kelvollisesta aikatilataulukosta. Esimerkiksi: select validTimeState(myDateEffective) * from xMyTable; ... tai... select validTimeState(myDateFrom, myDateTo) * from xMyTable; |
Kelvollisten aikatilataulukoiden vaikutukset luku- ja kirjoitustoimintoihin |
| void | Määrittää menetelmän, joka ei palauta arvoa. | Menetelmien määrittely |
| where | Osa lausuntoa select . - where lause määrittää ehdot, jotka on täytettävä: eli rivit, jotka haluat sisällyttää tulokseen. |
Valitse lausekkeen syntaksi |
| while | Iteration statement. Suorittaa lausekkeen toistuvasti, kunhan testiehto on tosi. | Silmukoiden ollessa valittuina Lausekkeet |
| window | Tämän avulla voit muuttaa tulosikkunan kokoa. Käytetään lauseiden print kanssa, joita tuotantokoodissa ei suositella. |
Print Statements |
Expressions syntax
Käytä lauseketta X++:ssa matemaattisille tai loogisille operaatioille. Rakenna lausekkeet kielen tietotyypeille. Lauseke palauttaa aina jonkinlaisen arvon. Käytä tätä arvoa laskelmissa, sijoituksissa, ehdollisissa lauseissa ja niin edelleen.
EBNF-kuvaus lausekkeista X++:ssa
| Term | Definition | |
|---|---|---|
| Expression | = | Yksinkertaislauseke [RelationalOperaattori Simple-lauseke ] |
| RelationalOperator | = | = |
| Simple-expression | = | Yksinkertaislauseke [ + |
| Term | = | Compfactor { Mult-operaattori CompFactor } |
| Mult-operator | = | * |
| CompFactor | = | [ ! ] [ - |
| Factor | = | Literal |
| Enum | = | Luettelointinimi :: Literaali |
| Variable | = | Tunniste [ [ Lauseke ] [ . Expression ] |
| FunctionCall | = | [ Ilmaisu (. |
| If-expression | = | Expression ? Lauseke : lauseke |
Semanttiset rajoitukset koskevat edeltävää syntaksia. Et voi kutsua mitään metodia operaattorin avulla :: . Samoin et voi käyttää tätä avainsanaa ilman aktiivista objektia. Tämän objektin täytyy olla instanssimetodin sisällä ja niin edelleen.
Examples
| Esimerkki lausekkeesta | Description |
|---|---|
1 |
Kokonaislukuliteraali. |
| NoYes::No | An enum-reference. |
A |
A variable-reference. |
| Debtor::Find("1") | Staattinen menetelmäkutsu (palauttaa asiakasmuuttujan). |
| (A > 3 ? totta : väärin) | if-expression-lauseke, joka palauttaa arvon tosi tai epätosi. |
| (valitse CustTable, jossa CustTable.Account == "100"). NameRef | A select-expression. Palauttaa asiakastaulukon nameref-kentän. Tämä on merkkijono. |
| A >= B | Looginen lauseke. Palauttaa arvon tosi tai epätosi. |
| A + B | Aritmeettinen lauseke. Summat A ja B. |
| A + B / C | Laskee B/C-arvon ja lisää tämän sitten arvoon A. |
| ~A+ tämä. Value() | Sums binary not A ja method-call Value -funktion tulos vaikutusalueella olevassa objektissa (tämä). |
| Debtor::Find("1").NameRef | Palauttaa löydetyn asiakastietueen NameRef-kentän. |
| Debtor::Find("1").Balance() | Menetelmäkutsu asiakkaalle Balance -taulukossa (Debtor::Find palauttaa asiakkaan). Palauttaa asiakkaan saldon käyttäen tiliä 1. |
EBNF overview
Laajennettu Backus Naur -muoto (EBNF) on metakieli. Tämä opas käyttää sitä kuvaamaan kielen syntaksia. EBNF:n määritelmä muodostuu tuotantosäännöistä, muista kuin terminaaleista ja terminaaleista. Seuraava taulukko esittää keskeiset termit.
| Key terms | Example | Description |
|---|---|---|
| Terminals | Work_Team | Pääte on yksi merkki tai merkkimerkkijono, joka ei koskaan muutu. |
| Nonterminals | Employee |
Nonterminal on kelvollisen lauseen osan kuvaus kielellä, joka on määritetty joko tuotantosäännön tai tekstimuotoisen kuvauksen perusteella. Ei-terminaalinen symboli voidaan aina laajentaa yhteen tai useampaan päätesymboliin. |
| Production rules | Työntekijä = kehittäjä | Tester |
Example
Work_Team = Esimiehen työntekijä {, Employee} Työntekijä = Kehittäjä | Tester Tässä esimerkissä Work_Team koostuu yhdestä Manager tai useammasta Employees.
Employee on määritelmä, joka on , Developertai Tester. Esimerkissä käytetyt symbolit on kuvattu seuraavassa taulukossa.
ERIKOISSymbolit EBNF:ssä
| Symbol | Description |
|---|---|
| (Expression) | Sulkeet pitävät symbolit (päätteet ja muut kuin terminaalit) yhdessä. Ne voidaan sijoittaa mihin tahansa tuotantosäännön oikealle puolelle. |
| Expression1 | Expression2 |
| [Expression] | Valinnainen: kohteiden [ ja ] välillä on valinnaisia. Kaikki tai ei mitään hakasulkeissa olevista kohteista eivät sisälly. |
| {Expression} | Toistan: Kohteet välillä { ja } ovat valinnaisia, mutta ne voidaan toistaa niin monta kertaa kuin on tarpeen. |
Jos esimerkiksi polkupyörälle ostamasi lisävarusteet koostuvat satulasta, vesipullonpitikkeistä, kelloista ja sarvista ja sinulla voi olla joko kello tai sarvi ja nolla, yksi tai useampi vesipullonpitike ja täsmälleen yksi satula, tämä voidaan ilmaista seuraavasti: Bicycle_Accessories = satula [kello | sarvi] {water_bottle_holders} Tämä kielioppi määrittää seuraavat mahdollisuudet: saddlesaddle bellsaddle horn satula water_bottle_holder satulakello water_bottle_holder satulakello water_bottle_holder water_bottle_holder Ja niin edelleen.
X++ Grammar
Tässä artikkelissa näytetään X++-kielen virallinen kielioppi.
Virallisen BNF-kieliopin tulkitseminen
Tässä osiossa kuvataan X++:n kielioppi Backus Naur -muodossa (BNF). Tässä on kuvattu pieni esimerkki BNF:stä.
AA ::= BB CC_SYM
BB ::= JJ_SYM
::= KK_SYM
AA on tuotantosäännön nimi.
AA edellyttää -, BB- ja -CC_SYM.
BB on myös tuotantosääntö. Sen vuoksi se BB ei ole pääte.
BB on oltava joko JJ_SYM tai KK_SYM. Sekä JJ_SYM että KK_SYM ovat päätemerkkejä, koska ne eivät ole minkään muun tuotantosäännön nimiä. CC_SYM on myös pääte.
BNF for X++ -kieliopissa useimmilla päätteellä on _SYM nimensä jälkiliitteeksi.
Muodollinen X++-kielioppi BNF:ssä
Tässä osiossa on BNF, joka määrittää X++-kieliopin.
CMPL_UNIT ::= RETTYPEID FUNC_HDR FUNC_HEAD BODY
::= RETTYPEID DATA_HDR CLASS_DECL
::= EXPR_HDR IF_EXPR SEMIOPT
::= RETTYPEID FUNC_HDR EVENT_DECL BODY
SEMIOPT ::= SEMICOLON_SYM
::=
CLASS_DECL ::= CLASS_HEADER LEFTBR_SYM DCL_EVENTMAP DCL_LIST RIGHTBR_SYM
CLASS_HEADER ::= ATTRIBUTE_DEF CLASS_MODIFIERS CLASSORINTERFACE STD_ID EXTENDS IMPLEMENTS
ATTRIBUTE_DEF ::= LEFT_BRKT_SYM ATTRIBUTE_INIT ATTRIBUTE_LIST RETTYPEID RGHT_BRKT_SYM
::=
ATTRIBUTE_INIT ::=
.
ATTRIBUTE_LIST ::= ATTRIBUTE
::= ATTRIBUTE_LIST LIST_SEP_SYM ATTRIBUTE
ATTRIBUTE ::= STD_ID
::= ATTRIBUTE_WITH_ARGS_BEGINS ATTRIBUTE_WITH_ARGS_ENDS
ATTRIBUTE_WITH_ARGS_BEGINS ::= STD_ID LEFT_PAR_SYM
ATTRIBUTE_WITH_ARGS_ENDS ::= ATTRIBUTE_ARGS RGHT_PAR_SYM
ATTRIBUTE_ARGS ::= ATTRIBUTE_CONSTANT
::= ATTRIBUTE_ARGS LIST_SEP_SYM ATTRIBUTE_CONSTANT
ATTRIBUTE_CONSTANT ::= INT_SYM
::= DBL_SYM
::= STR_SYM
::= DATE_SYM
::= DATETIME_SYM
::= STD_ID DBLCOLON_SYM STD_ID
::= TRUE_SYM
::= FALSE_SYM
::= INT64_SYM
::= ATTRIBUTE_INTRINSIC
ATTRIBUTE_INTRINSIC ::= INTRI_ID LEFT_PAR_SYM IARGS RGHT_PAR_SYM
CLASSORINTERFACE ::= CLASS_SYM
::= INTERFACE_SYM
CLASS_MODIFIERS ::= CLASS_MODS
::=
CLASS_MODS ::= CLASS_MODIFIER
::= CLASS_MODS RETTYPEID CLASS_MODIFIER
CLASS_MODIFIER ::= PUBLIC_SYM
::= FINAL_SYM
::= STATIC_SYM
::= ABSTRACT_SYM
::= PRIVATE_SYM
EXTENDS ::= EXTENDS_SYM STD_ID
::=
IMPLEMENTS ::= IMPLEMENTS_SYM IMPLEMENTLIST
::=
IMPLEMENTLIST ::= STD_ID
::= IMPLEMENTLIST LIST_SEP_SYM STD_ID
DCL_EVENTMAP ::=
EVENT_DECL ::= ATTRIBUTE_DEF EVENT_HEADER PARM_DCL_LIST
EVENT_HEADER ::= EVENT_MODIFIER VOID_TYPE_SYM STD_ID
EVENT_MODIFIER ::= EVENT_SYM
FUNC_HEAD ::= ATTRIBUTE_DEF FUNCNAME PARM_DCL_LIST
FUNCNAME ::= FUNCTYPE STD_ID
FUNCTYPE ::= FUNC_MODIFIERS DECL_TYPE
FUNC_MODIFIERS ::= FUNC_MODS
::=
FUNC_MODS ::= RETTYPEID FUNC_MODIFIER
::= FUNC_MODS RETTYPEID FUNC_MODIFIER
FUNC_MODIFIER ::= PUBLIC_SYM
::= PRIVATE_SYM
::= PROTECTED_SYM
::= FINAL_SYM
::= STATIC_SYM
::= ABSTRACT_SYM
::= DISPLAY_SYM
::= EDIT_SYM
BODY ::= LEFTBR_SYM DCL_FUNC_LIST SEMIOPT SECAUTHZCHECK STMTLIST SECAUTHZEND RIGHTBR_SYM
SECAUTHZCHECK ::=
SECAUTHZEND ::=
RETTYPEID ::=
FUNCTION_DEF ::= FUNC_HEADER PARM_DCL_LIST LOCAL_BODY
FUNC_HEADER ::= DECL_TYPE STD_ID
PARM_DCL_LIST ::= RETTYPEID PARM_START PARM_LIST_OPT RGHT_PAR_SYM RETTYPEID
PARM_START ::= LEFT_PAR_SYM
PARM_LIST_OPT ::= PARM_LIST
::=
PARM_LIST ::= DCL_INIT
::= PARM_LIST LIST_SEP_SYM DCL_INIT
LOCAL_BODY ::= LEFTBR_SYM DCL_LIST SEMIOPT STMTLIST RETTYPEID RIGHTBR_SYM
DCL_LIST ::= DCL_LIST2
::=
DCL_LIST2 ::= DCL_STMT
::= DCL_LIST2 DCL_STMT
DCL_FUNC_LIST ::= DCL_FUNC_LIST2
::=
DCL_FUNC_LIST2 ::= DCL_STMT
::= FUNCTION_DEF
::= DCL_FUNC_LIST2 DCL_STMT
::= DCL_FUNC_LIST2 FUNCTION_DEF
DCL_STMT ::= DCL_INIT_LIST RETTYPEID SEMICOLON_SYM
DCL_INIT_LIST ::= DCL_INIT
::= DCL_CLIST ASG_CLAUSE
DCL_CLIST ::= DCL_INIT_LIST LIST_SEP_SYM STD_ID ARR_DCL_IDX
DCL_INIT ::= DECL ASG_CLAUSE
DECL ::= DECL_TYPE STD_ID ARR_DCL_IDX
DECL_TYPE ::= STR_TYPE_SYM STR_LEN
::= INT_TYPE_SYM
::= DBL_TYPE_SYM
::= DATE_TYPE_SYM
::= DATETIME_TYPE_SYM
::= TYPE_ID
::= QUEUE_TYPE_SYM
::= VOID_TYPE_SYM
::= ANY_TYPE_SYM
::= GUID_TYPE_SYM
::= INT64_TYPE_SYM
::= CLR_TYPE
CLR_TYPE ::= CLR_NAMESPACE TYPE_ID CLR_ARRAY_TYPE_EXT
::= CLR_NAMESPACE CLR_TYPE
CLR_NAMESPACE ::= TYPE_ID PERIOD_SYM
CLR_ARRAY_TYPE_EXT ::= CLR_ARRAY_SPEC
::=
CLR_ARRAY_SPEC ::= CLR_ARRAY_PART
::= CLR_ARRAY_SPEC CLR_ARRAY_PART
CLR_ARRAY_PART ::= CLR_ARRAY_LEFT_PART CLR_RECTANGULAR_LIST RGHT_BRKT_SYM
CLR_ARRAY_LEFT_PART ::= LEFT_BRKT_SYM
CLR_RECTANGULAR_LIST ::= CLR_COMMA_LIST
::=
CLR_COMMA_LIST ::= LIST_SEP_SYM
::= CLR_COMMA_LIST LIST_SEP_SYM
STR_LEN ::= INT_SYM
::=
ARR_DCL_IDX ::= LEFT_BRKT_SYM RANGE ARRAY_MEM RGHT_BRKT_SYM
::=
RANGE ::= IF_EXPR
::=
ARRAY_MEM ::= LIST_SEP_SYM IF_EXPR
::=
ASG_CLAUSE ::= INIT_START IF_EXPR
::=
INIT_START ::= ASG_SYM
ASG_STMT ::= LVAL_FLD ASSIGN IF_EXPR
::= LVAL_LIST ASG_SYM IF_EXPR
::= LVAL_FLD ASG_INC_DEC
::= ASG_INC_DEC LVAL_FLD
::= LVAL_FLD ASG_EVENT_HANDLER
ASSIGN ::= ASG_SYM
::= ASGINC_SYM
::= ASGDEC_SYM
ASG_INCDEC ::= ASGINC_SYM
::= ASGDEC_SYM
ASG_EVENT_HANDLER ::= ASG_INCDEC EVENTHANDLER_SYM LEFT_PAR_SYM QUALIFIER STD_ID RGHT_PAR_SYM
::= ASG_INCDEC EVENTHANDLER_SYM LEFT_PAR_SYM STD_ID DBLCOLON_SYM STD_ID RGHT_PAR_SYM
::= ASG_INCDEC EVENTHANDLER_SYM LEFT_PAR_SYM QUALIFIER EVAL_CLR_TYPE DBLCOLON_SYM STD_ID RGHT_PAR_SYM
ASG_INC_DEC ::= INC_SYM
::= DEC_SYM
LVAL_FLD ::= FIELD
LVAL_START ::= LEFT_BRKT_SYM
LVAL_LIST ::= LVAL_START LVALUES RGHT_BRKT_SYM
LVALUE ::= FIELD
LVALUES ::= LVALUE
::= LVALUES NEXTLVAL LVALUE
NEXTLVAL ::= LIST_SEP_SYM
IF_EXPR ::= COND_TRUE IF_EXPR
::= BOOL_EXPR
COND_TRUE ::= COND_TEST IF_EXPR COLON_SYM
COND_TEST ::= BOOL_EXPR QUEST_SYM
BOOL_EXPR ::= BOOL_EXPR LOGOP EXPR
::= EXPR
LOGOP ::= AND_SYM
::= OR_SYM
EXPR ::= SMPL_EXPR RELOP SMPL_EXPR
::= SMPL_EXPR AS_SYM STD_ID
::= SMPL_EXPR IS_SYM STD_ID
::= SMPL_EXPR AS_SYM EVAL_CLR_TYPE
::= SMPL_EXPR IS_SYM EVAL_CLR_TYPE
::= SMPL_EXPR
RELOP ::= LT_SYM
::= LE_SYM
::= EQ_SYM
::= NE_SYM
::= GT_SYM
::= GE_SYM
::= LIKE_SYM
SMPL_EXPR ::= SMPL_EXPR ADDOP TERM
::= TERM
ADDOP ::= PLUS_SYM
::= MINUS_SYM
::= PHYSOR_SYM
TERM ::= TERM MULOP CMPL_FACT
::= CMPL_FACT
MULOP ::= MULT_SYM
::= DIV_SYM
::= MOD_SYM
::= INTDIV_SYM
::= SHIFTL_SYM
::= SHIFTR_SYM
::= PHYSAND_SYM
::= PHYSXOR_SYM
CMPL_FACT ::= NOT_SYM SGND_FACT
::= SGND_FACT
SGND_FACT ::= SIGNOP FACTOR
::= FACTOR
SIGNOP ::= UMINUS_SYM
::= PHYSNOT_SYM
FACTOR ::= LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
::= CONSTANT
::= FIELD
::= DIRSEARCH
::= FUNCTION
::= INTRINSICS
::= EVAL
::= CONLITTERAL
::= NEW_CLR_ARRAY
NEW_CLR_ARRAY ::= NEW_SYM EVAL_CLR_TYPE NEW_CLR_ARRAY_PART LEFT_PAR_SYM RGHT_PAR_SYM
NEW_CLR_ARRAY_PART ::= CLR_SIZED_ARRAY CLR_NOSIZED_ARRAY_SPEC
CLR_SIZED_ARRAY ::= LEFT_BRKT_SYM CLR_SMPL_EXPR_COMMA_LIST RGHT_BRKT_SYM
CLR_SMPL_EXPR_COMMA_LIST ::= SMPL_EXPR
::= CLR_SMPL_EXPR_COMMA_LIST LIST_SEP_SYM SMPL_EXPR
CLR_NOSIZED_ARRAY_SPEC ::= CLR_NOSIZED_ARRAY_LIST
::=
CLR_NOSIZED_ARRAY_LIST ::= CLR_NOSIZED_ARRAY
::= CLR_NOSIZED_ARRAY_LIST CLR_NOSIZED_ARRAY
CLR_NOSIZED_ARRAY ::= LEFT_BRKT_SYM CLR_EMPTY_COMMA_LIST RGHT_BRKT_SYM
CLR_EMPTY_COMMA_LIST ::= CLR_EMPTY_RECT_COMMA_LIST
::=
CLR_EMPTY_RECT_COMMA_LIST ::= LIST_SEP_SYM
::= CLR_EMPTY_RECT_COMMA_LIST LIST_SEP_SYM
CONLITTERAL ::= LEFT_BRKT_SYM IF_EXPR EXPR_LIST RGHT_BRKT_SYM
CONSTANT ::= INT_SYM
::= DBL_SYM
::= STR_SYM
::= DATE_SYM
::= DATETIME_SYM
::= STD_ID DBLCOLON_SYM STD_ID
::= TRUE_SYM
::= FALSE_SYM
::= NULL_SYM
::= INT64_SYM
::= QUALIFIER EVAL_CLR_TYPE DBLCOLON_SYM STD_ID
::= QUALIFIER STD_ID DBLCOLON_SYM STD_ID
DIRSEARCH ::= DIRS_HEADER PERIOD_SYM STD_ID ARR_IDX
::= DIRS_HEADER PERIOD_SYM FLD_NUM ARR_IDX
DIRS_HEADER ::= LEFT_PAR_SYM SET_DIRS FIND_JOIN RGHT_PAR_SYM
SET_DIRS ::=
FIELD ::= QUALIFIER STD_ID ARR_IDX
::= QUALIFIER FLD_NUM ARR_IDX
::= STD_ID ARR_IDX
QUALIFIER ::= EVAL PERIOD_SYM
::= STD_ID PERIOD_SYM
FLD_NUM ::= LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
ARR_IDX ::= LEFT_BRKT_SYM SMPL_EXPR RGHT_BRKT_SYM
::=
EXPR_LIST ::= EXPR_LIST2
::=
EXPR_LIST2 ::= LIST_SEP_SYM IF_EXPR
::= EXPR_LIST2 LIST_SEP_SYM IF_EXPR
FUNCTION ::= FUNC_ID LEFT_PAR_SYM EVAL_FUNCTION_NAME PAR_LIST RGHT_PAR_SYM
EVAL_FUNCTION_NAME ::=
EVAL_NAME ::= EVAL_ID LEFT_PAR_SYM
::= STD_ID LEFT_PAR_SYM
::= STD_ID DBLCOLON_SYM STD_ID LEFT_PAR_SYM
::= SUPER_SYM LEFT_PAR_SYM
::= NEW_SYM STD_ID LEFT_PAR_SYM
::= NEW_SYM EVAL_CLR_TYPE LEFT_PAR_SYM
::= QUALIFIER EVAL_CLR_TYPE DBLCOLON_SYM STD_ID LEFT_PAR_SYM
::= QUALIFIER STD_ID LEFT_PAR_SYM
::= QUALIFIER STD_ID DBLCOLON_SYM STD_ID LEFT_PAR_SYM
EVAL_CLR_TYPE ::= NAMESPACE STD_ID
::= NAMESPACE EVAL_CLR_TYPE
NAMESPACE ::= STD_ID PERIOD_SYM
EVAL ::= EVAL_NAME PAR_LIST RGHT_PAR_SYM
PAR_LIST ::= PRM_LIST
::=
PRM_LIST ::= PAR_ELEM
::= PRM_LIST LIST_SEP_SYM PAR_ELEM
PAR_ELEM ::= IF_EXPR
::= BYREF_SYM FIELD
INTRINSICS ::= INTRI_ID LEFT_PAR_SYM IARGS RGHT_PAR_SYM
IARGS ::= STD_ID
::= STR_SYM
::= STD_ID LIST_SEP_SYM STD_ID
::=
STMTLIST ::= STATEMENTS
::=
STATEMENTS ::= STATEMENT
::= STATEMENTS STATEMENT
STATEMENT ::= COMPOUND_STMT
::= WHILE_STMT
::= FOR_STMT
::= DO_STMT
::= SEARCH_STMT
::= FIND_STMT
::= PRINT_STMT
::= WINDOW_STMT
::= IF_STMT
::= SWITCH_STMT
::= EXPR_STMT
::= PAUSE_STMT
::= BP_CLAUSE
::= BREAK_STMT
::= CONTINUE_STMT
::= RETURN_CLAUSE
::= MOVE_REC_STMT
::= THROW_STMT
::= TRY_STMT
::= RETRY_STMT
::= TTS_STMT
::= FLUSH_STMT
::= TBLLOCK_STMT
::= CHANGE_STMT
::= UPDATE_STMT
::= INSERT_STMT
::= UNCHECKED_STMT
COMPOUND_STMT ::= LEFTBR_SYM STMTLIST RIGHTBR_SYM
THROW_STMT ::= THROW_SYM IF_EXPR SEMICOLON_SYM
TRY_STMT ::= TRY_BLOCK CATCH_LIST
TRY_BLOCK ::= TRY_START STATEMENT
TRY_START ::= TRY_SYM
CATCH_LIST ::= CATCH_STMT
::= CATCH_LIST CATCH_STMT
CATCH_STMT ::= CATCH_EXPR PRE_CATCH STATEMENT POST_CATCH
CATCH_EXPR ::= CATCH_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
::= CATCH_SYM LEFT_PAR_SYM IF_EXPR LIST_SEP_SYM TABLEINSTANCE RGHT_PAR_SYM
::= CATCH_SYM
PRE_CATCH ::=
POST_CATCH ::=
TABLEINSTANCE ::= INSTANCENAME
INSTANCENAME ::= QUALIFIER STD_ID ARR_IDX
::= STD_ID ARR_IDX
RETRY_STMT ::= RETRY_SYM SEMICOLON_SYM
WHILE_STMT ::= WHILE_TEST STATEMENT
WHILE_TEST ::= WHILE LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
WHILE ::= WHILE_SYM
DO_STMT ::= DO_BODY DO_TEST SEMICOLON_SYM
DO_BODY ::= DO_HEADER STATEMENT
DO_HEADER ::= DO_SYM
DO_TEST ::= WHILE_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
FOR_STMT ::= FOR_HEADER STATEMENT
FOR_HEADER ::= FOR_TEST SEMICOLON_SYM FOR_ASG RGHT_PAR_SYM
FOR_TEST ::= FOR_INIT SEMICOLON_SYM IF_EXPR
FOR_INIT ::= FOR_SYM LEFT_PAR_SYM FOR_ASG
FOR_ASG ::= LVAL_FLD ASSIGN IF_EXPR
::= LVAL_FLD ASG_INC_DEC
::= ASG_INC_DEC LVAL_FLD
JOIN_LIST ::= JOIN_SPECS
::=
JOIN_SPECS ::= JOIN_SPEC
::= JOIN_SPECS JOIN_SPEC
JOIN_SPEC ::= JOIN_ORDER WHERE IF_EXPR
::= JOIN_ORDER
JOIN_ORDER ::= JOIN_USING
::= JOIN_USING ORDER_GROUP
JOIN_USING ::= JOIN_CLAUSE USING_INDEX STD_ID
::= JOIN_CLAUSE USING_INDEX HINT_SYM STD_ID
::= JOIN_CLAUSE
JOIN_CLAUSE ::= OUTER JOIN_SYM SELECTOPT TABLE
OUTER ::= OUTER_SYM
::= EXISTS_SYM
::= NOTEXISTS_SYM
::=
SEARCH_STMT ::= SEARCH_JOIN STATEMENT
SEARCH_JOIN ::= SEARCH_WHERE JOIN_LIST
SEARCH_WHERE ::= SEARCH_ORDER WHERE IF_EXPR
::= SEARCH_ORDER
WHERE ::= WHERE_SYM
SUM_ELEM ::= SUM_FUNC LEFT_PAR_SYM STD_ID RGHT_PAR_SYM
SUM_FUNC ::= SUM_SYM
::= AVG_SYM
::= CNT_SYM
::= MINOF_SYM
::= MAXOF_SYM
SEARCH_ORDER ::= SEARCH_USING
::= SEARCH_USING ORDER_GROUP
ORDER_GROUP ::= ORDERBY_CLAUSE OPT_GROUPBY
::= GROUPBY_CLAUSE OPT_ORDERBY
OPT_GROUPBY ::= GROUPBY_CLAUSE
::=
OPT_ORDERBY ::= ORDERBY_CLAUSE
::=
ORDERBY_CLAUSE ::= ORDER_SYM OPT_BY ORDER_ELEM
::= ORDERBY_CLAUSE LIST_SEP_SYM ORDER_ELEM
GROUPBY_CLAUSE ::= GROUP_SYM OPT_BY ORDER_ELEM
::= GROUPBY_CLAUSE LIST_SEP_SYM ORDER_ELEM
ORDER_ELEM ::= STD_ID INDEX DIRECTION
::= ORDER_QUALIFIER STD_ID INDEX DIRECTION
ORDER_QUALIFIER ::= STD_ID PERIOD_SYM
INDEX ::= LEFT_BRKT_SYM INT_SYM RGHT_BRKT_SYM
::=
DIRECTION ::= ASCEND_SYM
::= DESCEND_SYM
::=
OPT_BY ::= BY_SYM
::=
SEARCH_USING ::= SEARCH_CLAUSE USING_INDEX STD_ID
::= SEARCH_CLAUSE USING_INDEX HINT_SYM STD_ID
::= SEARCH_CLAUSE
USING_INDEX ::= INDEX_SYM
SEARCH_CLAUSE ::= WHILE_SYM SELECT_SYM SELECTOPT CROSSCOMPANY_CLAUSE VALIDTIMESTATE_CLAUSE TABLE
CROSSCOMPANY_CLAUSE ::= CROSSCOMPANY_SYM
::= CROSSCOMPANY_SYM COLON_SYM STD_ID
::=
VALIDTIMESTATE_CLAUSE ::= VALIDTIMESTATE_SYM LEFT_PAR_SYM STD_ID LIST_SEP_SYM STD_ID RGHT_PAR_SYM
::= VALIDTIMESTATE_SYM LEFT_PAR_SYM STD_ID RGHT_PAR_SYM
::=
SELECTOPT ::=
::= SELECTOPT REVERSE_SYM
::= SELECTOPT FIRSTFAST_SYM
::= SELECTOPT FIRSTONLY_SYM
::= SELECTOPT FIRSTONLY_SYM1
::= SELECTOPT FIRSTONLY_SYM10
::= SELECTOPT FIRSTONLY_SYM100
::= SELECTOPT FIRSTONLY_SYM1000
::= SELECTOPT FORUPDATE_SYM
::= SELECTOPT NOFETCH_SYM
::= SELECTOPT FORCE_SELECT_ORDER_SYM
::= SELECTOPT FORCE_NESTED_LOOP_SYM
::= SELECTOPT FORCE_LITERALS_SYM
::= SELECTOPT FORCE_PLACEHOLDERS_SYM
::= SELECTOPT REPEATABLEREAD_SYM
::= SELECTOPT OPTIMISTICLOCK_SYM
::= SELECTOPT PESSIMISTICLOCK_SYM
::= SELECTOPT GENERATEONLY_SYM
FIND_STMT ::= FIND_JOIN SEMICOLON_SYM
FIND_JOIN ::= FIND_WHERE JOIN_LIST
FIND_WHERE ::= FIND_ORDER WHERE IF_EXPR
::= FIND_ORDER
FIND_ORDER ::= FIND_USING
::= FIND_USING ORDER_GROUP
FIND_USING ::= FIND_TABLE USING_INDEX STD_ID
::= FIND_TABLE USING_INDEX HINT_SYM STD_ID
::= FIND_TABLE
FIND_TABLE ::= SELECT_SYM SELECTOPT CROSSCOMPANY_CLAUSE VALIDTIMESTATE_CLAUSE TABLE
::= DELETE_SYM SELECTOPT CROSSCOMPANY_CLAUSE VALIDTIMESTATE_CLAUSE TABLE
TABLE ::= FLD_LIST OPT_FROM
FLD_LIST ::= MULT_SYM
::= FIELD_LIST
FIELD_LIST ::= FIELD_SPEC
::= FIELD_LIST LIST_SEP_SYM FIELD_SPEC
FIELD_SPEC ::= STD_ID INDEX
::= SUM_ELEM
OPT_FROM ::= FROM_SYM STD_ID
::=
SETFIELDSMODE ::=
UPDATE_STMT ::= UPDATETABLE SET_SYM SETFIELDSMODE FIELDASSIGNMENTS OPT_WHERE JOIN_LIST SEMICOLON_SYM
UPDATETABLE ::= UPDATE_SYM SELECTOPT CROSSCOMPANY_CLAUSE STD_ID
OPT_WHERE ::= WHERE IF_EXPR
::=
FIELDASSIGNMENTS ::= FIELDASSIGNMENTS LIST_SEP_SYM FIELDASSIGNMENT
::= FIELDASSIGNMENT
FIELDASSIGNMENT ::= STD_ID INDEX ASG_SYM IF_EXPR
INSERT_PART ::= INSERT_SYM CROSSCOMPANY_CLAUSE INSERT_NAME LEFT_PAR_SYM INSERTFIELDLIST RGHT_PAR_SYM
INSERT_NAME ::= STD_ID
INSERT_STMT ::= INSERT_PART FIND_JOIN SEMICOLON_SYM
INSERTFIELDLIST ::= INSERTFIELD
::= INSERTFIELDLIST LIST_SEP_SYM INSERTFIELD
INSERTFIELD ::= STD_ID INDEX
PRINT_STMT ::= PRINT_CLAUSE AT_CLAUSE SEMICOLON_SYM
PRINT_CLAUSE ::= PRINT IF_EXPR EXPR_LIST
PRINT ::= PRINT_SYM
AT_CLAUSE ::= AT_SYM IF_EXPR LIST_SEP_SYM IF_EXPR
::=
WINDOW_STMT ::= WINDOW_SYM IF_EXPR LIST_SEP_SYM IF_EXPR AT_CLAUSE SEMICOLON_SYM
IF_STMT ::= ELSE_STMT
::= IF_CONDS
IF_CONDS ::= IF_COND STATEMENT
IF_COND ::= IF_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
ELSE_STMT ::= ELSE STATEMENT
ELSE ::= IF_CONDS ELSE_SYM
SWITCH_STMT ::= CASE_LIST RIGHTBR_SYM
CASE_LIST ::= SWITCH_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM LEFTBR_SYM
::= CASE_TESTS STMTLIST
CASE_TESTS ::= CASE_HEADER COLON_SYM
::= CASE_LIST DEFAULT_SYM COLON_SYM
CASE_HEADER ::= CASE IF_EXPR
::= CASEALT IF_EXPR
CASE ::= CASE_LIST CASE_SYM
CASEALT ::= CASE_HEADER LIST_SEP_SYM
EXPR_STMT ::= ASG_STMT SEMICOLON_SYM
::= FUNCTION SEMICOLON_SYM
::= INTRINSICS SEMICOLON_SYM
::= EVAL SEMICOLON_SYM
PAUSE_STMT ::= PAUSE_SYM SEMICOLON_SYM
BP_CLAUSE ::= BP_SYM SEMICOLON_SYM
BREAK_STMT ::= BREAK_SYM SEMICOLON_SYM
CONTINUE_STMT ::= CONTINUE_SYM SEMICOLON_SYM
RETURN_CLAUSE ::= RETURN_SYM SEMICOLON_SYM
::= RETURN_SYM IF_EXPR SEMICOLON_SYM
TTS_STMT ::= TTSABORT_SYM SEMICOLON_SYM
::= TTSBEGIN_SYM SEMICOLON_SYM
::= TTSEND_SYM SEMICOLON_SYM
FLUSH_STMT ::= FLUSH ID_LIST SEMICOLON_SYM
FLUSH ::= FLUSH_SYM
TBLLOCK_STMT ::= TABLELOCK ID_LIST SEMICOLON_SYM
TABLELOCK ::= TABLELOCK_SYM
ID_LIST ::= STD_ID
::= ID_LIST LIST_SEP_SYM STD_ID
MOVE_REC_STMT ::= NEXT_SYM TABLE SEMICOLON_SYM
CHANGE_STMT ::= CHANGE_HEADER STATEMENT
CHANGE_HEADER ::= CHANGE LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
CHANGE ::= CHANGECOMP_SYM
::= CHANGESITE_SYM
UNCHECKED_STMT ::= UNCHECKED_HEADER STATEMENT
UNCHECKED_HEADER ::= UNCHECKED_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM