Avvio rapido: Creare un archivio di Configurazione app di Azure con Bicep

Questa guida introduttiva descrive come usare Bicep per:

  • Distribuire un archivio di Configurazione app di Azure.
  • Creare valori chiave in un archivio Configurazione app.
  • Leggere le coppie chiave-valore in un archivio di configurazione di app.

Bicep è un linguaggio specifico di dominio (DSL) che usa la sintassi dichiarativa per distribuire le risorse di Azure. Offre una sintassi concisa, una sicurezza dei tipi affidabile e supporto al riutilizzo del codice. Bicep offre la migliore esperienza di creazione per le soluzioni di infrastruttura come codice in Azure.

Prerequisiti

Se non si ha una sottoscrizione di Azure, creare un account gratuito prima di iniziare.

Autorizzazione

La gestione di una risorsa di configurazione app Azure con il file Bicep richiede un ruolo di Azure Resource Manager, ad esempio collaboratore o proprietario. L'accesso ai dati di Configurazione app di Azure (coppie chiave-valore, snapshot) richiede un ruolo di Azure Resource Manager e un ruolo del piano dati di Configurazione app di Azure aggiuntivo quando la modalità di autenticazione ARM dell'archivio di configurazione è impostata sulla modalità di autenticazione ARM pass-through.

Importante

Per configurare la modalità di autenticazione ARM è necessaria la versione 2023-08-01-preview o successiva dell'API del piano di controllo di App Configuration.

Esaminare il file Bicep

Il file Bicep usato in questo avvio rapido proviene dai modelli di avvio rapido di Azure.

Nota

I file Bicep usano lo stesso motore sottostante dei modelli arm. Tutti i suggerimenti, le note e le informazioni importanti contenuti nella guida introduttiva del modello ARM valgono anche qui. È consigliabile fare riferimento a queste informazioni quando si utilizzano i file Bicep.

@description('Specifies the name of the App Configuration store.')
param configStoreName string = 'appconfig${uniqueString(resourceGroup().id)}'

@description('Specifies the Azure location where the app configuration store should be created.')
param location string = resourceGroup().location

@description('Specifies the names of the key-value resources. The name is a combination of key and label with $ as delimiter. The label is optional.')
param keyValueNames array = [
  'myKey'
  'myKey$myLabel'
]

@description('Specifies the values of the key-value resources. It\'s optional')
param keyValueValues array = [
  'Key-value without label'
  'Key-value with label'
]

@description('Specifies the content type of the key-value resources. For feature flag, the value should be application/vnd.microsoft.appconfig.ff+json;charset=utf-8. For Key Value reference, the value should be application/vnd.microsoft.appconfig.keyvaultref+json;charset=utf-8. Otherwise, it\'s optional.')
param contentType string = 'the-content-type'

@description('Adds tags for the key-value resources. It\'s optional')
param tags object = {
  tag1: 'tag-value-1'
  tag2: 'tag-value-2'
}

resource configStore 'Microsoft.AppConfiguration/configurationStores@2024-05-01' = {
  name: configStoreName
  location: location
  sku: {
    name: 'standard'
  }
}

resource configStoreKeyValue 'Microsoft.AppConfiguration/configurationStores/keyValues@2024-05-01' = [for (item, i) in keyValueNames: {
  parent: configStore
  name: item
  properties: {
    value: keyValueValues[i]
    contentType: contentType
    tags: tags
  }
}]

output reference_key_value_value string = configStoreKeyValue[0].properties.value
output reference_key_value_object object = {
  name: configStoreKeyValue[1].name
  properties: configStoreKeyValue[1].properties
}

Nel file Bicep sono definite due risorse di Azure:

Con questo file Bicep viene creata una chiave con due valori diversi, uno dei quali ha un'etichetta univoca.

Distribuisci il file Bicep

  1. Salvare il file Bicep come main.bicep nel computer locale.

  2. Distribuisci il file Bicep usando l'interfaccia della riga di comando di Azure o Azure PowerShell.

    Negli esempi seguenti sostituire <ResourceGroupName> con un nome per il gruppo di risorse e <AppConfigurationStoreName> con un nome univoco per l'archivio di configurazione.

    az group create --name <ResourceGroupName> --location eastus
az deployment group create --resource-group <ResourceGroupName> --template-file main.bicep --parameters configStoreName=<AppConfigurationStoreName>

    Al termine della distribuzione, visualizzerai un messaggio che indica che la distribuzione è stata completata.

Esaminare le risorse distribuite

Usare l'interfaccia della riga di comando di Azure o Azure PowerShell per elencare le risorse distribuite nel gruppo di risorse.

az resource list --resource-group <ResourceGroupName>

È anche possibile usare il portale di Azure per elencare le risorse:

  1. Accedere al portale di Azure.
  2. Nella casella di ricerca immettere Configurazione app, quindi selezionare Configurazione app dall'elenco.
  3. Selezionare la risorsa di Configurazione app appena creata.
  4. In Operazioni selezionare Esplora configurazione.
  5. Verifica che esistano due coppie chiave-valore.

Pulire le risorse

Quando non è più necessario, usare l'interfaccia della riga di comando di Azure o Azure PowerShell per eliminare il gruppo di risorse e le relative risorse.

az group delete --name <ResourceGroupName>

È anche possibile usare il portale di Azure per eliminare il gruppo di risorse:

  1. Passa al gruppo di risorse.
  2. Selezionare Elimina gruppo di risorse.
  3. Verrà visualizzata una scheda. Immettere il nome del gruppo di risorse e selezionare Elimina.

Passaggi successivi

Per informazioni sull'aggiunta di un flag di funzionalità e di un riferimento a Key Vault a un archivio di App Configuration, consultare gli esempi di modelli ARM.

  • Last updated on