Lag formkartvisualiseringer i Power BI

Gjelder for:✅ Power BI Skrivebord og Power Bi-tjeneste

Bruk et visuelt Shape-kart for å vise data på hvilken som helst form du kan definere—land, regioner, plantegninger, sittekart eller tilpassede grenser. Fargelegg hvert område basert på dataene dine for raskt å oppdage mønstre, sammenligne verdier på tvers av regioner og markere områder som trenger oppmerksomhet. Velg blant innebygde kart for vanlige regioner, last opp dine egne TopoJSON- eller GeoJSON-filer, eller referer til kart direkte via URL.

Lag et formkart

Du kan teste Shape-kartkontrollen med de innebygde kartene, eller du kan bruke ditt eget tilpassede kart så lenge det oppfyller kravene i neste avsnitt kalt Bruk tilpassede kart. Formkartvisualiseringer er basert på kart du kan finne på Internett, lage selv, eller konvertere til TopoJSON- eller GeoJSON-format. Eksempler på egendefinerte kart er: geografiske, sitteplasser, plantegninger og andre.

Legg til et visuelt formkart

1. Åpne eller lag en rapport i Power BI Desktop eller Power Bi-tjeneste.
2. I Visualiseringer-ruten velger du Figurkart-ikonet for å legge til et tomt visualobjekt på lerretet.
3. (Valgfritt) Endre størrelsen på det visuelle bildet slik at det er stort nok til å se regionskyggeleggingen tydelig.

Eksempeldata for testing

For å prøve Shape-kartet med eksempeldata, kan du legge til dette TMDL-skriptet i en tom Power BI Desktop-fil. Dette skriptet lager en tabell med amerikanske delstater og australske delstater og territorier, sammen med tilfeldige verdier for demonstrasjonsformål.

createOrReplace

	/// Table listing US states and Australian states and territories with random values, used for map visual demos.
	table Map

		/// Sum of RandomValue from the Map table, used for the map visual demo.
		measure 'Some value' = ```
				
				        SUM(Map[RandomValue])
				```
			formatString: #,0

		column RandomValue
			formatString: 0
			summarizeBy: sum
			isNameInferred
			sourceColumn: [RandomValue]

			annotation SummarizationSetBy = Automatic

		column 'Country or Region'
			dataCategory: Country
			summarizeBy: none
			isNameInferred
			sourceColumn: [Country or Region]

			annotation SummarizationSetBy = Automatic

		column 'State or Territory'
			dataCategory: StateOrProvince
			summarizeBy: none
			isNameInferred
			sourceColumn: [State or Territory]

			annotation SummarizationSetBy = Automatic

		partition Map = calculated
			mode: import
			source = ```
					
					VAR USAStates = 
					    DATATABLE(
					        "Country or Region", STRING,
					        "State or Territory", STRING,
					        {
					            {"USA", "Alabama"},
					            {"USA", "Alaska"},
					            {"USA", "Arizona"},
					            {"USA", "Arkansas"},
					            {"USA", "California"},
					            {"USA", "Colorado"},
					            {"USA", "Connecticut"},
					            {"USA", "Delaware"},
					            {"USA", "Florida"},
					            {"USA", "Georgia"},
					            {"USA", "Hawaii"},
					            {"USA", "Idaho"},
					            {"USA", "Illinois"},
					            {"USA", "Indiana"},
					            {"USA", "Iowa"},
					            {"USA", "Kansas"},
					            {"USA", "Kentucky"},
					            {"USA", "Louisiana"},
					            {"USA", "Maine"},
					            {"USA", "Maryland"},
					            {"USA", "Massachusetts"},
					            {"USA", "Michigan"},
					            {"USA", "Minnesota"},
					            {"USA", "Mississippi"},
					            {"USA", "Missouri"},
					            {"USA", "Montana"},
					            {"USA", "Nebraska"},
					            {"USA", "Nevada"},
					            {"USA", "New Hampshire"},
					            {"USA", "New Jersey"},
					            {"USA", "New Mexico"},
					            {"USA", "New York"},
					            {"USA", "North Carolina"},
					            {"USA", "North Dakota"},
					            {"USA", "Ohio"},
					            {"USA", "Oklahoma"},
					            {"USA", "Oregon"},
					            {"USA", "Pennsylvania"},
					            {"USA", "Rhode Island"},
					            {"USA", "South Carolina"},
					            {"USA", "South Dakota"},
					            {"USA", "Tennessee"},
					            {"USA", "Texas"},
					            {"USA", "Utah"},
					            {"USA", "Vermont"},
					            {"USA", "Virginia"},
					            {"USA", "Washington"},
					            {"USA", "West Virginia"},
					            {"USA", "Wisconsin"},
					            {"USA", "Wyoming"}
					        }
					    )
					VAR AustraliaStates = 
					    DATATABLE(
					        "Country", STRING,
					        "State", STRING,
					        {
					            {"Australia", "New South Wales"},
					            {"Australia", "Victoria"},
					            {"Australia", "Queensland"},
					            {"Australia", "Western Australia"},
					            {"Australia", "South Australia"},
					            {"Australia", "Tasmania"},
					            {"Australia", "Northern Territory"},
					            {"Australia", "Australian Capital Territory"}
					        }
					    )
					VAR AllStates = UNION(USAStates, AustraliaStates)
					RETURN
					    ADDCOLUMNS(
					        AllStates,
					        "RandomValue", RANDBETWEEN(1000, 1000000)
					    )
					```

