Views.Add メソッド (Outlook)

Views コレクションに新しいビューを作成します。

構文

式。Add (Name, ViewType, SaveOption)

式Views オブジェクトを表す変数。

パラメーター

名前 必須 / オプション データ型 説明
名前 必須 文字列型 (String) 新しいビューの名前を指定します。
ViewType 必須 OlViewType 新しいビューの種類を指定します。
SaveOption 省略可能 OlViewSaveOption 新しいビューのアクセス許可を指定する保存オプション:
  • olViewSaveOptionAllFoldersOfType ビューは、このタイプのすべてのフォルダーにアクセスできます。
  • olViewSaveOptionThisFolderEveryOne ビューは、このフォルダーのみですべてのユーザーがアクセスできます。
  • olViewSaveOptionThisFolderOnlyMe ビューは、ユーザーだけがこのフォルダーにアクセスできます。

戻り値

新しい受信者を表す View オブジェクト。

注釈

現在のフォルダーではないフォルダーの Views コレクションにビューを追加する場合は、次のコード サンプルに示すように、最初に Views コレクション オブジェクトのコピーを保存してから、このコレクション オブジェクトに View を追加する必要があります。 これは、追加されたビューに対する View.Apply の呼び出しが失敗する既存の問題の回避策です。

Sub CalendarView() 
 Dim calView As Outlook.View 
 Dim vws As Views 
 
 Set Application.ActiveExplorer.CurrentFolder = Application.Session.GetDefaultFolder(olFolderInbox) 
 ' Current folder is Inbox; add a View to the Calendar folder which is not the current folder 
 ' Keep a copy of the object for the Views collection for the Calendar 
 Set vws = Application.Session.GetDefaultFolder(olFolderCalendar).Views 
 ' Add the View to this Views collection object 
 Set calView = vws.Add("New Calendar", olCalendarView, olViewSaveOptionThisFolderEveryone) 
 calView.Save 
 ' This Apply call will be fine 
 calView.Apply 
End Sub

例

次の Visual Basic for Applications (VBA) の例では、New Table という新しいビューを作成し、それを objNewView という変数に格納します。

Sub CreateView() 
 'Creates a new view 
 Dim objName As Outlook.NameSpace 
 Dim objViews As Outlook.Views 
 Dim objNewView As Outlook.View 
 
 Set objName = Application.GetNamespace("MAPI") 
 Set objViews = objName.GetDefaultFolder(olFolderInbox).Views 
 Set objNewView = objViews.Add(Name:="New Table", _ 
 ViewType:=olTableView, SaveOption:=olViewSaveOptionThisFolderEveryone) 
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。

  • Last updated on