ナビゲーション ウィンドウに表示されたときの CalendarModule オブジェクトの序数位置を表す Long 値を返すか設定します。 値の取得と設定が可能です。
構文
式。位置
式CalendarModule オブジェクトを表す変数。
注釈
このプロパティは 1 ～ 9 の範囲の値にのみ設定できます。 このプロパティをこの範囲外の値に設定しようとすると、エラーが発生します。
指定した CalendarModule オブジェクトに対してこのプロパティの値を変更すると、新しい値と元の値との間の相対的な変化に応じて、 NavigationModules コレクションには、他のナビゲーション モジュールの 位置 の値が変更されます。
新しい値が元の値より小さい場合は、指定した CalendarModule オブジェクトが新しい位置に移動し、されているかを下に新しい、他のナビゲーション モジュールが下へ移動を配置します。
新しい値が元の値より大きい場合は、指定した CalendarModule オブジェクトが新しい位置を下へ移動し、古い位置と新しい位置の間では、他のナビゲーション モジュールが、上へ移動、古い位置を埋めます。
例
次の Visual Basic for Applications (VBA) サンプル コードでは、ナビゲーション ウィンドウから Calendar ナビゲーション モジュールの取得が試行されます。 モジュールが正常に取得されると、コードは CalendarModule オブジェクトの Position プロパティを '1' に設定し、ナビゲーション ウィンドウの最上部に移動します。 最後に、コードは、取得した Calendar モジュールに NavigationPane オブジェクトの CurrentModule プロパティを設定し、ナビゲーション ウィンドウで選択します。
Sub MoveCalendarModuleFirst()
Dim objPane As NavigationPane
Dim objModule As CalendarModule
On Error GoTo ErrRoutine
' Get the current NavigationPane object.
Set objPane = Application.ActiveExplorer.NavigationPane
' Get the Calendar navigation module
' from the navigation pane.
Set objModule = objPane.Modules.GetNavigationModule( _
olModuleCalendar)
' If a CalendarModule object is present,
' make it the first navigation module displayed in the
' Navigation Pane.
If Not (objModule Is Nothing) Then
objModule.Position = 1
End If
' Select the Calendar navigation module in the
' Navigation Pane.
Set objPane.CurrentModule = objModule
EndRoutine:
On Error GoTo 0
Set objModule = Nothing
Set objPane = Nothing
Exit Sub
ErrRoutine:
Debug.Print Err.Number & " (&H" & Hex(Err.Number) & ")"
Select Case Err.Number
Case -2147024809 '&H80070057
' Typically occurs if you set the Position
' property less than 1 or greater than 9.
MsgBox Err.Number & " - " & Err.Description, _
vbOKOnly Or vbCritical, _
"MoveCalendarModuleFirst"
End Select
GoTo EndRoutine
End Sub
関連項目
サポートとフィードバック
Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。