objet ConnectorFormat (Excel)

Contient des propriétés et des méthodes qui s’appliquent aux connecteurs.

Remarques

Un connecteur est une ligne reliant deux autres formes à des points nommés points de connexion. Si vous réorganisez des formes connectées, la géométrie du connecteur sera automatiquement ajustée de telle sorte que les formes demeurent connectées.

Généralement, les points d'attache sont numérotés conformément aux règles présentées dans le tableau suivant.

Type de forme Type de numérotation des points d'attache
Formes automatiques, objets WordArt, images et objets OLE Les points d'attache sont numérotés à partir du haut et en tournant dans le sens des aiguilles d'une montre.
Formes libres Les points d'attache sont les sommets de la forme libre et portent les mêmes numéros que ces sommets.

Utilisez la propriété ConnectorFormat de l’objet Shape pour renvoyer un objet ConnectorFormat . Utilisez les méthodes BeginConnect et EndConnect pour attacher les extrémités du connecteur à d’autres formes dans le document. Utilisez la méthode RerouteConnections de l’objet Shape pour trouver automatiquement le chemin le plus court entre deux formes reliées par le connecteur. Utiliser le connecteur propriété pour voir si une forme est un connecteur.

Remarque

Vous attribuez une taille et une position lorsque vous ajoutez un lien à la collection Formes , mais la taille et la position sont automatiquement ajustées lorsque vous attachez le début et la fin du lien à d’autres formes de la collection. Par conséquent, si vous avez l’intention d’attacher un lien à d’autres formes, la taille et la position initiales que vous spécifiez n’ont pas d’importance.

De même, vous définissez les sites de connexion sur une forme et attache le connecteur lorsque vous l'attachez, mais à l'aide de la méthode RerouteConnections après l'attache du connecteur peut modifier les sites de connexion que le connecteur s'attache, de rendre votre premier choix de sites de connexion sans effet.

Exemple

Pour déterminer quel nombre correspond à quel site de connexion sur une forme complexe, vous pouvez expérimenter la forme pendant que l’enregistreur de macros est allumé, puis examiner le code enregistré ; Vous pouvez également créer une forme, la sélectionner, puis exécuter l’exemple suivant. Ce code numérote chaque site de connexion et y attache un connecteur.

Set mainshape = ActiveWindow.Selection.ShapeRange(1) 
With mainshape 
 bx = .Left + .Width + 50 
 by = .Top + .Height + 50 
End With 
With ActiveSheet 
 For j = 1 To mainshape.ConnectionSiteCount 
 With .Shapes.AddConnector(msoConnectorStraight, _ 
 bx, by, bx + 50, by + 50) 
 .ConnectorFormat.EndConnect mainshape, j 
 .ConnectorFormat.Type = msoConnectorElbow 
 .Line.ForeColor.RGB = RGB(255, 0, 0) 
 l = .Left 
 t = .Top 
 End With 
 With .Shapes.AddTextbox(msoTextOrientationHorizontal, _ 
 l, t, 36, 14) 
 .Fill.Visible = False 
 .Line.Visible = False 
 .TextFrame.Characters.Text = j 
 End With 
 Next j 
End With

L'exemple suivant montre comment ajouter deux rectangles à myDocument et les connecter à l'aide d'un connecteur en arc.

Set myDocument = Worksheets(1) 
Set s = myDocument.Shapes 
Set firstRect = s.AddShape(msoShapeRectangle, 100, 50, 200, 100) 
Set secondRect = s.AddShape(msoShapeRectangle, 300, 300, 200, 100) 
Set c = s.AddConnector(msoConnectorCurve, 0, 0, 0, 0) 
With c.ConnectorFormat 
 .BeginConnect ConnectedShape:=firstRect, ConnectionSite:=1 
 .EndConnect ConnectedShape:=secondRect, ConnectionSite:=1 
 c.RerouteConnections 
End With

Méthodes

Propriétés

Voir aussi

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.

  • Last updated on