Remarque
L’accès à cette page nécessite une autorisation. Vous pouvez essayer de vous connecter ou de modifier des répertoires.
L’accès à cette page nécessite une autorisation. Vous pouvez essayer de modifier des répertoires.
Renvoie un objet Range qui représente une cellule ou une plage de cellules.
Syntaxe
expression. Plage (cell1, cell2)
expression Variable qui représente un objet Feuille de calcul.
Paramètres
| Nom | Requis/Facultatif | Type de données | Description |
|---|---|---|---|
| Cell1 | Obligatoire | Variant | Chaîne qui est une référence de plage lorsqu’un argument est utilisé. Soit une chaîne qui est une référence de plage, soit un objet Range lorsque deux arguments sont utilisés. |
| Cell2 | Facultatif | Variant | Soit une chaîne qui est une référence de plage, soit un objet Range. La cellule 2 définit une autre extrémité de la plage renvoyée par la propriété. |
Remarques
Cell1 et Cell2 peuvent être des références de type A1 dans la langue de la macro. Les références de plage peuvent inclure l’opérateur de plage (un signe deux-points), un opérateur d’intersection (un espace) ou un opérateur d’union (une virgule). Ils peuvent également inclure des signes dollar, qui sont ignorés. Un nom défini localement peut être une référence de plage. Si vous utilisez un nom, celui-ci est supposé être dans le langage de la macro.
Cell1 et Cell2 peuvent être des objets Range qui contiennent une seule cellule, colonne, ligne ou toute autre plage de cellules.
Souvent, Cell1 et Cell2 sont des cellules uniques situées dans les coins supérieur gauche et inférieur droit de la plage renvoyée.
Lorsqu’elle est utilisée sans qualificateur d’objet, cette propriété est un raccourci pour ActiveSheet.Range (elle retourne une plage de la feuille active ; si la feuille active n’est pas une feuille de calcul, la propriété échoue).
Appliquée à un objet Range, la propriété est relative à l'objet Range. Par exemple, si la sélection est la cellule C3, Selection.Range("B1") renvoie la cellule D3 car elle est relative à l’objet Range renvoyé par la propriété Selection . En revanche, le code ActiveSheet.Range("B1") renvoie toujours la cellule B1.
Exemples
Cet exemple définit la valeur de la cellule A1 de Sheet1 sur 3,14159.
Worksheets("Sheet1").Range("A1").Value = 3.14159
Cet exemple crée une formule dans la cellule A1 de Sheet1.
Worksheets("Sheet1").Range("A1").Formula = "=10*RAND()"
Cet exemple s’exécute en boucle sur les cellules A1 :D10 de la feuille 1 du classeur actif. Si la valeur d'une des cellules est inférieure à 0,001, le code remplace la valeur par 0 (zéro).
For Each c in Worksheets("Sheet1").Range("A1:D10")
If c.Value < .001 Then
c.Value = 0
End If
Next c
Cet exemple effectue une boucle sur la plage nommée TestRange et affiche le nombre de cellules vides dans la plage.
numBlanks = 0
For Each c In Range("TestRange")
If c.Value = "" Then
numBlanks = numBlanks + 1
End If
Next c
MsgBox "There are " & numBlanks & " empty cells in this range"
Cet exemple définit le style de police des cellules A1 :C5 de la feuille 1 du classeur actif en italique. L'exemple utilise la syntaxe 2 de la propriété Range.
With Worksheets("Sheet1")
.Range(.Cells(1, 1), .Cells(5, 3)).Font.Italic = True
End With
Cet exemple compare la propriété Worksheet.Range , la méthode Application.Union et la méthode Application.Intersect .
Range("A1:A10").Select 'Selects cells A1 to A10.
Range(Range("A1"), Range("A10")).Select 'Selects cells A1 to A10.
Range("A1, A10").Select 'Selects cells A1 and A10.
Union(Range("A1"), Range("A10")).Select 'Selects cells A1 and A10.
Range("A1:A5 A5:A10").Select 'Selects cell A5.
Intersect(Range("A1:A5"), Range("A5:A10")).Select 'Selects cell A5.
Assistance et commentaires
Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.