Power Platform -varastomallikyselyt

Seuraavat mallikyselyt suoritetaan PowerPlatformResources -taulukkoa vasten kohteessa Azure Resource Graph. Ne kattavat resurssien laskemisen ja jakelun, kenttien etsinnän, resurssien haut ja yhdistimien käyttöanalyysit. Yleiskatsaus Power Platform -varastosta on kohdassa Power Platform -varasto. Lisätietoja rakenteen ja kentän viitteistä on kohdassa Power Platform -varastorakenteen viittaus.

Kyselyjen suorittaminen

Voit suorittaa minkä tahansa näistä kyselyistä Azure Resource Graph liittymien kautta. Vaiheittaiset ohjeet ovat seuraavissa pikaoppaissa:

Määrät ja jakelu

Kaikkien resurssien kokonaismäärä

PowerPlatformResources
| count

Kokonaismäärä resurssityypin mukaan

PowerPlatformResources
| summarize resourceCount = count() by type
| order by resourceCount

Määrät ympäristön mukaan

PowerPlatformResources
| extend properties = parse_json(properties)
| extend environmentId = tostring(properties.environmentId)
| summarize resourceCount = count() by environmentId
| order by resourceCount desc

Määrät alueittain

PowerPlatformResources
| summarize resourceCount = count() by location
| order by resourceCount desc

Ylimmät omistajat kohteiden määrän mukaan

PowerPlatformResources
| extend properties = parse_json(properties)
| extend ownerId = tostring(properties.ownerId)
| summarize resourceCount = count() by ownerId
| order by resourceCount desc

Resurssihakuja

Yhden agentin etsiminen vuokraajasta

PowerPlatformResources
| where type == "microsoft.copilotstudio/agents"
| where name == "[Enter the agent's ID]"

Vinkki

Agentin tunnus löytyy Copilot Studion URL-osoitteesta agenttia tarkasteltaessa tai varastotaulukon Nimi-sarakkeesta .

Laske agentit valjastamalla

Näyttää erittelyn agenteista, jotka on luotu GitHub Copilot valjaiden, Copilot Chat valjaiden tai vakiovaljaiden avulla.

Agentin valjaat näkyvät Power Platform -hallintakeskuksen Valjaat-sarakkeessakohdassa Hallinta>Copilot Studio. Kyseinen sarake on vain käyttöliittymän sarake. Harness ei vielä palaudu agentin metatiedoissa, joten tämä kysely päättelee sen inventaarion palauttamista kentistä: properties.isCLIAgent, properties.model ja properties.createdIn. properties.harness Kun kenttä tulee saataville, voit tehdä sille kyselyn suoraan sen sijaan. Kenttien määritykset ovat kohdassa Microsoft Copilot Studio Agenttien varastorakenne.

PowerPlatformResources
| where type == "microsoft.copilotstudio/agents"
| extend properties = parse_json(properties)
| extend
    isCLIAgent = tobool(properties.isCLIAgent),
    model = tostring(properties.model),
    createdIn = tostring(properties.createdIn)
| extend harness = case(
    isCLIAgent == true, "GitHub Copilot",
    model =~ "Microsoft 365 Copilot" or createdIn =~ "Microsoft 365 Copilot Agent Builder", "Copilot Chat",
    "Standard")
| summarize agentCount = count() by harness
| order by agentCount desc

Luetteloi agentit valjaineen

Palauttaa yhden rivin kutakin agenttia ja sen valjaita kohden, jotta voit etsiä yksittäisiä agentteja ja kohdistaa niihin toimia sen sijaan, että vain lasket ne. Poista kommenttimerkintä riviltä where, jotta palautetaan vain GitHub Copilot -testivaljailla rakennetut agentit.

PowerPlatformResources
| where type == "microsoft.copilotstudio/agents"
| extend properties = parse_json(properties)
| extend
    isCLIAgent = tobool(properties.isCLIAgent),
    model = tostring(properties.model),
    createdIn = tostring(properties.createdIn)
