Report.Circle メソッド (Access)

Circle メソッドは、印刷イベントが発生したときに Report オブジェクトに円、楕円、または円弧を描画します。

構文

式。円 (ステップ (x, y)、 半径、 色、 始点、 終点、 縦横比)

式: Report オブジェクトを表す変数。

パラメーター

名前 データ型 説明
手順 Keyword 円、楕円、または円弧の中心が、Object 引数の CurrentX プロパティおよび CurrentY プロパティの現在の設定によって指定される現在の座標に相対することを示します。
(x, y) 単精度浮動小数点型 円、楕円、または円弧の中心点の座標を示します。Object 引数で指定されている Report オブジェクトのスケール プロパティ (ScaleMode、ScaleLeft、ScaleTop、ScaleHeight、および ScaleWidth) によって、使用される測定単位が決まります。
半径 単精度浮動小数点型 円、楕円、または円弧の半径を示します。Object 引数で指定されている Report オブジェクトのスケール プロパティ (ScaleMode、ScaleLeft、ScaleTop、ScaleHeight、および ScaleWidth) によって、使用される測定単位が決まります。 既定では、距離は twips で計測されます。
Color Long 円のアウトラインの RGB (赤緑青) 色を示します。 この引数を省略すると、" ForeColor /前景色" プロパティの値が使われます。 また、色を指定する目的で、 RGB や QBColor 関数を使用できます。
Start 単精度浮動小数点型 部分的な円または楕円を描画する場合、 開始引 数は円弧の開始位置を (ラジアンで) 指定します。 開始引 数の既定値は 0 ラジアンです。 範囲は -2 パイ ラジアンから 2 パイ ラジアンです。
End 単精度浮動小数点型 部分的な円または楕円が描画されている場合、 End 引数は円弧の終了位置を (ラジアンで) 指定します。 End 引数の既定値は 2 π ラジアンです。 範囲は -2 パイ ラジアンから 2 パイ ラジアンです。
特徴 単精度浮動小数点型 円の縦横比を示します。 この場合は、任意の画面で完全な (楕円でない) 円が描画されます。

注釈

このメソッドは、レポート セクションのイベント プロパティ、またはレポートの OnPage イベント プロパティで指定されたイベント プロシージャまたはマクロでのみ使用します。

部分的な円または楕円を描画するときに、 Start 引数が負の場合、 Circle メソッドは Start 引数で指定された位置までの半径を描画し、角度を正の値として扱います。 End 引数が負の場合、Circle メソッドは End 引数で指定された位置に半径を描画し、角度を再度正として扱います。 The Circle method always draws in a counterclockwise (positive) direction.

円を塗りつぶすには、レポートの FillColor と FillStyle プロパティを設定します。 ただし、塗りつぶしができるのは閉じた図形だけです。 円、楕円、および扇形 (両端の半径が描画されている円弧) などが閉じた図形となります。

円グラフ スライスを描画するときに、右に水平な線分を形成するために角度 0 の半径を描画する必要がある場合は、 開始引 数に 0 ではなく非常に小さい負の値を指定します。 たとえば、 開始引 数に -.00000001 を指定します。

構文の途中の引数を省略することはできますが、その場合には次の引数の前にカンマを入れる必要があります。 末尾の引数を省略する場合は、最後に指定した引数の後にコンマを使用しないでください。

円、楕円、または円弧の描画に使用される線の幅は、 DrawWidth プロパティの設定によって異なります。 背景に円を描画する方法は、 DrawMode プロパティと DrawStyle プロパティの設定によって異なります。

Circle メソッドを適用すると、CurrentX プロパティと CurrentY プロパティは、x 引数と y 引数で指定された中心点に設定されます。

例

次の例では、Circle メソッドを使って円を描き、その中に扇形を作成して赤色を付けます。

To try this example in Microsoft Access, create a new report. Set the OnPrint property of the Detail section to [Event Procedure]. レポートのモジュールに次のコードを入力し、[印刷プレビュー] に切り替えます。

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    Const conPI = 3.14159265359 
    Dim sngHCtr As Single, sngVCtr As Single 
    Dim sngRadius As Single 
    Dim sngStart As Single, sngEnd As Single 
 
    sngHCtr = Me.ScaleWidth / 2     ' Horizontal center. 
    sngVCtr = Me.ScaleHeight / 2     ' Vertical center. 
    sngRadius = Me.ScaleHeight / 3     ' Circle radius. 
    ' Draw circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius 
    sngStart = -0.00000001             ' Start of pie slice. 
    sngEnd = -2 * conPI / 3             ' End of pie slice. 
    Me.FillColor = RGB(255,0,0)     ' Color pie slice red. 
    Me.FillStyle = 0                     ' Fill pie slice. 
    ' Draw pie slice within circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius, , sngStart, sngEnd 
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。

  • Last updated on