RecurrencePattern.DayOfWeekMask プロパティ (Outlook)

定期的な予定またはタスクが発生する曜日のマスクを表す OlDaysOfWeek 定数を返すか、または設定します。 値の取得と設定が可能です。

構文

expression。 DayOfWeekMask

式RecurrencePattern オブジェクトを表す変数。

注釈

DayOfWeekMask は、 RecurrenceType プロパティが設定されているし、前に、 プロパティ 、 PatternStartDate プロパティを設定した後に設定してください。

月間および年間のパターンは、1 日にのみ有効です。 毎週のパターンはと かDayOfWeekMask の有効なのみです。

例

この Visual Basic for Applications の例は、新しく作成された AppointmentItem の RecurrencePattern オブジェクトを取得するのに GetRecurrencePattern を使用します。 プロパティ、 RecurrenceType 、 DayOfWeekMask 、 PatternStartDate 、 年 、 期間 、 開始時刻 、 終了時刻 、および 件名 が設定されて、予定が保存され、パターンが表示されます:「金曜日、月曜日、水曜日、および金曜日 10/2006 年 7 月 8/25/2006 年まで午後 2:00 から午後 3:00 にします」。

Sub RecurringAppointmentEveryMondayWednesdayFriday() 
 
 Dim oAppt As AppointmentItem 
 
 Dim oPattern As RecurrencePattern 
 
 Set oAppt = Application.CreateItem(olAppointmentItem) 
 
 Set oPattern = oAppt.GetRecurrencePattern 
 
 With oPattern 
 
 .RecurrenceType = olRecursWeekly 
 
 .DayOfWeekMask = olMonday Or olWednesday Or olFriday 
 
 .PatternStartDate = #7/10/2006# 
 
 .PatternEndDate = #8/25/2006# 
 
 .Duration = 60 
 
 .StartTime = #2:00:00 PM# 
 
 .EndTime = #3:00:00 PM# 
 
 End With 
 
 oAppt.Subject = "Recurring Appointment Monday Wednesday Friday" 
 
 oAppt.Save 
 
 oAppt.Display 
 
End Sub

最後の例と同様に、この Visual Basic for Applications の使用例もを使用して、 GetRecurrencePattern 新しく作成された AppointmentItem の RecurrencePattern オブジェクトを取得します。 プロパティ、 RecurrenceType 、 DayOfWeekMask 、 PatternStartDate 、 年 、 期間 、 開始時刻 、 終了時刻 、および 件名 が設定されて、予定が保存され、パターンが表示されます:「金曜日、月曜日、火曜日、水曜日、木曜日、および金曜日 10/2006 年 7 月 2006 年 8 月 4 日までです」。

Sub RecurringEventEveryWeekday() 
 
 Dim oPattern As Outlook.RecurrencePattern 
 
 Dim oAppt As Outlook.AppointmentItem 
 
 Set oAppt = Application.CreateItem(olAppointmentItem) 
 
 Set oPattern = oAppt.GetRecurrencePattern 
 
 With oPattern 
 
 .RecurrenceType = olRecursWeekly 
 
 .DayOfWeekMask = olMonday Or olTuesday Or olWednesday Or olThursday Or olFriday 
 
 .PatternStartDate = #7/10/2006# 
 
 .PatternEndDate = #8/4/2006# 
 
 .Duration = 1440 'Duration in minutes, for all day event = 24 * 60 
 
 .StartTime = #12:00:00 AM# 
 
 .EndTime = #12:00:00 AM# 
 
 End With 
 
 oAppt.Subject = "Recurring Event Every Weekday" 
 
 oAppt.Save 
 
 oAppt.Display 
 
End Sub

関連項目

RecurrencePattern オブジェクト

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。

  • 最終更新: