References.ItemAdded イベント (アクセス)

ItemAdded イベントは、Visual Basic で参照設定がプロジェクトに追加されると発生します。

構文

式。ItemAdded (リファレンス)

式References オブジェクトを表す変数。

パラメーター

注釈

ItemAdded イベントは References コレクションに適用されます。 他のほとんどのイベントのように、コントロール、フォーム、またはレポートに関連付けられることはありません。 したがって、 ItemAdded イベント プロシージャのプロシージャ定義を作成するには、特別な構文を使用する必要があります。

ItemAdded イベントは、イベント プロシージャが発生したときにのみ実行できます。マクロを実行できません。

このイベントは、コードで参照設定を追加したときにのみ発生します。 [参照設定] ダイアログ ボックスから参照を追加した場合、モジュール ウィンドウが作業中のウィンドウであるときに [ツール] メニューの [参照] を選択して参照が表示される場合は、発生しません。

例

次の例には、ItemAdded イベントおよび ItemRemoved イベントのイベント プロシージャが含まれています。 この例を試すには、まず [挿入] メニューの [クラス モジュール] を選択して、新しいクラス モジュールを作成します。 次のコードをクラス モジュールに貼り付けて、モジュールを RefEvents として保存します。

' Declare object variable to represent References collection. 
Public WithEvents evtReferences As References 
 
' When instance of class is created, initialize evtReferences 
' variable. 
Private Sub Class_Initialize() 
 Set evtReferences = Application.References 
End Sub 
 
' When instance is removed, set evtReferences to Nothing. 
Private Sub Class_Terminate() 
 Set evtReferences = Nothing 
End Sub 
 
' Display message when reference is added. 
Private Sub evtReferences_ItemAdded(ByVal Reference As _ 
 Access.Reference) 
 MsgBox "Reference to " & Reference.Name & " added." 
End Sub 
 
' Display message when reference is removed. 
Private Sub evtReferences_ItemRemoved(ByVal Reference As _ 
 Access.Reference) 
 MsgBox "Reference to " & Reference.Name & " removed." 
End Sub

次の Function プロシージャは、指定された参照を追加します。 参照が追加されると、RefEvents クラスで定義されている ItemAdded イベント プロシージャが実行されます。

' Create new instance of RefEvents class. 
Dim objRefEvents As New RefEvents 
 
' Pass file name and path of type library to this procedure. 
Function AddReference(strFileName As String) As Boolean 
 Dim ref As Reference 
 
 On Error GoTo Error_AddReference 
 ' Create new reference on References object variable. 
 Set ref = objRefEvents.evtReferences.AddFromFile(strFileName) 
 AddReference = True 
 
Exit_AddReference: 
 Exit Function 
 
Error_AddReference: 
 MsgBox Err & ": " & Err.Description 
 AddReference = False 
 Resume Exit_AddReference 
End Function

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。