Task.PathDrivenSuccessor プロパティ (Project)

[タスク パス] ドロップダウン リストで [DrivenSuccessors] 項目が選択されている場合に、タスクが選択したタスクによって駆動される後続タスクであるかどうかを示す値を取得します。 読み取り専用の Boolean です。

構文

expression。 PathDrivenSuccessor

式Task オブジェクトを表す変数。

注釈

Task.PathDrivenSuccessor プロパティは、リボンの [GANTT CHART TOOLS] (ガント チャート ツール) の下にある [書式] タブの [タスク パス] ドロップダウン リストの [駆動後続処理] 項目に関連しています。 タスク パスは主に Project クライアントの書式設定機能であり、ガント チャートのタスクの色は、現在の選択されているタスクと、選択内容に対する指定したタスクの関係によって変わります。 図 1 では、[タスク パス] ドロップダウン リストで [駆動先行タスク] 項目と [駆動後続処理] 項目が選択されています。 T3 を選択すると、ガント チャートは、T1 が駆動先行タスクであり、T4 が駆動後続タスクであることを示しています。

図 1. タスクのパスのプロパティを使用してタスクを強調

タスク パス プロパティを使用してタスクを強調表示する PathDrivenSuccessor プロパティは、ユーザー インターフェイスの [駆動後続] の選択とは異なります。 代わりに、次の両方の条件が満たされている場合、PathDrivenSuccessor プロパティは True になります。(a) タスクが選択したタスクの駆動付き後続タスクであり、(b) タスク パスで [駆動付き後続タスク] 項目が選択されている場合。 タスクを手動で選択するか、VBA を使用してタスクを選択し、VBA を使用して、別のタスクが選択したタスクの後続タスクであるかどうかをチェックできます。 たとえば、図 1 のように 3 番目のタスクを選択し、[タスク パス] で [駆動後続タスク] 項目が選択されている場合、次のステートメントは VBE の [即時] ウィンドウに True と出力します。

? ActiveProject.Tasks(4).PathDrivenSuccessor

ただし、[ Driven Successors ] 項目が選択されていない場合、前のステートメントは False を出力します。 Project には、[ タスク パス] ドロップダウン リストの項目を設定できる VBA メソッドがありません。

例

TestTaskPath マクロは、プロジェクト内の各タスクを選択し、4 つのタスク パス プロパティを順番に使用して、他のタスクと選択したタスクの関係を示します。

Option Explicit

Sub TestTaskPath()
    Dim t As Task
    Dim chkTsk As Task
    Dim selectedTaskId As Integer
    
    For Each t In ActiveProject.Tasks
        selectedTaskId = t.ID
        Application.SelectRow Row:=selectedTaskId, RowRelative:=False
            
        If Not (ActiveSelection.Tasks Is Nothing) Then
            Debug.Print
            
            With ActiveSelection.Tasks(1)
                Debug.Print "Selected task ID " & .UniqueID & ", name: " & .Name
            End With
                        
            For Each chkTsk In ActiveProject.Tasks
                If Not (chkTsk.ID = selectedTaskId) Then
                    If chkTsk.PathPredecessor Then
                        Debug.Print vbTab & chkTsk.Name & ": PathPredecessor"
                    End If
                    If chkTsk.PathDrivingPredecessor Then
                        Debug.Print vbTab & chkTsk.Name & ": PathDrivingPredecessor"
                    End If
                    If chkTsk.PathSuccessor Then
                        Debug.Print vbTab & chkTsk.Name & ": PathSuccessor"
                    End If
                    If chkTsk.PathDrivenSuccessor Then
                        Debug.Print vbTab & chkTsk.Name & ": PathDrivenSuccessor"
                    End If
                End If
            Next chkTsk
        End If
    Next t
End Sub

図 1 のプロジェクトでは、[タスク パス] で [先行タスク]、[先行タスク]、[後続タスク]、[駆動後続タスク] の項目がすべて選択されている場合、TestTaskPath マクロの出力は次のようになります。

Selected task ID 1, name: T1
    T2: PathSuccessor
    T2: PathDrivenSuccessor
    T3: PathSuccessor
    T3: PathDrivenSuccessor
    T4: PathSuccessor
    T4: PathDrivenSuccessor

Selected task ID 2, name: T2
    T1: PathPredecessor
    T1: PathDrivingPredecessor

Selected task ID 3, name: T3
    T1: PathPredecessor
    T1: PathDrivingPredecessor
    T4: PathSuccessor
    T4: PathDrivenSuccessor

Selected task ID 4, name: T4
    T1: PathPredecessor
    T1: PathDrivingPredecessor
    T3: PathPredecessor
    T3: PathDrivingPredecessor

プロパティ値

VARIANT

関連項目

タスク オブジェクト

PathDrivingPredecessor プロパティPathPredecessor プロパティPathSuccessor プロパティ

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。

  • Last updated on