DataColumns.SetColumnProperties メソッド (Visio)

1 つ以上のデータ列のプロパティを設定します。

注:

この Visio オブジェクトまたはメンバーは Visio Professional 2013 のライセンス ユーザーのみが使用できます。

構文

式。SetColumnProperties (ColumnNames(), Properties(), Values())

式DataColumns オブジェクトを返す式。

パラメーター

名前 必須 / オプション データ型 説明
ColumnNames() 必須 String データ列名を表す文字列の配列。
properties() 必須 Long データ列のプロパティを VisDataColumnProperties 列挙で表す配列です。 使用可能な値については備考を参照してください。
Values() 必須 バリアント型 プロパティに割り当てられる値の配列です。 設定可能な値については、「備考」を参照してください。

戻り値

なし

解説

SetColumnProperties メソッドは、一度に 1 つの列にプロパティを設定するよりも、複数のデータ列のプロパティを同時に設定する方が効率的な方法です。 3 つのパラメーター配列のそれぞれに配置する項目に応じて、同じデータ列の複数のプロパティを変更したり、異なるデータ列の 1 つ以上のプロパティを変更したりできます。 変更するたびに、関連する列名/プロパティ/値のトリプレットを 3 つの配列すべての対応する位置に渡します。 メソッドに渡す 3 つの配列すべてのサイズは同じでなければならないことに注意してください。そうしないと、メソッドはエラーを返します。

ColumnNames() パラメーターには、プロパティを変更するデータ列の名前の配列を渡します。 同じ列の複数のプロパティを変更する場合、変更するプロパティの配列内の位置に対応する要素には、それぞれ同じ列の名前を登録することも、1 つだけ列の名前を登録し、続く要素は空の文字列にしておくこともできます。

Properties() パラメーター配列の要素に設定可能な値は、次のとおりです。これらの値は VisDataColumnProperties で宣言されています。

定数 値 説明
visDataColumnPropertyCalendar 3 データ列プロパティのカレンダー。
visDataColumnPropertyCurrency 5 データ列プロパティの通貨。
visDataColumnPropertyDisplayName 6 UI でのデータ列プロパティの表示名。
visDataColumnPropertyHyperlink 8 図形にリンクされている場合、Visio UI でデータ列の値をハイパーリンクとして表示するかどうかを表します。
visDataColumnPropertyLangID 2 データ列プロパティの言語 ID。
visDataColumnPropertyType 1 データ列プロパティのデータ型。
visDataColumnPropertyUnits 4 データ列プロパティの単位。
visDataColumnPropertyVisible 7 データ列のプロパティが UI に表示されるかどうかを表します。

Values() パラメーター配列の要素に設定可能な値は、対応する Property() 配列のパラメーター値によって決まります。 DataColumn.SetProperty トピックの表には、データ列のデータ型に応じて、各データ列プロパティの有効なデータ列プロパティ値が表示されます。

例

次の Microsoft Visual Basic for Applications (VBA) マクロは、アクティブなドキュメントの DataRecordsets コレクションで最後に追加されたレコードセットの 2 つの異なる列に対して 1 つのプロパティの値を設定する方法を示しています。 このマクロは、Visio に含まれている ORGDATA.xls ワークシートのデータに基づいたレコードセットが最後に追加されたと想定して書かれています。 そのデータ レコードセットを追加するためのサンプル コードは、「 DataRecordsets.Add 」メソッドのトピックに示されています。 ただし、このコードでは最低 2 つの列があるデータ レコードセットであれば、どのデータ レコードセットでも使用することができます。

このマクロでは、最初の列の表示名を "Dept." に変更し、2 番目の列の Hyperlink プロパティを True に設定します。 その後は (データ ソースとして ORGDATA を使用している場合)、データ レコードセット内のデータにリンクされた図形の電子メール アドレスがハイパーリンクの役割を果たします。

データ列の表示名を変更しても、変更されるのは DisplayName プロパティのみで、 Name プロパティで指定される列のプログラム名は変更されないことに注意してください。

 
Public Sub SetColumnProperties_Example() 
 
    Dim vsoDataRecordset As Visio.DataRecordset 
    Dim intCount As Integer 
     
    intCount = Visio.ActiveDocument.DataRecordsets.Count 
    Set vsoDataRecordset = Visio.ActiveDocument.DataRecordsets(intCount) 
     
    Dim astrColumnNames(1) As String 
    Dim alngProperties(1) As Long 
    Dim avarValues(1) As Variant 
     
    astrColumnNames(0) = vsoDataRecordset.DataColumns(1).DisplayName 
    astrColumnNames(1) = vsoDataRecordset.DataColumns(2).DisplayName 
        
    alngProperties(0) = visDataColumnPropertyDisplayName 
    alngProperties(1) = visDataColumnPropertyHyperlink 
        
    avarValues(0) = "Dept." 
    avarValues(1) = True 
         
    vsoDataRecordset.DataColumns.SetColumnProperties astrColumnNames, alngProperties, avarValues 
 
End Sub

サポートとフィードバック

Office VBA またはこの説明書に関するご質問やフィードバックがありますか？ サポートの受け方およびフィードバックをお寄せいただく方法のガイダンスについては、Office VBA のサポートおよびフィードバックを参照してください。

  • Last updated on