Bygg formkartet

1. Velg det tomme visualobjektet for figurkart.

2. I Datapanelet drar du et geografisk felt til Lokasjonsbrønnen (for eksempel State, Region eller District).

   Tips

   Du kan merke en kolonne som geografisk ved å sette Datakategori-egenskapen når du redigerer den semantiske modellen.

3. Dra et numerisk mål (for eksempel Salg, Populasjon) til Fargemetning-brønnen .

4. Med det visuelle fortsatt valgt, velg i Visualisering-paneletFormater visuell og utvid Kartinnstillinger.

5. Velg en karttype (for eksempel Italia, Mexico, USA) fra rullegardinmenyen.

6. Hvis du vil vise kartnøklene for det valgte kartet, velger du Vis karttypenøkkel.

7. Velg hvilken måte å vise et tredimensjonalt objekt (jorden) på som et todimensjonalt kart ved hjelp av rullegardinlisten Projeksjon .

   • Ekvirektangulær: Sylindrisk projeksjon som konverterer kloden til et rutenett med hver rektangulær celle som har samme størrelse, form og areal.
   • Mercator: Sylindrisk projeksjon med ekvator avbildet som tangenslinjen. Polare områder er mer forvrengt enn equirectangular projeksjoner.
   • Orthographic (Ortografisk ) En projeksjon fra et uendelig punkt, som fra det dype verdensrommet. Det gir en illusjon av en tredimensjonal klode.

   Hvis du vil ha mer detaljert informasjon, kan du se Esris kartprojeksjonsreferanse.

8. (Valgfritt) Legg til et kategorisk felt i Forklaring for å klassifisere kartområdene etter kategori.

9. (Valgfritt) I Visualiseringspanelet , utvid Farger for å justere paletten og andre fargeinnstillinger.

Bruk egendefinerte kart

Du kan bruke de innebygde karttypene eller ditt eget tilpassede kart så lenge det oppfyller kravene i Load a custom map. Formkartvisualiseringer er basert på kart du kan finne, lage eller konvertere til TopoJSON- eller GeoJSON-format (for eksempel: geografiske regioner, sitteoppsett, plantegninger).

Last inn et egendefinert kart

Du kan laste inn et egendefinert kart ved å laste opp en fil eller oppgi en URL.

Last opp en kartfil

