リソースの定義

完了済み

Bicep ファイルは、デプロイする Azure リソースを定義する作成ファイルです。

あなたの玩具会社は、製品の発売のために再利用可能な Bicep ファイルを作成する必要があります。 このファイルでは、Azure ストレージ アカウントと Azure App Service リソースをデプロイする必要があります。これは、起動時に各新製品のマーケティングに使用されます。

このユニットでは、Bicep ファイルでリソースを定義する方法、リソース名のしくみ、および相互に関連するリソースを作成する方法について説明します。

注

このユニットのコマンドは、概念を説明するために示されています。 コマンドはまだ実行しないでください。 ここで学習した内容をすぐに練習します。

リソースを定義する

Bicep ファイルで行う主な操作は、Azure リソースを定義することです。 Bicep の一般的なリソース定義の例を次に示します。 この例では、toylaunchstorage という名前のストレージ アカウントを作成します。

resource storageAccount 'Microsoft.Storage/storageAccounts@2023-05-01' = {
  name: 'toylaunchstorage'
  location: 'westus3'
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
  properties: {
    accessTier: 'Hot'
  }
}

このリソース定義の重要な部分について詳しく見てみましょう。

  • 開始時のresourceキーワードは、リソースを定義しようとしていることを Bicep に指示します。

  • 次に、リソースに シンボリック名を指定します。 この例では、その名前は storageAccount。 リソースを参照するには、Bicep式で使用します。 name プロパティによって割り当てられたAzure リソース名とは異なります。

  • Microsoft.Storage/storageAccounts@2023-05-01 は、リソースの種類と API のバージョンを指定します。 Microsoft.Storage/storageAccountsは、Azureストレージ アカウントを宣言します。 2023-05-01 は、そのリソースのデプロイに使用されるリソース プロバイダーの管理 API バージョンを選択します。

    ヒント

    Visual Studio CodeのBicep拡張機能は、作成するリソースのリソースの種類と API バージョンを見つけるのに役立ちます。 ARM テンプレートに精通している場合は、API バージョンが使用しているバージョンと一致することに注意してください。

  • リソース名を宣言する必要があります。これは、ストレージ アカウントが Azure に割り当てられる名前です。 name キーワードを使用して、リソース名を設定します。

    Von Bedeutung

    シンボリック名は、テンプレート内のリソースを識別します。 リソースの name プロパティは、そのAzure名を設定します。 シンボリック名のみを変更しても、デプロイされたAzure リソースの名前は変更されません。

  • その後、リソースの場所、SKU (価格レベル)、種類など、リソースのその他の詳細を設定します。 定義できるプロパティもあります。これは、リソースの種類ごとに異なります。 API バージョンによって、異なるプロパティが導入される場合もあります。 この例では、ストレージ アカウントのアクセス レベルを Hot に設定しています。

ヒント

多くの場合、リソース名には、最大長、許容される文字数、すべての Azure でにおける一意性など、従う必要がある規則があります。 リソース名の要件は、Azure リソースの種類によって異なります。 Bicep ファイルに追加する前に、名前付けの制限と要件を理解しておいてください。

リソースが相互に依存している場合はどうなりますか?

通常、Bicep ファイルには複数のリソースが含まれています。 多くの場合、リソースは別のリソースに依存する必要があります。 あるリソースから別のリソースを定義できるように、いくつかの情報を抽出しなければならない場合があります。 Web アプリケーションをデプロイする場合は、アプリケーションを追加する前に、サーバー インフラストラクチャを作成する必要があります。 これらのリレーションシップを 依存関係と呼びます。

おもちゃの製品を起動するのに役立つBicep ファイル用の App Service アプリをデプロイする必要がありますが、App Service アプリを作成するには、まず App Service プランを作成する必要があります。 App Service プランはサーバーホスティング リソースを表し、次の例のように宣言されています。

resource appServicePlan 'Microsoft.Web/serverFarms@2023-12-01' = {
  name: 'toy-product-launch-plan'
  location: 'westus3'
  sku: {
    name: 'F1'
  }
}

このリソース定義により、リソースの種類 Microsoft.Web/serverFarms を持つ App Service プランをデプロイすることが Bicep に指示されます。 プラン リソースには toy-product-launch-plan という名前が付けられ、米国西部 3 リージョンにデプロイされます。 これには、App Service の free レベルである F1 の価格 SKU を使います。

App Service プランを宣言したので、次の手順ではアプリを宣言します。

resource appServiceApp 'Microsoft.Web/sites@2023-12-01' = {
  name: 'toy-product-launch-1'
  location: 'westus3'
  properties: {
    serverFarmId: appServicePlan.id
    httpsOnly: true
  }
}

この Bicep ファイルは、作成したプランでアプリをホストするように Azure に指示します。 アプリの定義で、 serverFarmId: appServicePlan.id アプリの properties.serverFarmId プロパティを App Service プランのリソース ID に設定します。 この式では、プランのシンボリック名 ( appServicePlan) を使用して、その id プロパティにアクセスします。

ヒント

Azure リソース ID は、リソースとそのスコープを識別します。 このモジュールのリソース グループ スコープ リソースの場合、ID にはサブスクリプション ID、リソース グループ名、リソース プロバイダーの名前空間、リソースの種類、リソース名が含まれます。 他のスコープのリソースでは、異なる ID 形式が使用されます。 自分で ID を作成するのではなく、リソースの id プロパティ ( appServicePlan.id など) を参照します。 詳細については、「概要」ユニットの「詳細情報」セクションのリソース ID 関数のBicepを参照してください。

アプリ リソースとプランのシンボル名を参照するプロパティを宣言することで、App Service アプリとプランの間の "暗黙的な依存関係" が Azure で認識されます。 リソースのデプロイ時には、アプリのデプロイが始まる前に、プランが完全にデプロイされることが Azure によって確認されます。