Worksheet.Range プロパティ (Excel)

セルまたはセルの範囲を表す Range オブジェクトを返します。

構文

式。範囲 (セル 1、 セル 2)

式Worksheet オブジェクトを表す変数。

パラメーター

注釈

Cell1 と Cell2 は、マクロの言語で A1 スタイルの参照にすることができます。 範囲参照には、範囲演算子 (コロン)、共通部分演算子 (スペース)、または和集合演算子 (コンマ) を含めることができます。 また、無視されるドル記号を含めることもできます。 ローカルで定義された名前は、範囲参照として使用できます。 名前を使用する場合、その名前はコード記述時の言語で表されたものと見なされます。

Cell1 と Cell2 には、1 つのセル、列、行、またはその他任意のセル範囲を含む Range オブジェクトを指定できます。

多くの場合、 Cell1 と Cell2 は、返される範囲の左上隅と右下隅にある 1 つのセルです。

オブジェクト修飾子を指定せずにこのプロパティを使用すると、ActiveSheet.Range のショートカットとなります。つまり、アクティブ シートから範囲を取得します。アクティブ シートがワークシートでない場合、このプロパティは失敗します。

Range オブジェクトに対して使用すると、このプロパティは Range オブジェクト基準にした相対的な範囲を返します。 たとえば、選択範囲がセル C3 の場合、Selection プロパティによって返される Range オブジェクトを基準にしているため、Selection.Range("B1") はセル D3 を返します。 一方、 ActiveSheet.Range("B1") というコードでは、常にセル B1 が取得されます。

例

次の使用例は、シート 1 のセル A1 の値を 3.14159 に設定します。

Worksheets("Sheet1").Range("A1").Value = 3.14159

次の使用例は、シート 1 のセル A1 に数式を作成します。

Worksheets("Sheet1").Range("A1").Formula = "=10*RAND()"

この例では、アクティブなブックの Sheet1 のセル A1:D10 でループしています。 セルの値が 0.001 未満の場合は、値をゼロ (0) に置き換えます。

For Each c in Worksheets("Sheet1").Range("A1:D10") 
 If c.Value < .001 Then 
 c.Value = 0 
 End If 
Next c

この例では、TestRange という名前の範囲をループし、範囲内の空のセルの数を表示します。

numBlanks = 0 
For Each c In Range("TestRange") 
 If c.Value = "" Then 
 numBlanks = numBlanks + 1 
 End If 
Next c 
MsgBox "There are " & numBlanks & " empty cells in this range"

この例では、アクティブなブックの Sheet1 のセル A1:C5 のフォント スタイルを斜体に設定します。 Range プロパティの構文 2 を使用します。

With Worksheets("Sheet1")
	.Range(.Cells(1, 1), .Cells(5, 3)).Font.Italic = True
End With

この例では、 Worksheet.Range プロパティ、 Application.Union メソッド、および Application.Intersect メソッドを比較します。

Range("A1:A10").Select                            'Selects cells A1 to A10.
Range(Range("A1"), Range("A10")).Select           'Selects cells A1 to A10.
 Range("A1, A10").Select                          'Selects cells A1 and A10.
Union(Range("A1"), Range("A10")).Select           'Selects cells A1 and A10.
 Range("A1:A5 A5:A10").Select                     'Selects cell A5.
Intersect(Range("A1:A5"), Range("A5:A10")).Select 'Selects cell A5.

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。