1. Legg til eller velg et visualobjekt for formkart.
2. I Visualiseringspanelet velger du Formater visuell og utvid Kartinnstillinger.
3. I Karttype velger du Egendefinert kart.
4. Velg Legg til en karttype.
5. Gå til og velg .topojson - eller .geojson-filen din, og velg deretter Åpne.
6. (Valgfritt) Velg Vis karttype-tast for å verifisere at regionsnavn eller ID-er samsvarer med dine posisjonsfeltverdier .

Legg til et kart fra URL

Du kan også referere til en kartfil som ligger på nettet:

1. Legg til eller velg et visualobjekt for formkart.
2. I Visualiseringspanelet velger du Formater visuell og utvid Kartinnstillinger.
3. I Type, velg URL.
4. Lim inn URL-en til en TopoJSON- eller GeoJSON-fil i Enter a URL, eller bruk Fx-knappen for å peke til et mål som inneholder URL-en.

Denne tilnærmingen er nyttig når du ønsker å dele et kart på tvers av flere rapporter eller bruke et kart som ligger sentralt.

Last ned og rediger et tilpasset kart

Hvis du tidligere lastet opp et egendefinert kart og trenger å gjøre endringer, kan du laste det ned:

1. Velg Shape-kartvisualiseringen som bruker det tilpassede kartet.
2. Åpne Format-ruten , og utvid Kartinnstillinger.
3. Velg Last ned kart.
4. Rediger den nedlastede filen etter behov ved hjelp av en teksteditor eller et GIS-verktøy.
5. Last opp den oppdaterte filen ved å bruke trinnene i Last opp en kartfil.

Eksempel på egendefinert kart

Kontorene til de USA advokatene utgir en årlig regnskapsrapport om deres rettstvister og sakslastdata. Vi konverterer noe av distriktsdataene deres til .json filer og legger dem til i dette eksempelet på PBIX.

Demonstrasjon av egendefinert figurkart . PBIX-fil

Hvis du vil eksperimentere med egendefinerte kart, last ned denne PBIX-filen og følg med.

1. Fra Power BI Desktop velger du Åpne > fil-rapport.
2. Siden delstatene kan deles inn i flere distrikter, må du bruke et tilpasset formkart for distriktene. Ved å importere TopoJSON-kartet over de amerikanske rettsdistriktene inn i Power BI Desktop, kan du visualisere de årlige dataene til statsadvokatens årlige finansdepartement.

Støttede kartformater

Shape Map støtter to kartfilformater:

• TopoJSON: En utvidelse av GeoJSON som koder topologi. TopoJSON-filer er vanligvis mindre enn GeoJSON-filer fordi delte grenser kun lagres én gang.
• GeoJSON: Et åpent standardformat for koding av geografiske datastrukturer.

Begge formatene fungerer med Shape Map. Bruk TopoJSON for mindre filstørrelser eller GeoJSON hvis det er det kartverktøyene dine produserer.

Fargeformateringsmuligheter

Fargeseksjonen i de visuelle formateringsalternativene tilpasses basert på datakonfigurasjonen din:

• Kun lokasjon: Sett farger med betinget formatering eller individuelt for hver region.
• Sted og legende: Sett en egen farge for hver legendeverdi individuelt.
• Fargemetning: Velg fargegradientfarger basert på verdiene i fargemetningsfeltet.

Du kan også tilpasse fargen på tomt område for områder som ikke matcher dataene dine, og justere kantfarge og tykkelse.

Eksempel: Gradientfarger etter region

Når du kun bruker Location-feltet (uten Legend eller Color saturation), kan du bruke betinget formatering med et DAX-mål for å skape en gradienteffekt innenfor hver region. Følgende mål beregner en hex-farge basert på totalsalg, hvor hver region bruker sin egen fargepalett. Delstater med høyere salg virker mer mettede, mens delstater med lavere salg virker lettere.

Region Gradient Color = 
VAR ScaleWithinRegion = TRUE
VAR CurrentSales = [Total Sales]

VAR ScopeMin =
    IF (
        ScaleWithinRegion,
        CALCULATE (
            MINX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALLEXCEPT ( StateRegion, StateRegion[Region] )
        ),
        CALCULATE (
            MINX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALL ( StateRegion )
        )
    )

