Méthode Views.Add (Outlook)

Crée un affichage dans la collection Views.

Syntaxe

expression. Ajouter (nom, ViewType, SaveOption)

expression Variable qui représente un objet Vues .

Paramètres

Nom Requis/Facultatif Type de données Description
Name Obligatoire String Nom du nouvel affichage.
ViewType Obligatoire OlViewType Type du nouvel affichage.
SaveOption Facultatif OlViewSaveOption L’option save qui spécifie les autorisations du nouvel affichage :
  • olViewSaveOptionAllFoldersOfTypeL'affichage est accessible à partir de tous les dossiers de ce type.
  • olViewSaveOptionThisFolderEveryOne L'affichage est accessible par tous les utilisateurs dans ce dossier uniquement.
  • olViewSaveOptionThisFolderOnlyMe L'affichage est accessible dans ce dossier uniquement par l'utilisateur.

Valeur renvoyée

Objet View qui représente la nouvelle vue.

Remarques

Si vous ajoutez une vue à une collection de vues d’un dossier qui n’est pas le dossier actuel, vous devez d’abord enregistrer une copie de l’objet de collection Vues , puis ajouter la vue à cet objet de collection, comme illustré dans l’exemple de code suivant. Il s’agit d’une solution de contournement pour un problème existant qui, sinon, entraînerait un appel à View.Apply pour l’échec de la vue ajoutée.

Sub CalendarView() 
 Dim calView As Outlook.View 
 Dim vws As Views 
 
 Set Application.ActiveExplorer.CurrentFolder = Application.Session.GetDefaultFolder(olFolderInbox) 
 ' Current folder is Inbox; add a View to the Calendar folder which is not the current folder 
 ' Keep a copy of the object for the Views collection for the Calendar 
 Set vws = Application.Session.GetDefaultFolder(olFolderCalendar).Views 
 ' Add the View to this Views collection object 
 Set calView = vws.Add("New Calendar", olCalendarView, olViewSaveOptionThisFolderEveryone) 
 calView.Save 
 ' This Apply call will be fine 
 calView.Apply 
End Sub

Exemple

L’exemple Visual Basic pour Applications (VBA) suivant crée une vue appelée Nouvelle table et la stocke dans une variable appelée objNewView.

Sub CreateView() 
 'Creates a new view 
 Dim objName As Outlook.NameSpace 
 Dim objViews As Outlook.Views 
 Dim objNewView As Outlook.View 
 
 Set objName = Application.GetNamespace("MAPI") 
 Set objViews = objName.GetDefaultFolder(olFolderInbox).Views 
 Set objNewView = objViews.Add(Name:="New Table", _ 
 ViewType:=olTableView, SaveOption:=olViewSaveOptionThisFolderEveryone) 
End Sub

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.

  • Last updated on