Événement Report.Page (Access)

L'événement Page survient après que Microsoft Access a mis en forme une page d'un état en vue de son impression, mais avant que la page ne soit imprimée. Utilisez cet événement pour dessiner une bordure autour de la page ou ajouter d’autres éléments graphiques à la page.

Syntaxe

expression. Page d’annonce

expression Variable qui représente un objet Rapport .

Valeur renvoyée

Aucune

Remarques

Pour exécuter une macro ou une procédure événementielle lorsque cet événement se produit, définissez la propriété OnPage sur le nom de la macro ou sur [Procédure événementielle].

Cet événement se produit après tous les événements de mise en forme du rapport et après tous les événements d’impression de la page, mais avant l’impression de la page.

Vous utilisez normalement les méthodes Ligne, Cercle ou PSet dans la procédure d’événement de page pour créer les graphiques souhaités pour la page.

L’événement NoData se produit avant le premier événement Page du rapport.

Exemple

L'exemple suivant montre comment tracer un rectangle autour de la page d'un état à l'aide de la méthode Line. Les propriétés ScaleWidth et ScaleHeight par défaut renvoient la largeur et la hauteur intérieures de l'état.

Private Sub Report_Page() 
    Me.Line(0, 0)-(Me.ScaleWidth, Me.ScaleHeight), , B 
End Sub

L’exemple suivant montre comment utiliser l’événement Page pour ajouter un filigrane à un rapport avant de l’imprimer.

Private Sub Report_Page()
    Dim strWatermarkText As String
    Dim sizeHor As Single
    Dim sizeVer As Single

#If RUN_PAGE_EVENT = True Then
    With Me
        '// Print page border
        Me.Line (0, 0)-(.ScaleWidth - 1, .ScaleHeight - 1), vbBlack, B
    
        '// Print watermark
        strWatermarkText = "Confidential"
        
        .ScaleMode = 3
        .FontName = "Segoe UI"
        .FontSize = 48
        .ForeColor = RGB(255, 0, 0)

        '// Calculate text metrics
        sizeHor = .TextWidth(strWatermarkText)
        sizeVer = .TextHeight(strWatermarkText)
        
        '// Set the print location
        .CurrentX = (.ScaleWidth / 2) - (sizeHor / 2)
        .CurrentY = (.ScaleHeight / 2) - (sizeVer / 2)
    
        '// Print the watermark
        .Print strWatermarkText
    End With
#End If

End Sub

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.