Propriété Shape.TextFrame2 (projet)

Obtient un objet TextFrame2 qui contient le texte d’un bloc de texte et les membres qui contrôlent l’alignement, l’ancrage et d’autres fonctionnalités du bloc de texte. TextFrame 2 en lecture seule.

Syntaxe

expression. Cadre de texte 2

expression Une variable qui représente uneForme d’objet.

Remarques

Un objet TextFrame2 contient de nombreuses propriétés identiques à celles d’un objet TextFrame, ainsi que des propriétés supplémentaires telles que AutoSize, ThreeD et WordArtformat.

Exemple

L’exemple suivant crée deux zones de texte et les ajoute à un objet ShapeRange , définit les deux blocs de texte de manière à ce qu’ils s’ajustent automatiquement au texte, définit la couleur de premier plan du texte de la première forme de zone de texte sur rouge, définit la couleur de premier plan de la plage de formes sur un brun jaunâtre, puis utilise la propriété TextEffect pour définir les propriétés de police sur les deux zones de texte de la plage de formes.

La propriété TextFrame2 pour les objets Shape individuels s’affiche en gras.

Sub FormatTextBox()
    Dim theReport As Report
    Dim textShape1 As shape
    Dim textShape2 As shape
    Dim reportName As String
    Dim sRange As ShapeRange
    
    reportName = "Textbox range report"
    
    Set theReport = ActiveProject.Reports.Add(reportName)
    Set textShape1 = theReport.Shapes.AddTextbox(msoTextOrientationHorizontal, 30, 50, 350, 80)
    textShape1.Name = "Text box 1"
    
    Set textShape2 = theReport.Shapes.AddTextbox(msoTextOrientationHorizontal, 30, 130, 350, 80)
    textShape2.Name = "Text box 2"
    
    Set sRange = theReport.Shapes.Range(Array("Text box 1", "Text box 2"))
        
    sRange.TextFrame2.AutoSize = msoAutoSizeShapeToFitText
        
    sRange(1).TextFrame2.TextRange.Text = "This is a test. It's only a test."
    sRange(2).TextFrame2.TextRange.Text = "This is text box 2."
    sRange(1).TextFrame2.TextRange.Characters.Font.Fill.ForeColor.RGB = &H2020CC
    sRange.Fill.ForeColor.RGB = &H88CCCC
        
    With sRange.TextEffect
        .FontName = "Courier New"
        .FontBold = True
        .FontItalic = True
        .FontSize = 28
    End With
    
    sRange(2).Select
End Sub

Valeur de la propriété

TEXTFRAME2

Voir aussi

Objet de formeTextFrame2

Assistance et commentaires

Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.