plug-in dax_request

Le dax_request plug-in exécute une requête DAX (Data Analysis Expressions) sur un modèle sémantique Power BI et retourne les résultats sous forme de table. Traitez la table retournée avec des opérateurs KQL (Kusto Query Language) standard. Appelez le plug-in avec l’opérateur evaluate.

Le plug-in utilise l’API Exécuter des requêtes DAX Power BI, qui retourne des résultats au format Apache Arrow. Le plug-in conserve les types de colonnes pris en charge lorsqu’il convertit la réponse en table KQL.

Prerequisites

• Le modèle sémantique doit se trouver dans un espace de travail affecté à une capacité Fabric ou Power BI Premium.
• L’API REST d’exécution de jeu de données,autoriser les points de terminaison XMLA et analyser dans Excel avec les paramètres de locataire des modèles sémantiques locaux doit être activé.
• Vous devez disposer d’autorisations de génération et de lecture sur le modèle sémantique.
• La stratégie de légende de cluster doit autoriser dax les légendes à .api.powerbi.com Pour modifier cette stratégie, vous avez besoin AllDatabasesAdmin ou Ops autorisations.

Syntaxe

evaluate dax_request ( ConnectionString,DaxQuery) [:OutputSchema]

En savoir plus sur les conventions de syntaxe dans les conventions de syntaxe pour la documentation de référence.

Parameters

Chaîne de connexion

Le chaîne de connexion se compose de l’URL du modèle sémantique et de la ;Impersonate directive d’authentification. Utilisez l'un des éléments suivants :

• Modèle sémantique dans un espace de travail : https://api.powerbi.com/v1.0/myorg/groups/WorkspaceId/datasets/SemanticModelId;Impersonate

• Modèle sémantique dans mon espace de travail : https://api.powerbi.com/v1.0/myorg/datasets/SemanticModelId;Impersonate

Le segment de myorg chemin est littéral. *WorkspaceId* et *SemanticModelId* doit être des identificateurs globaux uniques (GUID). N’incluez pas de chaîne de requête, de fragment ou de chemin de fin après SemanticModelId.

Authentification et autorisation

Le plug-in utilise Microsoft Entra l’authentification au nom de l’utilisateur. Le moteur obtient un jeton pour l’utilisateur demandeur et envoie la requête DAX dans le contexte de sécurité de cet utilisateur. L’utilisateur doit disposer d’autorisations de génération et de lecture sur le modèle sémantique. Toute sécurité au niveau des lignes ou sécurité au niveau de l’objet configurée pour l’utilisateur s’applique à la requête.

Utilisez ;Impersonate comme directive d’authentification. L’identité managée, le principal de service et l’authentification par clé d’application ne sont pas pris en charge.

Configurer et définir la stratégie de légende

Le plug-in effectue un appel externe à Power BI. Étant donné que la stratégie de légende par défaut bloque dax les légendes, un administrateur de cluster doit autoriser explicitement le point de terminaison Power BI.

La commande suivante fusionne une règle restrictive dax dans la stratégie de légende de cluster existante :

.alter-merge cluster policy callout @'[{
  "CalloutType": "dax",
  "CalloutUriRegex": "api\\.powerbi\\.com.*",
  "CanCall": true
}]'

Vérifiez la stratégie :

.show cluster policy callout

Returns

Le plug-in retourne le résultat de la requête DAX sous la forme d’une table KQL. Il conserve les types de données Flèche pris en charge. Par exemple, Flèche int64, double, utf8et date-time valeurs mappent à Kusto long, stringreal, et datetime, respectivement.

Power BI retourne des noms de colonnes entre crochets, tels que [Category]. Dans KQL, référencez ces noms avec la ['...'] syntaxe, par ['[Category]']exemple .

Examples

Retourner toutes les lignes d’une table

L’exemple suivant interroge la Sales table. Le résultat retourné est soumis à la limite de ligne par défaut de l’API.

evaluate dax_request(
  'https://api.powerbi.com/v1.0/myorg/groups/<workspace-id>/datasets/<semantic-model-id>;Impersonate',
  'EVALUATE Sales')

Traiter les résultats DAX avec Kusto

L’exemple suivant sélectionne deux colonnes dans DAX, récapitule le résultat en KQL et filtre par catégorie :

evaluate dax_request(
  'https://api.powerbi.com/v1.0/myorg/groups/<workspace-id>/datasets/<semantic-model-id>;Impersonate',
  'EVALUATE SELECTCOLUMNS(Sales, "Category", Sales[Category], "Amount", Sales[Amount])')
| summarize TotalAmount = sum(['[Amount]']) by ['[Category]']
| where ['[Category]'] == 'Electronics'

Spécifier un schéma de sortie

L’exemple suivant déclare le schéma de sortie attendu afin que Kusto puisse déterminer le schéma sans contacter Power BI pendant l’analyse des requêtes. Le schéma déclaré doit correspondre au schéma de résultat en direct.

evaluate dax_request(
  'https://api.powerbi.com/v1.0/myorg/groups/<workspace-id>/datasets/<semantic-model-id>;Impersonate',
  'EVALUATE ROW("cnt", COUNTROWS(Sales), "sumAmt", SUM(Sales[Amount]))')
  : (['[cnt]']:long, ['[sumAmt]']:real)

Troubleshooting