Control.Object プロパティ (Access)

コントロール内のリンクまたは埋め込み OLE オブジェクトと関連付けられている ActiveX オブジェクトへの参照を返すには、Visual Basic の Object プロパティを使用します。 この参照を使用すると、OLE オブジェクトのプロパティにアクセスしたり、メソッドを呼び出すことができます。 読み取り専用 オブジェクト 。

構文

式。オブジェクト

式コントロール オブジェクトを表す変数。

注釈

Object プロパティは、ActiveX オブジェクトへの参照を返します。 この ActiveX オブジェクトをオブジェクト変数に割り当てるには、 Set ステートメントを使用します。 返されるオブジェクト参照の種類は、その OLE オブジェクトを作成したアプリケーションに応じて異なります。

Access のフォームに OLE オブジェクトを埋め込む、またはリンクするときは、オブジェクトの種類とコンテナー コントロールの動作を確認するプロパティを設定できます。 ただし、オートメーションの実行中と同じように OLE オブジェクトのプロパティを直接設定、取得したり、メソッドを適用したりすることはできません。

Object プロパティは、リンクされた、または埋め込まれた OLE オブジェクトを表すオートメーション オブジェクトへの参照を返します。 この参照を使用すると、プロパティを設定または参照するかメソッドを適用して、OLE オブジェクトを変更できます。 たとえば、Microsoft Excel はオートメーションをサポートする COM コンポーネントです。 Excel ワークシートを Access フォームに埋め込んだ場合は、 Object プロパティを使って、そのワークシートに関連付けられている ワークシート オブジェクトへの参照を設定できます。 その後、その Worksheet オブジェクトのすべてのプロパティとメソッドを使用できるようになります。

ActiveX オブジェクトがサポートするプロパティとメソッドの詳細については、OLE オブジェクトの作成に使用されたアプリケーションのマニュアルを参照してください。

例

次の例では、OLE1 という名前のバインドされていないオブジェクト フレームの Object プロパティを使用しています。 顧客の名前と住所の情報は、名前と住所情報のプレースホルダーが付属し、レター本文に定型文が含まれるフォーム レターとして書式設定された埋め込まれた Microsoft Word ドキュメントに挿入されます。 この手順では、各レコードのプレースホルダー情報を置き換え、フォーム レターを印刷します。 印刷されたフォーム レターのコピーは保存されません。

Sub PrintFormLetter_Click() 
 Dim objWord As Object 
 Dim strCustomer As String, strAddress As String 
 Dim strCity As String, strRegion As String 
 
 ' Assign object property of control to variable. 
 Set objWord = Me!OLE1.Object.Application.Wordbasic 
 ' Assign customer address to variables. 
 strCustomer = Me!CompanyName 
 strAddress = Me!Address 
 strCity = Me!City & ", " 
 If Not IsNull(Me!Region) Then 
 strRegion = Me!Region 
 Else 
 strRegion = Me!Country 
 End If 
 ' Activate ActiveX control. 
 Me!OLE1.Action = acOLEActivate 
 With objWord 
 .StartOfDocument 
 ' Go to first placeholder. 
 .LineDown 2 
 ' Highlight placeholder text. 
 .EndOfLine 1 
 ' Insert customer name. 
 .Insert strCustomer 
 ' Go to next placeholder. 
 .LineDown 
 .StartOfLine 
 ' Highlight placeholder text. 
 .EndOfLine 1 
 ' Insert address. 
 .Insert strAddress 
 ' Go to last placeholder. 
 .LineDown 
 .StartOfLine 
 ' Highlight placeholder text. 
 .EndOfLine 1 
 ' Insert City and Region. 
 .Insert strCity & strRegion 
 .FilePrint 
 .FileClose 
 End With 
 Set objWord = Nothing 
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。

  • Last updated on