| extend harness = case(
    isCLIAgent == true, "GitHub Copilot",
    model =~ "Microsoft 365 Copilot" or createdIn =~ "Microsoft 365 Copilot Agent Builder", "Copilot Chat",
    "Standard")
//| where harness == "GitHub Copilot"
| project agentName = tostring(properties.displayName),
          agentId = name,
          harness,
          environmentId = tostring(properties.environmentId),
          ownerId = tostring(properties.ownerId),
          createdAt = todatetime(properties.createdAt)
| order by harness asc, createdAt desc

Viimeisen 24 tunnin aikana luodut kohteet

PowerPlatformResources
| extend properties = parse_json(properties)
| extend createdAt = todatetime(properties.createdAt)
| where createdAt >= ago(24h)

Liitinkyselyt (esikatselu)

Seuraavissa kyselyissä analysoidaan liittimen käyttöä kaikissa resurssityypeissä, joita liitinvarasto (esikatselu) koskee. Jokainen kysely toimii pohjaan perustuvien sovellusten, mallipohjaisten sovellusten, pilvipalvelutyönkulkujen, agenttien työnkulkujen, työnkulkuagenttien työnkulkujen ja Copilot Studio-agenttien lähettämissä properties.powerPlatformConnectors -matriisissa.

Power Platform -resursseissa käytetyt parhaat liittimet

Luetteloi erillisten resurssien käyttämät liittimet. Hyödyllinen ymmärrys siitä, mitkä liittimet hallitsevat käyttöönottoa koko vuokraajassa.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| mv-expand connector = properties.powerPlatformConnectors
| extend connectorId = tostring(connector.connectorId)
| where isnotempty(connectorId)
| summarize ResourceCount = dcount(name) by connectorId
| order by ResourceCount desc
| take 10

Liitinten määrän jakautuminen resurssia kohden

Näyttää, kuinka monta resurssia käyttää 0,1, 2 tai useampia liittimiä. Hyödyllinen monimutkaisten poikkeavien arvojen havaitsemiseen.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| extend connectorCount = array_length(properties.powerPlatformConnectors)
| summarize ResourceCount = count() by toint(connectorCount)
| order by connectorCount asc

Etsi kaikki resurssit, jotka käyttävät tiettyä liitintä

Korvaa shared_sharepointonline etsittävällä liittimellä. Tästä kyselystä on hyötyä vaikutusanalyysissa, kun liittimessä on tunnettu ongelma, se on vanhentumassa tai se edellyttää uutta käyttölupaa.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| mv-expand connector = properties.powerPlatformConnectors
| where tostring(connector.connectorId) == "shared_sharepointonline"
| project resourceName = tostring(properties.displayName),
          resourceId = name,
          resourceType = type,
          environmentId = tostring(properties.environmentId),
          operationsUsed = connector.operations

Liittimen käyttö ympäristön mukaan

Näyttää luettelon jokaisesta ympäristössä käytetystä liittimestä ja sitä käyttävien eri resurssien määrän. Tästä luettelosta on hyötyä käyttöönottotapojen ymmärtämisessä ja DLP-käytäntöpäätösten informoimisessa.

PowerPlatformResources
| where type in (
    "microsoft.powerapps/canvasapps",
    "microsoft.powerapps/modeldrivenapps",
    "microsoft.powerautomate/cloudflows",
    "microsoft.powerautomate/agentflows",
    "microsoft.powerautomate/m365agentflows",
    "microsoft.copilotstudio/agents")
| extend properties = parse_json(properties)
| mv-expand connector = properties.powerPlatformConnectors
| extend connectorId = tostring(connector.connectorId)
| where isnotempty(connectorId)
| extend environmentId = tostring(properties.environmentId)
| summarize ResourceCount = dcount(name) by environmentId, connectorId
| order by environmentId asc, ResourceCount desc

Palaute

Onko tästä sivusta apua?

Last updated on 2026-08-20