VAR ScopeMax =
    IF (
        ScaleWithinRegion,
        CALCULATE (
            MAXX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALLEXCEPT ( StateRegion, StateRegion[Region] )
        ),
        CALCULATE (
            MAXX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALL ( StateRegion )
        )
    )

VAR Ratio =
    DIVIDE ( CurrentSales - ScopeMin, ScopeMax - ScopeMin )

VAR Region = SELECTEDVALUE ( StateRegion[Region] )

VAR EndR = SWITCH ( Region,
    "Northwest", 17,  "Northeast", 216, "Southeast", 116,
    "Southwest", 224, "Alaska", 17,     "Hawaii", 17,    128 )
VAR EndG = SWITCH ( Region,
    "Northwest", 141, "Northeast", 106, "Southeast", 78,
    "Southwest", 68,  "Alaska", 141,    "Hawaii", 141,   128 )
VAR EndB = SWITCH ( Region,
    "Northwest", 255, "Northeast", 44,  "Southeast", 194,
    "Southwest", 68,  "Alaska", 255,    "Hawaii", 255,   128 )

VAR TintStrength = 0.15
VAR StartR = 255 - ( 255 - EndR ) * TintStrength
VAR StartG = 255 - ( 255 - EndG ) * TintStrength
VAR StartB = 255 - ( 255 - EndB ) * TintStrength

VAR R01 = MIN ( 1, MAX ( 0, Ratio ) )

VAR R = INT ( StartR + ( EndR - StartR ) * R01 )
VAR G = INT ( StartG + ( EndG - StartG ) * R01 )
VAR B = INT ( StartB + ( EndB - StartB ) * R01 )

VAR HexChars = "0123456789ABCDEF"
VAR Hex =
    "#" &
    MID ( HexChars, QUOTIENT ( R, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( R, 16 ) + 1, 1 ) &
    MID ( HexChars, QUOTIENT ( G, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( G, 16 ) + 1, 1 ) &
    MID ( HexChars, QUOTIENT ( B, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( B, 16 ) + 1, 1 )

RETURN
    IF ( ISBLANK ( CurrentSales ), "#FFFFFF", Hex )

For å bruke dette målet:

1. Legg til målingen i din semantiske modell.
2. I Shape-kartvisualiseringen, legg til lokasjonsfeltet ditt i Location-brønnen.
3. I Format-panelet, utvid Fargeplassering>.
4. Velg Fx-knappen ved siden av Standard.
5. Sett Format-stil til Felt-verdi og velg målet Region Gradient Color .

Hver delstat viser en fargeintensitet basert på salget i forhold til andre delstater i samme region.

Få kartdata

For raskt å få data inn i en modell for å teste Shape map, kopier en av tabellene på slutten av denne artikkelen, og velg deretter Enter data fra Home-båndet .

Den øverste raden identifiseres automatisk som en topptekst. Skriv inn en ny kolonne ved å skrive et nytt kolonnenavn i den tomme kolonnen til høyre. Legg til verdier i hver celle, akkurat som du kan gjøre i Excel. Når du er ferdig, velg Last inn. Tabellen legges til datamodellen.

Hensyn og begrensninger

Tenk på følgende når du bruker Shape Map:

• Fargemetningsbøtten må settes for at Legend-klassifiseringen skal fungere riktig.
• Shape-kartet viser opptil maksimalt 1 500 datapunkter.

Områdenøkler

Bruk følgende regionstaster for å teste Shape-kartet.

Australia: Stater

Østerrike: Stater

Brasil: Delstater

Canada: Provinser

Frankrike: Regioner

Tyskland: Stater

Irland: Fylker

Italia: Regioner

Mexico: Stater

Nederland: Provinser

Storbritannia: Land/regioner

USA: Stater

Relatert innhold

• Kartvisualiseringer i Power BI
• Fylte kart (choropleths) i Power BI
• Tips og triks for kartvisualiseringer
• Betinget formatering i Power BI
• Visualiseringstyper i Power BI