Exporter des données OpenTelemetry vers Datadog dans Azure Container Apps

Ce guide montre comment configurer Azure Container Apps pour transférer des journaux, des suivis et des métriques vers Datadog à l’aide de l’assistant OpenTelemetry géré.

Pour plus d’informations sur l’agent OpenTelemetry managé, consultez Set up OpenTelemetry agents in Azure Container Apps.

Ce que vous apprenez

  • Créez une clé API Datadog pour l’ingestion de données de télémétrie.
  • Configurez une destination Datadog dans votre environnement Container Apps à l’aide de Bicep, de Azure CLI ou du portail Azure.
  • Appliquez des mises à jour de configuration à votre environnement et application Container Apps existants.
  • Vérifiez la télémétrie dans Datadog.

Prerequisites

  • Un abonnement Azure dans lequel vous pouvez créer des groupes de ressources et déployer des ressources Azure Container Apps.
  • Un environnement Datadog et une clé API.
  • Azure CLI installé et connecté.
  • Azure Container Apps extension CLI installée.
az extension add --name containerapp --upgrade

Créer une clé API Datadog

Créez une clé API Datadog avec des autorisations qui autorisent l’ingestion des données de télémétrie.

Vous avez besoin des valeurs Datadog suivantes pour la configuration OTel gérée par Container Apps :

  • site (valeur de site Datadog complète, par exemple : datadoghq.com, us3.datadoghq.com, us5.datadoghq.com, datadoghq.eu)
  • key (Clé API Datadog)

Pour la création et la gestion des clés Datadog, consultez l’API Datadog et les clés d’application.

Configurer des destinations OpenTelemetry

Utilisez l’une des options suivantes pour configurer Datadog en tant que destination OpenTelemetry dans votre environnement Container Apps.

Important

La configuration d’une destination OpenTelemetry managée ne produit pas automatiquement de données de télémétrie. Votre application doit également être instrumentée pour émettre des suivis, des métriques et des journaux à l’aide d’un Kit de développement logiciel (SDK) OpenTelemetry.

Définissez les variables CLI pour la commande de déploiement :

$RESOURCE_GROUP = "<resource-group-name>"
$DATADOG_SITE = "<datadog-site>" # Example: us3.datadoghq.com, us5.datadoghq.com, datadoghq.eu
$DATADOG_API_KEY = ""
$IMAGE = ""
$ACR_USERNAME = ""
$ACR_PASSWORD = ""

Utilisez un bloc de ressources d’environnement managé comme dans l’exemple suivant :

param datadogSite string
@secure()
param datadogApiKey string

var datadogDestinationName = 'dataDog'

resource environment 'Microsoft.App/managedEnvironments@2024-10-02-preview' = {
  name: ''
  location: ''
  properties: {
    openTelemetryConfiguration: {
      destinationsConfiguration: {
        dataDogConfiguration: {
          site: datadogSite
          key: datadogApiKey
        }
      }
      tracesConfiguration: {
        destinations: [
          datadogDestinationName
        ]
      }
      logsConfiguration: {
        destinations: [
          datadogDestinationName
        ]
      }
      metricsConfiguration: {
        destinations: [
          datadogDestinationName
        ]
      }
    }
  }
}

Utilisez un bloc de ressources d’application conteneur comme l’exemple suivant pour définir les variables d’environnement requises :

resource app 'Microsoft.App/containerApps@2024-10-02-preview' = {
  name: ''
  location: ''
  properties: {
    managedEnvironmentId: environment.id
    template: {
      containers: [
        {
          name: ''
          image: ''
          env: [
            {
              name: 'OTEL_SERVICE_NAME'
              value: ''
            }
            {
              name: 'OTEL_TRACES_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_METRICS_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_LOGS_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_EXPORTER_OTLP_PROTOCOL'
              value: 'grpc'
            }
          ]
        }
      ]
    }
  }
}

Pour les déploiements de production, transmettez des valeurs de jeton via des paramètres de Bicep sécurisés ou des Key Vault au lieu de coder en dur les secrets.

Après avoir mis à jour le modèle, déployez la configuration Bicep à partir de la racine du référentiel :

az deployment group create `
  --resource-group $RESOURCE_GROUP `
  --template-file infra/main.bicep `
  --parameters @infra/main.parameters.json `
  image=$IMAGE `
  acrUsername=$ACR_USERNAME `
  acrPassword=$ACR_PASSWORD `
  datadogSite="$DATADOG_SITE" `
  datadogApiKey="$DATADOG_API_KEY"

Votre application conteneur est maintenant configurée pour envoyer des données de télémétrie à Datadog via l’agent OpenTelemetry managé.

Vérifier les données OpenTelemetry dans Datadog

Une fois la configuration terminée, votre application conteneur commence à envoyer des données de télémétrie à Datadog via l’agent OpenTelemetry managé. Utilisez Datadog pour vérifier que les journaux, les suivis et les métriques proviennent bien de l’application et que les données apparaissent dans le contexte de service ou d’environnement attendu.

Validez les résultats à l’aide d’outils Datadog comme l’exploration des journaux, le traçage distribué et la recherche de métriques. Le chemin de requête ou de navigation exact varie en fonction des données que vous inspectez.

Pour plus d’informations sur l’exploration des données dans Datadog, consultez Observabilité et télémétrie Datadog.

  • Last updated on