Remarque
L’accès à cette page nécessite une autorisation. Vous pouvez essayer de vous connecter ou de modifier des répertoires.
L’accès à cette page nécessite une autorisation. Vous pouvez essayer de modifier des répertoires.
Cet article fournit la référence syntaxique pour X++.
X++ keywords
Le tableau suivant liste les mots-clés X++ réservés. Vous ne pouvez pas utiliser ces mots-clés à d’autres fins.
| Reserved word | Description | Related information |
|---|---|---|
| ! | Not. | Relational Operators |
| != | Opérateur d’inégalité (différent de). | Relational Operators |
| # | Préfixe sur les noms de macros. | Guide pratique pour utiliser #define et #if pour tester une macro |
| & | Binary AND. | Arithmetic Operators |
| && | Logical AND. | Relational Operators |
| ( | Opérateur d’appel de fonction, qui indique le début de l’appel de fonction. | |
| ) | Opérateur d’appel de fonction, qui indique la fin de l’appel de fonction. | |
| * | Multiply. L’astérisque (*) est également utilisé dans X++ SQL. Une utilisation consiste à signer tous les champs des tables d’une select instruction. Une autre utilisation est un caractère générique avec l’opérateur like , pour signer 0 à de nombreux caractères de n’importe quel type. L’opérateur like utilise également le ? caractère. |
Arithmetic Operators |
| ^ | Binary XOR. | Arithmetic Operators |
| | | Binary OR. | Arithmetic Operators |
| || | Logical OR. | Relational Operators |
| ~ | Not. | Arithmetic Operators |
| + | Plus. | Arithmetic Operators |
| ++ | Increment. | Assignment Operators |
| += | Additive assignment. | Assignment Operators |
| , | Comma operator. Les expressions séparées par des virgules sont évaluées séquentiellement de gauche à droite. | |
| - | Minus. | Arithmetic Operators |
| -- | Decrement operator. | Assignment Operators |
| -= | Subtractive assignment. | Assignment Operators |
| . | Par exemple, formRun.run l’opérateur d’accès membre de classe accède à la run méthode d’un objet du type FormRunde classe. |
|
| / | Divide. | Arithmetic Operators |
| \ | Échappement dans des chaînes. Échappe aux guillemets supplémentaires, et à certaines lettres comme '\t' pour tab. |
|
| @ | Échappement de mots clés. Par exemple, var @str = 1@abstract; ne parvient pas à compiler sans le @ caractère qui provoque l’affichage d’une chaîne suivante comme identificateur. Elle affecte également les chaînes littérales, en négation de l’effet du caractère d’échappement \ et en permettant à la chaîne d’étendre plusieurs lignes dans le code source. La nouvelle ligne est représentée par un caractère de 0x0A hexadécimal, communément appelé flux de ligne. Aucun caractère de retour chariot de 0x0D hexadécimal n’est inclus, comme dans 0x0D0A. |
|
| : | Le caractère deux-points (:) est utilisé pour délimiter les valeurs des cas majuscules dans l’énoncé switch . |
|
| :: | Utilisé pour appeler les méthodes statiques (de classe) : ClassName::methodName() and to designate enumeration literals, like NoYes::Yes. |
|
| ; | Terminates statements. Utilisé dans for des boucles ou en tant que séparateur d’initialiseur, de mise à jour et de parties de vérification de valeur. |
|
| < | Less than. | Relational Operators |
| << | Left shift. | Arithmetic Operators |
| <= | Inférieur ou égal. | Arithmetic Operators |
| = | Assignment operator. L’argument à gauche de «= » est défini sur la valeur de l’argument à droite. | Assignment Operators |
| == | Retourne true si les expressions sont égales. | Relational Operators |
| > | Greater than. | Relational Operators |
| >= | Supérieur ou égal. | Relational Operators |
| >> | Maj droite au niveau du bit. Cet opérateur déplace les bits du côté gauche par la quantité située sur le côté droit. Chaque décalage divise efficacement le nombre par 2^n, où n correspond au nombre de positions décalées. | Arithmetic Operators |
| ?: | Ternary operator. Le caractère point d’interrogation (?) est également utilisé par l’opérateur like pour signifier exactement un caractère de n’importe quel type. L’opérateur like utilise également le * caractère. |
Opérateur ternaire ( ?) |
| [ | Déclarateur de tableau, ouvert. Doit être utilisé avec « ] ». | |
| ] | Déclarateur de tableau, fermer. Doit être utilisé avec « [ ». | |
| { | Démarre une instruction composée qui peut à son tour contenir zéro ou plusieurs instructions. L’instruction composée se termine par le « } » correspondant le plus proche. | |
| } | Indique la fin de l’instruction composée décrite ci-dessus. Un « { » doit apparaître avant la première de ces instructions. | |
| abstract | Modificateur de classe et de méthode. Une classe abstraite ne peut pas être construite avec le nouveau mot clé : seules les classes dérivées de celle-ci peuvent. Une méthode abstraite ne peut pas être appelée, seules les méthodes qui le remplacent peuvent. Une table peut être modifiée en abstract en définissant sa propriété Abstract sur Oui dans l’AOT, ou en utilisant la DictTable classe. La propriété Abstract est par défaut No, et elle ne peut être définie que si la table est étendue par une autre table. Chaque ligne d’une table abstraite doit avoir une ligne dépendante dans une table dérivée. Cela signifie que chaque ligne d’une table abstraite a une valeur supérieure à zéro dans son champ de propriété InstanceRelationType. Il n’y a aucun autre effet de marquer une table comme abstraite. De manière informelle, les programmeurs utilisent souvent le terme concret pour décrire une classe non abstraite. |
Vue d’ensemble de l’héritage des tables modificateurs de méthode |
| anytype | Type qui peut contenir des valeurs de n’importe quel type. | Anytype |
| as | Nécessaire lorsque vous affectez une variable de classe de base à une variable de classe dérivée. Par exemple, étant donné une Derived classe qui étend une Base classe, l’instruction myDerived = myBase as Derived; évite une erreur du compilateur à l’aide du mot clé. Ce mot clé s’applique également lorsque vous affectez une variable de table de base à une variable de table dérivée. Si la valeur (myBase) n’est pas du type désigné (dérivé), l’expression retourne null. |
Opérateurs d’expression : Is and As for Inheritance |
| asc | Option sur la ou orderla clause d’une bygroupby instruction.select Le tri est croissant. |
Syntaxe de l’instruction Select |
| at | Spécifie la position d’une fenêtre d’impression dans le cadre d’une print instruction. L’instruction print ne doit pas être utilisée. |
Print Statements |
| avg | Retourne la moyenne des champs des lignes spécifiées par la group by clause dans une select instruction. |
Syntaxe de l’instruction Select |
| break | Sortie immédiate d’un bloc de code itératif. | Break Statements |
| breakpoint | Représente un point d’arrêt défini à des fins de débogage. Pour définir un point d’arrêt dans votre code, écrivez : breakpoint; |
|
| by | Partie d’un terme réservé, tel que le groupe par et l’ordre par. | |
| byref | Précise que le paramètre transmis à la méthode appelée est transmis par référence (adresse), au lieu de par valeur. Byref est utilisé dans X++ lors de l’appel d’une méthode .NET qui prend un paramètre par référence (par exemple, avec les mots clés C# out ou ref). | Guide pratique pour utiliser le mot clé byref pour l’interopérabilité CLR. |
| case | Sélection dans une switch instruction. |
Switch Statements |
| catch | Utilisé dans la gestion des exceptions. | Gestion des exceptions avec try et intercepter des mots clés |
| changeCompany | Modifie les paramètres de base de données d’une autre entreprise. | Modifier le modèle de conception de l’entreprise |
| class | Déclare une classe. | Classes dans X++ |
| container | Désigne le container type. Les conteneurs contiennent une séquence de valeurs atomiques et d’autres conteneurs. |
Containers |
| continue | Force l’itération suivante d’une boucle. | Continue Statements |
| count | Retourne le nombre d’enregistrements des lignes spécifiées par la group by clause dans une select instruction. |
Syntaxe de l’instruction Select |
| crossCompany | Provoque un select retour de données pour toutes les entreprises à partir de laquelle l’utilisateur est autorisé à lire. |
Concepts de base du code X++ inter-entreprises |
| date | Spécifie une variable de type date. |
Dates |
| default | Cas par défaut dans les switch instructions. Le bloc de code dans la partie par défaut est exécuté si la valeur du switch ne correspond à aucune des case clauses fournies dans l’instruction switch . |
Switch Statements |
| delegate | Un membre de classe qui peut stocker plusieurs références à des méthodes dans d’autres classes, et appeler toutes ces méthodes lorsqu’il est sollicité. Un délégué peut stocker des références à différents types de méthodes, notamment : méthodes statiques sur les classes X++ ; méthodes d’instance sur les classes X++ ; méthodes sur les classes .NET Framework. | Terminologie des événements et mots clés X++, comparaison C# : événement |
| delete_from | Supprime les enregistrements de la base de données. | delete_from |
| desc | Option sur la ou order by la clause d’une group byselect instruction. Le tri est décroissant. |
Syntaxe de l’instruction Select |
| display | Method modifier. Une display méthode affiche des valeurs calculées dans un contrôle de forme. Contrairement aux champs classiques, ces valeurs ne sont pas stockées dans la base de données mais sont calculées dynamiquement. |
Method Modifiers |
| div | Integer division. | Arithmetic Operators |
| do | Début d’une do...while boucle. |
Do...while Loops |
| edit | Method modifier. Une edit méthode dans X++ permet aux utilisateurs de modifier des valeurs dans un contrôle de formulaire lors de l’exécution d’une logique personnalisée. Contrairement aux méthodes qui n’affichent que des valeurs calculées, edit les méthodes permettent à la fois la display visualisation et le montage. |
Method Modifiers |
| else | Exécution conditionnelle (if...else). La else partie de l’énoncé if est exécutée si l’expression dans l’énoncé if évalue à false. |
si et si ... else, instructions |
| eventHandler | Doit être utilisé chaque fois que vous ajoutez ou supprimez une référence de méthode d’un délégué à l’aide de l’opérateur ou += de l’opérateur-=. Par exemple : myDelegate += eventHandler(OtherClass::myStaticMethod); |
Terminologie des événements et mots clés X++, comparaison C# : événement |
| exists | Utilisé avec join des clauses dans select les instructions. |
Syntaxe de l’instruction Select |
| extends | Clause de déclaration de classe ou d’interface. Si votre classe n’étend pas explicitement une autre classe, votre classe est considérée comme étendre la Object classe (comme si vous aviez écrit « étend l’objet »). |
Création d’une sous-classe |
| false | Boolean literal. | Booleans |
| final | Modificateur de classe et de méthode. Spécifie que cette méthode ne peut pas être substituée. | Method Modifiers |
| firstFast | Utilisé dans select les instructions pour accélérer la récupération pour la première ligne. |
Syntaxe de l’instruction Select |
| firstOnly | Utilisé dans select les instructions pour extraire uniquement le premier enregistrement. Le firstOnly mot clé ne garantit pas qu’un maximum d’un enregistrement est récupéré par une instruction SQL select X++. Si l’AOS peut utiliser le EntireTable cache pour répondre aux demandes de données de l’instruction select , le firstOnly mot clé est ignoré. |
Sélection de la mise en cache basée sur l’ensemble d’instructions |
| firstOnly10 | Identique à firstOnly, sauf retourne 10 lignes au lieu d’une. | |
| firstOnly100 | Identique à firstOnly, sauf retourne 100 lignes au lieu d’une. | |
| firstOnly1000 | Identique à firstOnly, sauf retourne 1 000 lignes au lieu d’une. | |
| flush | Efface l’intégralité du cache de table. Cette action peut être utile lorsque vous souhaitez vous assurer que toute modification apportée à la table soit immédiatement reflétée dans les opérations suivantes. | Set-based Caching |
| for | Itération de boucle. | For Loops |
| forceLiterals | Utilisé dans select les instructions pour révéler les valeurs réelles utilisées dans where les clauses de la base de données Microsoft SQL Server au moment de l’optimisation. |
Syntaxe de l’instruction Select |
| forceNestedLoop | Force la base de données SQL Server à utiliser un algorithme de boucle imbriquée pour traiter une instruction SQL particulière contenant un join. |
Syntaxe de l’instruction Select |
| forcePlaceholders | Utilisé dans select les instructions pour indiquer au noyau de ne pas révéler les valeurs réelles utilisées dans where les clauses à la base de données Microsoft SQL Server au moment de l’optimisation. |
Syntaxe de l’instruction Select |
| forceSelectOrder | Force la base de données SQL Server à accéder aux tables d’une jointure dans l’ordre spécifié. | Syntaxe de l’instruction Select |
| forUpdate | Sélectionne les enregistrements exclusivement pour la mise à jour. L’opération à effectuer sur les enregistrements récupérés est une mise à jour. Selon la base de données sous-jacente, les enregistrements peuvent être verrouillés pour d’autres utilisateurs. | Syntaxe de l’instruction Select |
| from | Partie d’une select instruction. La from clause spécifie le tampon de table dans lequel se trouvent les colonnes. |
Syntaxe de l’instruction Select |
| group | Partie de la group by clause dans une select instruction. |
Syntaxe de l’instruction Select |
| if | Conditional execution. | si et si ... else, instructions |
| implements | Implémentation d’un interface. |
Interfaces Overview |
| insert_recordset | Copie les données d’une ou de plusieurs tables dans une table de destination résultante sur un seul voyage de serveur. | insert_recordset |
| int | Spécifie une variable de type integer (32 bits). |
Integers |
| int64 | Spécifie une variable de type integer (64 bits). |
Integers |
| interface | Interface declaration. | Interfaces Overview |
| is | Demande si l’objet référencé par une variable de classe hérite de la classe donnée ou est de la classe donnée. Par exemple, étant donné une Derived classe qui étend une Base classe, l’expression (myDerived is Base) retourne true. Ce mot clé s’applique à l’héritage de classe et à l’héritage de table. |
Opérateurs d’expression : Is and As for Inheritance |
| join | Les tables sont jointes sur des colonnes communes aux deux tables. Vous pouvez générer un jeu de résultats unique basé sur plusieurs tables à l’aide de jointures. | Syntaxe de l’instruction Select |
| like | Teste les correspondances par modèle, avec des symboles génériques « * » et « ? ». | Relational Operators |
| maxof | Retourne le maximum des champs des lignes spécifiées par la group by clause. |
Syntaxe de l’instruction Select |
| minof | Retourne le minimum des champs des lignes spécifiées par la group by clause. |
Syntaxe de l’instruction Select |
| mod | Retourne le reste entier de l’expression de gauche1 divisé par l’expression de droite2. De façon informelle, il s’agit parfois de l’opérateur modulo.
(12 mod 7) == 5 est vrai. |
|
| new | Operator. Crée une instance d’une classe ou alloue de la mémoire pour un tableau. | |
| next | Récupère l’enregistrement suivant dans une table ou appelle la méthode suivante dans une séquence de commandes en chaîne. | |
| noFetch | Indique qu’aucun enregistrement ne doit être récupéré maintenant. | Syntaxe de l’instruction Select |
| notExists | Utilisé avec join des clauses dans select les instructions. |
Syntaxe de l’instruction Select |
| null | Symbolic constant. | |
| optimisticLock | Force une instruction à s’exécuter avec un contrôle d’accès concurrentiel optimiste, même si une valeur différente est définie sur la table. | Syntaxe de l’instruction Select |
| order | Partie de la order by clause dans une select instruction. |
Syntaxe de l’instruction Select |
| outer | outer join. | Syntaxe de l’instruction Select |
| pause | Arrête l’exécution d’un travail. L’utilisateur est invité à indiquer si l’exécution doit continuer. Vous ne devez pas utiliser cette instruction dans le code de production. | Select Statements |
| pessimisticLock | Force une instruction à s’exécuter avec un contrôle d’accès concurrentiel pessimiste, même si une valeur différente est définie sur la table. | Syntaxe de l’instruction Select |
| Vous permet d’afficher la sortie à l’écran. Vous ne devez pas utiliser cette instruction dans le code de production. | Print Statements | |
| private | Modificateur d’accès aux méthodes. La méthode ne peut être utilisée que dans la classe qui déclare la méthode. | Contrôle d’accès aux méthodes |
| protected | Modificateur d’accès aux méthodes. La méthode peut être utilisée à partir de méthodes dans la classe déclarant les méthodes et dans toutes les classes dérivées. | Contrôle d’accès aux méthodes |
| public | Modificateur d’accès aux méthodes. La méthode peut être appelée à partir de n’importe quelle classe. | Contrôle d’accès aux méthodes |
| real | Désigne le real type, un type décimal sans arrondi d’erreurs. |
Reals |
| repeatableRead | Précise qu’aucune autre transaction ne peut modifier les données que la transaction en cours lit avant la fin de celle-ci. Une transaction explicite se termine soit à ttsAbort , soit au ttsCommit le plus externe. Pour une instruction select autonome, la durée de la transaction est la durée de la commande select . Toutefois, la base de données applique parfois l’équivalent de repeatableRead dans des instructions select individuelles, même sans ce mot clé apparaissant dans votre code X++ (selon la façon dont la base de données décide d’analyser les tables). | Pour plus d’informations, consultez la documentation relative au produit de base de données relationnelle sous-jacent. |
| retry | Utilisé dans la gestion des exceptions. | Gestion des exceptions avec try et intercepter des mots clés |
| return | Retourne à partir d’une méthode. | Déclaration des méthodes |
| reverse | Les enregistrements sont retournés dans l’ordre inverse. | Syntaxe de l’instruction Select |
| select | La select clause désigne les colonnes ou vues affichées dans le jeu de résultats. |
Select Statements |
| setting | Utilisé avec la update_recordset commande. |
update_recordset |
| static | Les méthodes statiques ne peuvent pas se référer aux variables d’instance (seulement aux variables statiques). Invoquez des méthodes statiques en utilisant le nom de la classe plutôt que sur une instance de la classe («MyClass.aStaticProcedure »). |
Method Modifiers |
| str | Désigne le string type. |
Strings |
| sum | Retourne la somme des champs des lignes spécifiées par la group by clause dans une select instruction. |
Syntaxe de l’instruction Select |
| super | Appelle la méthode que la méthode actuelle supprime. | Table Methods |
| switch | Switch statement. | Switch Statements |
| tableLock | Obsolète; tableLock n’est plus disponible. | |
| this | Référence à l’instance actuelle de la classe. Utilisé dans le code X++ à l’intérieur d’une méthode d’instance de la classe. Utilisé pour référencer les membres de la méthode de la classe. | |
| throw | Utilisé dans la gestion des exceptions. | Gestion des exceptions avec try et intercepter des mots clés |
| true | Boolean literal. | Booleans |
| try | Utilisé dans la gestion des exceptions. | Gestion des exceptions avec try et intercepter des mots clés |
| ttsAbort | Annule (défausse) tous les changements dans la transaction en cours. | Transaction Integrity |
| ttsBegin | Marque le début d’une transaction. | Transaction Integrity |
| ttsCommit | Marque la fin d’une transaction, en commençant les modifications dans les tables. | Transaction Integrity |
| update_recordset | Autorise la manipulation des jeux de lignes dans une seule opération. | update_recordset |
| validTimeState | Filtre les lignes qu’une instruction SQL select X++ récupère à partir d’une table d’état temporelle valide. Par exemple : select validTimeState(myDateEffective) * from xMyTable; ... ou... select validTimeState(myDateFrom, myDateTo) * from xMyTable; |
Effets des tables d’état de temps valides sur les opérations de lecture et d’écriture |
| void | Identifie une méthode qui ne retourne pas de valeur. | Déclaration des méthodes |
| where | Partie d’une select instruction. La where clause spécifie les conditions à satisfaire ; autrement dit, les lignes que vous souhaitez inclure dans le résultat. |
Syntaxe de l’instruction Select |
| while | Iteration statement. Exécute une instruction à plusieurs reprises tant que la condition de test est vraie. | Boucles While lors de la sélection d’instructions |
| window | Vous permet de modifier la taille de la fenêtre de sortie. Utilisé avec print des instructions non recommandées dans le code de production. |
Print Statements |
Expressions syntax
Utilisez une expression en X++ pour des opérations mathématiques ou logiques. Construisez des expressions sur les types de données du langage. Une expression retourne toujours une valeur d’un certain type. Utilisez cette valeur dans les calculs, les devoirs, les instructions conditionnelles, etc.
Description EBNF des expressions en X++
| Term | Definition | |
|---|---|---|
| Expression | = | Expression simple [RelationalOperator Simple-expression ] |
| RelationalOperator | = | = |
| Simple-expression | = | Expression simple [ + |
| Term | = | Compfactor { Multipl-operator CompFactor } |
| Mult-operator | = | * |
| CompFactor | = | [ ! ] [ - |
| Factor | = | Literal |
| Enum | = | EnumName :: Littéral |
| Variable | = | Identificateur [ [ Expression ] ] [ . Expression ] |
| FunctionCall | = | [ Expression (. |
| If-expression | = | Expression ? Expression : Expression |
Des restrictions sémantiques s’appliquent à la syntaxe précédente. Vous ne pouvez appeler aucune méthode en utilisant l’opérateur :: . De même, vous ne pouvez pas utiliser ce mot-clé sans un objet actif. Cet objet doit être dans une méthode d’instance, et ainsi de suite.
Examples
| Exemple d’expression | Description |
|---|---|
1 |
Littéral entier. |
| NoYes::No | An enum-reference. |
A |
A variable-reference. |
| Debtor::Find("1") | Un appel de méthode statique (retourne une variable client). |
| (Un > 3 ? vrai : faux) | Expression if qui retourne true ou false. |
| (sélectionnez CustTable où CustTable.Account == « 100 »). NameRef | A select-expression. Retourne le champ nameref dans la table client. Il s’agit d’une chaîne. |
| A >= B | Expression logique. Retourne true ou false. |
| A + B | Expression arithmétique. Somme A et B. |
| A + B / C | Calcule B/C, puis l’ajoute à A. |
| ~A + ceci. Value() | Sums binary not A et the result of the method-call Value on the object in scope (this). |
| Debtor::Find("1").NameRef | Retourne le champ NameRef de l’enregistrement client trouvé. |
| Debtor::Find("1").Balance() | Un appel de méthode dans Balance la table client (Débiteur ::Find retourne un client). Retourne le solde du client avec le numéro de compte 1. |
EBNF overview
La forme Backus Naur étendue (EBNF) est un métalangage. Ce guide l’utilise pour décrire la syntaxe du langage. Une définition EBNF se compose de règles de production, de terminaux et de terminaux non déterminaux. Le tableau suivant présente les termes clés.
| Key terms | Example | Description |
|---|---|---|
| Terminals | Work_Team | Un terminal est un caractère ou une chaîne de caractères qui ne changent jamais. |
| Nonterminals | Employee |
Une expression non déterministe est une description d’une partie d’une phrase valide dans la langue définie par une règle de production ou une description textuelle. Un symbole non déterministe peut toujours être étendu à un ou plusieurs symboles terminal. |
| Production rules | Employé = Développeur | Tester |
Example
Work_Team = Employé responsable {, Employee} Employee = Developer | Testeur Cet exemple définit une Work_Team comme composée d’un Manager ou plusieurs Employees. Un Employee est défini comme étant un Developer, ou un Tester. Les symboles utilisés dans l’exemple sont décrits dans le tableau suivant.
Symboles spéciaux dans EBNF
| Symbol | Description |
|---|---|
| (Expression) | Les parenthèses contiennent les symboles (terminaux et non déterminaux) ensemble. Ils peuvent être placés n’importe où sur le côté droit d’une règle de production. |
| Expression1 | Expression2 |
| [Expression] | Facultatif : les éléments entre [ et ] sont facultatifs. Tous ou aucun des éléments entre crochets n’est inclus. |
| {Expression} | Répétez : les éléments compris entre { et } sont facultatifs, mais peuvent être répétés autant de fois que nécessaire. |
Par exemple, si les accessoires que vous achetez pour votre vélo se composent d’une selle, de porte-bouteilles d’eau, de cloches et de cornes, et que vous pourriez avoir une cloche ou une corne, et zéro, un ou plusieurs porte-bouteilles d’eau, et exactement une selle, cela peut être exprimé comme : Bicycle_Accessories = selle [cloche | corne] {water_bottle_holders} Cette grammaire définit les possibilités suivantes : saddlesaddle bellsaddle horn selle water_bottle_holder cloche de selle water_bottle_holder cloche de selle water_bottle_holder water_bottle_holder Et ainsi de suite.
X++ Grammar
Cet article présente la grammaire formelle du langage X++.
Comment interpréter la grammaire BNF formelle
Cette section décrit la grammaire de X++ dans Backus Naur Form (BNF). Un petit exemple de BNF est décrit ici.
AA ::= BB CC_SYM
BB ::= JJ_SYM
::= KK_SYM
AA est le nom d’une règle de production. Une AA requête nécessite un BBCC_SYM, suivi d’une CC_SYM. A BB est également une règle de production. Par conséquent, BB n’est pas un terminal.
BB doit être un JJ_SYM ou un KK_SYM. Les deux JJ_SYM et KK_SYM sont des terminaux, car ils ne sont pas les noms d’autres règles de production. CC_SYM est également un terminal.
Dans la grammaire BNF pour X++, la plupart des terminaux ont _SYM comme suffixe de leur nom.
Grammaire X++ formelle dans BNF
Cette section contient le BNF qui définit la grammaire de X++.
CMPL_UNIT ::= RETTYPEID FUNC_HDR FUNC_HEAD BODY
::= RETTYPEID DATA_HDR CLASS_DECL
::= EXPR_HDR IF_EXPR SEMIOPT
::= RETTYPEID FUNC_HDR EVENT_DECL BODY
SEMIOPT ::= SEMICOLON_SYM
::=
CLASS_DECL ::= CLASS_HEADER LEFTBR_SYM DCL_EVENTMAP DCL_LIST RIGHTBR_SYM
CLASS_HEADER ::= ATTRIBUTE_DEF CLASS_MODIFIERS CLASSORINTERFACE STD_ID EXTENDS IMPLEMENTS
ATTRIBUTE_DEF ::= LEFT_BRKT_SYM ATTRIBUTE_INIT ATTRIBUTE_LIST RETTYPEID RGHT_BRKT_SYM
::=
ATTRIBUTE_INIT ::=
.
ATTRIBUTE_LIST ::= ATTRIBUTE
::= ATTRIBUTE_LIST LIST_SEP_SYM ATTRIBUTE
ATTRIBUTE ::= STD_ID
::= ATTRIBUTE_WITH_ARGS_BEGINS ATTRIBUTE_WITH_ARGS_ENDS
ATTRIBUTE_WITH_ARGS_BEGINS ::= STD_ID LEFT_PAR_SYM
ATTRIBUTE_WITH_ARGS_ENDS ::= ATTRIBUTE_ARGS RGHT_PAR_SYM
ATTRIBUTE_ARGS ::= ATTRIBUTE_CONSTANT
::= ATTRIBUTE_ARGS LIST_SEP_SYM ATTRIBUTE_CONSTANT
ATTRIBUTE_CONSTANT ::= INT_SYM
::= DBL_SYM
::= STR_SYM
::= DATE_SYM
::= DATETIME_SYM
::= STD_ID DBLCOLON_SYM STD_ID
::= TRUE_SYM
::= FALSE_SYM
::= INT64_SYM
::= ATTRIBUTE_INTRINSIC
ATTRIBUTE_INTRINSIC ::= INTRI_ID LEFT_PAR_SYM IARGS RGHT_PAR_SYM
CLASSORINTERFACE ::= CLASS_SYM
::= INTERFACE_SYM
CLASS_MODIFIERS ::= CLASS_MODS
::=
CLASS_MODS ::= CLASS_MODIFIER
::= CLASS_MODS RETTYPEID CLASS_MODIFIER
CLASS_MODIFIER ::= PUBLIC_SYM
::= FINAL_SYM
::= STATIC_SYM
::= ABSTRACT_SYM
::= PRIVATE_SYM
EXTENDS ::= EXTENDS_SYM STD_ID
::=
IMPLEMENTS ::= IMPLEMENTS_SYM IMPLEMENTLIST
::=
IMPLEMENTLIST ::= STD_ID
::= IMPLEMENTLIST LIST_SEP_SYM STD_ID
DCL_EVENTMAP ::=
EVENT_DECL ::= ATTRIBUTE_DEF EVENT_HEADER PARM_DCL_LIST
EVENT_HEADER ::= EVENT_MODIFIER VOID_TYPE_SYM STD_ID
EVENT_MODIFIER ::= EVENT_SYM
FUNC_HEAD ::= ATTRIBUTE_DEF FUNCNAME PARM_DCL_LIST
FUNCNAME ::= FUNCTYPE STD_ID
FUNCTYPE ::= FUNC_MODIFIERS DECL_TYPE
FUNC_MODIFIERS ::= FUNC_MODS
::=
FUNC_MODS ::= RETTYPEID FUNC_MODIFIER
::= FUNC_MODS RETTYPEID FUNC_MODIFIER
FUNC_MODIFIER ::= PUBLIC_SYM
::= PRIVATE_SYM
::= PROTECTED_SYM
::= FINAL_SYM
::= STATIC_SYM
::= ABSTRACT_SYM
::= DISPLAY_SYM
::= EDIT_SYM
BODY ::= LEFTBR_SYM DCL_FUNC_LIST SEMIOPT SECAUTHZCHECK STMTLIST SECAUTHZEND RIGHTBR_SYM
SECAUTHZCHECK ::=
SECAUTHZEND ::=
RETTYPEID ::=
FUNCTION_DEF ::= FUNC_HEADER PARM_DCL_LIST LOCAL_BODY
FUNC_HEADER ::= DECL_TYPE STD_ID
PARM_DCL_LIST ::= RETTYPEID PARM_START PARM_LIST_OPT RGHT_PAR_SYM RETTYPEID
PARM_START ::= LEFT_PAR_SYM
PARM_LIST_OPT ::= PARM_LIST
::=
PARM_LIST ::= DCL_INIT
::= PARM_LIST LIST_SEP_SYM DCL_INIT
LOCAL_BODY ::= LEFTBR_SYM DCL_LIST SEMIOPT STMTLIST RETTYPEID RIGHTBR_SYM
DCL_LIST ::= DCL_LIST2
::=
DCL_LIST2 ::= DCL_STMT
::= DCL_LIST2 DCL_STMT
DCL_FUNC_LIST ::= DCL_FUNC_LIST2
::=
DCL_FUNC_LIST2 ::= DCL_STMT
::= FUNCTION_DEF
::= DCL_FUNC_LIST2 DCL_STMT
::= DCL_FUNC_LIST2 FUNCTION_DEF
DCL_STMT ::= DCL_INIT_LIST RETTYPEID SEMICOLON_SYM
DCL_INIT_LIST ::= DCL_INIT
::= DCL_CLIST ASG_CLAUSE
DCL_CLIST ::= DCL_INIT_LIST LIST_SEP_SYM STD_ID ARR_DCL_IDX
DCL_INIT ::= DECL ASG_CLAUSE
DECL ::= DECL_TYPE STD_ID ARR_DCL_IDX
DECL_TYPE ::= STR_TYPE_SYM STR_LEN
::= INT_TYPE_SYM
::= DBL_TYPE_SYM
::= DATE_TYPE_SYM
::= DATETIME_TYPE_SYM
::= TYPE_ID
::= QUEUE_TYPE_SYM
::= VOID_TYPE_SYM
::= ANY_TYPE_SYM
::= GUID_TYPE_SYM
::= INT64_TYPE_SYM
::= CLR_TYPE
CLR_TYPE ::= CLR_NAMESPACE TYPE_ID CLR_ARRAY_TYPE_EXT
::= CLR_NAMESPACE CLR_TYPE
CLR_NAMESPACE ::= TYPE_ID PERIOD_SYM
CLR_ARRAY_TYPE_EXT ::= CLR_ARRAY_SPEC
::=
CLR_ARRAY_SPEC ::= CLR_ARRAY_PART
::= CLR_ARRAY_SPEC CLR_ARRAY_PART
CLR_ARRAY_PART ::= CLR_ARRAY_LEFT_PART CLR_RECTANGULAR_LIST RGHT_BRKT_SYM
CLR_ARRAY_LEFT_PART ::= LEFT_BRKT_SYM
CLR_RECTANGULAR_LIST ::= CLR_COMMA_LIST
::=
CLR_COMMA_LIST ::= LIST_SEP_SYM
::= CLR_COMMA_LIST LIST_SEP_SYM
STR_LEN ::= INT_SYM
::=
ARR_DCL_IDX ::= LEFT_BRKT_SYM RANGE ARRAY_MEM RGHT_BRKT_SYM
::=
RANGE ::= IF_EXPR
::=
ARRAY_MEM ::= LIST_SEP_SYM IF_EXPR
::=
ASG_CLAUSE ::= INIT_START IF_EXPR
::=
INIT_START ::= ASG_SYM
ASG_STMT ::= LVAL_FLD ASSIGN IF_EXPR
::= LVAL_LIST ASG_SYM IF_EXPR
::= LVAL_FLD ASG_INC_DEC
::= ASG_INC_DEC LVAL_FLD
::= LVAL_FLD ASG_EVENT_HANDLER
ASSIGN ::= ASG_SYM
::= ASGINC_SYM
::= ASGDEC_SYM
ASG_INCDEC ::= ASGINC_SYM
::= ASGDEC_SYM
ASG_EVENT_HANDLER ::= ASG_INCDEC EVENTHANDLER_SYM LEFT_PAR_SYM QUALIFIER STD_ID RGHT_PAR_SYM
::= ASG_INCDEC EVENTHANDLER_SYM LEFT_PAR_SYM STD_ID DBLCOLON_SYM STD_ID RGHT_PAR_SYM
::= ASG_INCDEC EVENTHANDLER_SYM LEFT_PAR_SYM QUALIFIER EVAL_CLR_TYPE DBLCOLON_SYM STD_ID RGHT_PAR_SYM
ASG_INC_DEC ::= INC_SYM
::= DEC_SYM
LVAL_FLD ::= FIELD
LVAL_START ::= LEFT_BRKT_SYM
LVAL_LIST ::= LVAL_START LVALUES RGHT_BRKT_SYM
LVALUE ::= FIELD
LVALUES ::= LVALUE
::= LVALUES NEXTLVAL LVALUE
NEXTLVAL ::= LIST_SEP_SYM
IF_EXPR ::= COND_TRUE IF_EXPR
::= BOOL_EXPR
COND_TRUE ::= COND_TEST IF_EXPR COLON_SYM
COND_TEST ::= BOOL_EXPR QUEST_SYM
BOOL_EXPR ::= BOOL_EXPR LOGOP EXPR
::= EXPR
LOGOP ::= AND_SYM
::= OR_SYM
EXPR ::= SMPL_EXPR RELOP SMPL_EXPR
::= SMPL_EXPR AS_SYM STD_ID
::= SMPL_EXPR IS_SYM STD_ID
::= SMPL_EXPR AS_SYM EVAL_CLR_TYPE
::= SMPL_EXPR IS_SYM EVAL_CLR_TYPE
::= SMPL_EXPR
RELOP ::= LT_SYM
::= LE_SYM
::= EQ_SYM
::= NE_SYM
::= GT_SYM
::= GE_SYM
::= LIKE_SYM
SMPL_EXPR ::= SMPL_EXPR ADDOP TERM
::= TERM
ADDOP ::= PLUS_SYM
::= MINUS_SYM
::= PHYSOR_SYM
TERM ::= TERM MULOP CMPL_FACT
::= CMPL_FACT
MULOP ::= MULT_SYM
::= DIV_SYM
::= MOD_SYM
::= INTDIV_SYM
::= SHIFTL_SYM
::= SHIFTR_SYM
::= PHYSAND_SYM
::= PHYSXOR_SYM
CMPL_FACT ::= NOT_SYM SGND_FACT
::= SGND_FACT
SGND_FACT ::= SIGNOP FACTOR
::= FACTOR
SIGNOP ::= UMINUS_SYM
::= PHYSNOT_SYM
FACTOR ::= LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
::= CONSTANT
::= FIELD
::= DIRSEARCH
::= FUNCTION
::= INTRINSICS
::= EVAL
::= CONLITTERAL
::= NEW_CLR_ARRAY
NEW_CLR_ARRAY ::= NEW_SYM EVAL_CLR_TYPE NEW_CLR_ARRAY_PART LEFT_PAR_SYM RGHT_PAR_SYM
NEW_CLR_ARRAY_PART ::= CLR_SIZED_ARRAY CLR_NOSIZED_ARRAY_SPEC
CLR_SIZED_ARRAY ::= LEFT_BRKT_SYM CLR_SMPL_EXPR_COMMA_LIST RGHT_BRKT_SYM
CLR_SMPL_EXPR_COMMA_LIST ::= SMPL_EXPR
::= CLR_SMPL_EXPR_COMMA_LIST LIST_SEP_SYM SMPL_EXPR
CLR_NOSIZED_ARRAY_SPEC ::= CLR_NOSIZED_ARRAY_LIST
::=
CLR_NOSIZED_ARRAY_LIST ::= CLR_NOSIZED_ARRAY
::= CLR_NOSIZED_ARRAY_LIST CLR_NOSIZED_ARRAY
CLR_NOSIZED_ARRAY ::= LEFT_BRKT_SYM CLR_EMPTY_COMMA_LIST RGHT_BRKT_SYM
CLR_EMPTY_COMMA_LIST ::= CLR_EMPTY_RECT_COMMA_LIST
::=
CLR_EMPTY_RECT_COMMA_LIST ::= LIST_SEP_SYM
::= CLR_EMPTY_RECT_COMMA_LIST LIST_SEP_SYM
CONLITTERAL ::= LEFT_BRKT_SYM IF_EXPR EXPR_LIST RGHT_BRKT_SYM
CONSTANT ::= INT_SYM
::= DBL_SYM
::= STR_SYM
::= DATE_SYM
::= DATETIME_SYM
::= STD_ID DBLCOLON_SYM STD_ID
::= TRUE_SYM
::= FALSE_SYM
::= NULL_SYM
::= INT64_SYM
::= QUALIFIER EVAL_CLR_TYPE DBLCOLON_SYM STD_ID
::= QUALIFIER STD_ID DBLCOLON_SYM STD_ID
DIRSEARCH ::= DIRS_HEADER PERIOD_SYM STD_ID ARR_IDX
::= DIRS_HEADER PERIOD_SYM FLD_NUM ARR_IDX
DIRS_HEADER ::= LEFT_PAR_SYM SET_DIRS FIND_JOIN RGHT_PAR_SYM
SET_DIRS ::=
FIELD ::= QUALIFIER STD_ID ARR_IDX
::= QUALIFIER FLD_NUM ARR_IDX
::= STD_ID ARR_IDX
QUALIFIER ::= EVAL PERIOD_SYM
::= STD_ID PERIOD_SYM
FLD_NUM ::= LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
ARR_IDX ::= LEFT_BRKT_SYM SMPL_EXPR RGHT_BRKT_SYM
::=
EXPR_LIST ::= EXPR_LIST2
::=
EXPR_LIST2 ::= LIST_SEP_SYM IF_EXPR
::= EXPR_LIST2 LIST_SEP_SYM IF_EXPR
FUNCTION ::= FUNC_ID LEFT_PAR_SYM EVAL_FUNCTION_NAME PAR_LIST RGHT_PAR_SYM
EVAL_FUNCTION_NAME ::=
EVAL_NAME ::= EVAL_ID LEFT_PAR_SYM
::= STD_ID LEFT_PAR_SYM
::= STD_ID DBLCOLON_SYM STD_ID LEFT_PAR_SYM
::= SUPER_SYM LEFT_PAR_SYM
::= NEW_SYM STD_ID LEFT_PAR_SYM
::= NEW_SYM EVAL_CLR_TYPE LEFT_PAR_SYM
::= QUALIFIER EVAL_CLR_TYPE DBLCOLON_SYM STD_ID LEFT_PAR_SYM
::= QUALIFIER STD_ID LEFT_PAR_SYM
::= QUALIFIER STD_ID DBLCOLON_SYM STD_ID LEFT_PAR_SYM
EVAL_CLR_TYPE ::= NAMESPACE STD_ID
::= NAMESPACE EVAL_CLR_TYPE
NAMESPACE ::= STD_ID PERIOD_SYM
EVAL ::= EVAL_NAME PAR_LIST RGHT_PAR_SYM
PAR_LIST ::= PRM_LIST
::=
PRM_LIST ::= PAR_ELEM
::= PRM_LIST LIST_SEP_SYM PAR_ELEM
PAR_ELEM ::= IF_EXPR
::= BYREF_SYM FIELD
INTRINSICS ::= INTRI_ID LEFT_PAR_SYM IARGS RGHT_PAR_SYM
IARGS ::= STD_ID
::= STR_SYM
::= STD_ID LIST_SEP_SYM STD_ID
::=
STMTLIST ::= STATEMENTS
::=
STATEMENTS ::= STATEMENT
::= STATEMENTS STATEMENT
STATEMENT ::= COMPOUND_STMT
::= WHILE_STMT
::= FOR_STMT
::= DO_STMT
::= SEARCH_STMT
::= FIND_STMT
::= PRINT_STMT
::= WINDOW_STMT
::= IF_STMT
::= SWITCH_STMT
::= EXPR_STMT
::= PAUSE_STMT
::= BP_CLAUSE
::= BREAK_STMT
::= CONTINUE_STMT
::= RETURN_CLAUSE
::= MOVE_REC_STMT
::= THROW_STMT
::= TRY_STMT
::= RETRY_STMT
::= TTS_STMT
::= FLUSH_STMT
::= TBLLOCK_STMT
::= CHANGE_STMT
::= UPDATE_STMT
::= INSERT_STMT
::= UNCHECKED_STMT
COMPOUND_STMT ::= LEFTBR_SYM STMTLIST RIGHTBR_SYM
THROW_STMT ::= THROW_SYM IF_EXPR SEMICOLON_SYM
TRY_STMT ::= TRY_BLOCK CATCH_LIST
TRY_BLOCK ::= TRY_START STATEMENT
TRY_START ::= TRY_SYM
CATCH_LIST ::= CATCH_STMT
::= CATCH_LIST CATCH_STMT
CATCH_STMT ::= CATCH_EXPR PRE_CATCH STATEMENT POST_CATCH
CATCH_EXPR ::= CATCH_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
::= CATCH_SYM LEFT_PAR_SYM IF_EXPR LIST_SEP_SYM TABLEINSTANCE RGHT_PAR_SYM
::= CATCH_SYM
PRE_CATCH ::=
POST_CATCH ::=
TABLEINSTANCE ::= INSTANCENAME
INSTANCENAME ::= QUALIFIER STD_ID ARR_IDX
::= STD_ID ARR_IDX
RETRY_STMT ::= RETRY_SYM SEMICOLON_SYM
WHILE_STMT ::= WHILE_TEST STATEMENT
WHILE_TEST ::= WHILE LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
WHILE ::= WHILE_SYM
DO_STMT ::= DO_BODY DO_TEST SEMICOLON_SYM
DO_BODY ::= DO_HEADER STATEMENT
DO_HEADER ::= DO_SYM
DO_TEST ::= WHILE_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
FOR_STMT ::= FOR_HEADER STATEMENT
FOR_HEADER ::= FOR_TEST SEMICOLON_SYM FOR_ASG RGHT_PAR_SYM
FOR_TEST ::= FOR_INIT SEMICOLON_SYM IF_EXPR
FOR_INIT ::= FOR_SYM LEFT_PAR_SYM FOR_ASG
FOR_ASG ::= LVAL_FLD ASSIGN IF_EXPR
::= LVAL_FLD ASG_INC_DEC
::= ASG_INC_DEC LVAL_FLD
JOIN_LIST ::= JOIN_SPECS
::=
JOIN_SPECS ::= JOIN_SPEC
::= JOIN_SPECS JOIN_SPEC
JOIN_SPEC ::= JOIN_ORDER WHERE IF_EXPR
::= JOIN_ORDER
JOIN_ORDER ::= JOIN_USING
::= JOIN_USING ORDER_GROUP
JOIN_USING ::= JOIN_CLAUSE USING_INDEX STD_ID
::= JOIN_CLAUSE USING_INDEX HINT_SYM STD_ID
::= JOIN_CLAUSE
JOIN_CLAUSE ::= OUTER JOIN_SYM SELECTOPT TABLE
OUTER ::= OUTER_SYM
::= EXISTS_SYM
::= NOTEXISTS_SYM
::=
SEARCH_STMT ::= SEARCH_JOIN STATEMENT
SEARCH_JOIN ::= SEARCH_WHERE JOIN_LIST
SEARCH_WHERE ::= SEARCH_ORDER WHERE IF_EXPR
::= SEARCH_ORDER
WHERE ::= WHERE_SYM
SUM_ELEM ::= SUM_FUNC LEFT_PAR_SYM STD_ID RGHT_PAR_SYM
SUM_FUNC ::= SUM_SYM
::= AVG_SYM
::= CNT_SYM
::= MINOF_SYM
::= MAXOF_SYM
SEARCH_ORDER ::= SEARCH_USING
::= SEARCH_USING ORDER_GROUP
ORDER_GROUP ::= ORDERBY_CLAUSE OPT_GROUPBY
::= GROUPBY_CLAUSE OPT_ORDERBY
OPT_GROUPBY ::= GROUPBY_CLAUSE
::=
OPT_ORDERBY ::= ORDERBY_CLAUSE
::=
ORDERBY_CLAUSE ::= ORDER_SYM OPT_BY ORDER_ELEM
::= ORDERBY_CLAUSE LIST_SEP_SYM ORDER_ELEM
GROUPBY_CLAUSE ::= GROUP_SYM OPT_BY ORDER_ELEM
::= GROUPBY_CLAUSE LIST_SEP_SYM ORDER_ELEM
ORDER_ELEM ::= STD_ID INDEX DIRECTION
::= ORDER_QUALIFIER STD_ID INDEX DIRECTION
ORDER_QUALIFIER ::= STD_ID PERIOD_SYM
INDEX ::= LEFT_BRKT_SYM INT_SYM RGHT_BRKT_SYM
::=
DIRECTION ::= ASCEND_SYM
::= DESCEND_SYM
::=
OPT_BY ::= BY_SYM
::=
SEARCH_USING ::= SEARCH_CLAUSE USING_INDEX STD_ID
::= SEARCH_CLAUSE USING_INDEX HINT_SYM STD_ID
::= SEARCH_CLAUSE
USING_INDEX ::= INDEX_SYM
SEARCH_CLAUSE ::= WHILE_SYM SELECT_SYM SELECTOPT CROSSCOMPANY_CLAUSE VALIDTIMESTATE_CLAUSE TABLE
CROSSCOMPANY_CLAUSE ::= CROSSCOMPANY_SYM
::= CROSSCOMPANY_SYM COLON_SYM STD_ID
::=
VALIDTIMESTATE_CLAUSE ::= VALIDTIMESTATE_SYM LEFT_PAR_SYM STD_ID LIST_SEP_SYM STD_ID RGHT_PAR_SYM
::= VALIDTIMESTATE_SYM LEFT_PAR_SYM STD_ID RGHT_PAR_SYM
::=
SELECTOPT ::=
::= SELECTOPT REVERSE_SYM
::= SELECTOPT FIRSTFAST_SYM
::= SELECTOPT FIRSTONLY_SYM
::= SELECTOPT FIRSTONLY_SYM1
::= SELECTOPT FIRSTONLY_SYM10
::= SELECTOPT FIRSTONLY_SYM100
::= SELECTOPT FIRSTONLY_SYM1000
::= SELECTOPT FORUPDATE_SYM
::= SELECTOPT NOFETCH_SYM
::= SELECTOPT FORCE_SELECT_ORDER_SYM
::= SELECTOPT FORCE_NESTED_LOOP_SYM
::= SELECTOPT FORCE_LITERALS_SYM
::= SELECTOPT FORCE_PLACEHOLDERS_SYM
::= SELECTOPT REPEATABLEREAD_SYM
::= SELECTOPT OPTIMISTICLOCK_SYM
::= SELECTOPT PESSIMISTICLOCK_SYM
::= SELECTOPT GENERATEONLY_SYM
FIND_STMT ::= FIND_JOIN SEMICOLON_SYM
FIND_JOIN ::= FIND_WHERE JOIN_LIST
FIND_WHERE ::= FIND_ORDER WHERE IF_EXPR
::= FIND_ORDER
FIND_ORDER ::= FIND_USING
::= FIND_USING ORDER_GROUP
FIND_USING ::= FIND_TABLE USING_INDEX STD_ID
::= FIND_TABLE USING_INDEX HINT_SYM STD_ID
::= FIND_TABLE
FIND_TABLE ::= SELECT_SYM SELECTOPT CROSSCOMPANY_CLAUSE VALIDTIMESTATE_CLAUSE TABLE
::= DELETE_SYM SELECTOPT CROSSCOMPANY_CLAUSE VALIDTIMESTATE_CLAUSE TABLE
TABLE ::= FLD_LIST OPT_FROM
FLD_LIST ::= MULT_SYM
::= FIELD_LIST
FIELD_LIST ::= FIELD_SPEC
::= FIELD_LIST LIST_SEP_SYM FIELD_SPEC
FIELD_SPEC ::= STD_ID INDEX
::= SUM_ELEM
OPT_FROM ::= FROM_SYM STD_ID
::=
SETFIELDSMODE ::=
UPDATE_STMT ::= UPDATETABLE SET_SYM SETFIELDSMODE FIELDASSIGNMENTS OPT_WHERE JOIN_LIST SEMICOLON_SYM
UPDATETABLE ::= UPDATE_SYM SELECTOPT CROSSCOMPANY_CLAUSE STD_ID
OPT_WHERE ::= WHERE IF_EXPR
::=
FIELDASSIGNMENTS ::= FIELDASSIGNMENTS LIST_SEP_SYM FIELDASSIGNMENT
::= FIELDASSIGNMENT
FIELDASSIGNMENT ::= STD_ID INDEX ASG_SYM IF_EXPR
INSERT_PART ::= INSERT_SYM CROSSCOMPANY_CLAUSE INSERT_NAME LEFT_PAR_SYM INSERTFIELDLIST RGHT_PAR_SYM
INSERT_NAME ::= STD_ID
INSERT_STMT ::= INSERT_PART FIND_JOIN SEMICOLON_SYM
INSERTFIELDLIST ::= INSERTFIELD
::= INSERTFIELDLIST LIST_SEP_SYM INSERTFIELD
INSERTFIELD ::= STD_ID INDEX
PRINT_STMT ::= PRINT_CLAUSE AT_CLAUSE SEMICOLON_SYM
PRINT_CLAUSE ::= PRINT IF_EXPR EXPR_LIST
PRINT ::= PRINT_SYM
AT_CLAUSE ::= AT_SYM IF_EXPR LIST_SEP_SYM IF_EXPR
::=
WINDOW_STMT ::= WINDOW_SYM IF_EXPR LIST_SEP_SYM IF_EXPR AT_CLAUSE SEMICOLON_SYM
IF_STMT ::= ELSE_STMT
::= IF_CONDS
IF_CONDS ::= IF_COND STATEMENT
IF_COND ::= IF_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
ELSE_STMT ::= ELSE STATEMENT
ELSE ::= IF_CONDS ELSE_SYM
SWITCH_STMT ::= CASE_LIST RIGHTBR_SYM
CASE_LIST ::= SWITCH_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM LEFTBR_SYM
::= CASE_TESTS STMTLIST
CASE_TESTS ::= CASE_HEADER COLON_SYM
::= CASE_LIST DEFAULT_SYM COLON_SYM
CASE_HEADER ::= CASE IF_EXPR
::= CASEALT IF_EXPR
CASE ::= CASE_LIST CASE_SYM
CASEALT ::= CASE_HEADER LIST_SEP_SYM
EXPR_STMT ::= ASG_STMT SEMICOLON_SYM
::= FUNCTION SEMICOLON_SYM
::= INTRINSICS SEMICOLON_SYM
::= EVAL SEMICOLON_SYM
PAUSE_STMT ::= PAUSE_SYM SEMICOLON_SYM
BP_CLAUSE ::= BP_SYM SEMICOLON_SYM
BREAK_STMT ::= BREAK_SYM SEMICOLON_SYM
CONTINUE_STMT ::= CONTINUE_SYM SEMICOLON_SYM
RETURN_CLAUSE ::= RETURN_SYM SEMICOLON_SYM
::= RETURN_SYM IF_EXPR SEMICOLON_SYM
TTS_STMT ::= TTSABORT_SYM SEMICOLON_SYM
::= TTSBEGIN_SYM SEMICOLON_SYM
::= TTSEND_SYM SEMICOLON_SYM
FLUSH_STMT ::= FLUSH ID_LIST SEMICOLON_SYM
FLUSH ::= FLUSH_SYM
TBLLOCK_STMT ::= TABLELOCK ID_LIST SEMICOLON_SYM
TABLELOCK ::= TABLELOCK_SYM
ID_LIST ::= STD_ID
::= ID_LIST LIST_SEP_SYM STD_ID
MOVE_REC_STMT ::= NEXT_SYM TABLE SEMICOLON_SYM
CHANGE_STMT ::= CHANGE_HEADER STATEMENT
CHANGE_HEADER ::= CHANGE LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM
CHANGE ::= CHANGECOMP_SYM
::= CHANGESITE_SYM
UNCHECKED_STMT ::= UNCHECKED_HEADER STATEMENT
UNCHECKED_HEADER ::= UNCHECKED_SYM LEFT_PAR_SYM IF_EXPR RGHT_PAR_SYM