SharePoint.Contents

Syntaks

SharePoint.Contents(url as text, optional options as nullable record) as table

Om

Returnerer en hierarkisk tabell som inneholder mappene og filene som ble funnet på det angitte SharePoint-området. url Tabellen viser elementene på gjeldende nivå og returnerer ikke alle filer på området på nytt. For mapper Content inneholder kolonnen en nestet tabell som kan brukes til å navigere til mappeinnholdet. For filer Content inneholder kolonnen filinnholdet som en binær verdi. Hvis du vil returnere en flat tabell over alle filene på området og undermappene, bruker SharePoint.Filesdu . Hver rad inneholder Nameogså kolonnene , , ExtensionDate accessed, Date createdDate modified, Attributesog .Folder Path Mapperader har en tom Extension verdi. Date accessed er null for både mapper og filer. Verdien Folder Path er den absolutte URL-adressen til mappen som inneholder elementet. URL-adressen for området kan ikke inneholde en spørringsstreng eller et fragment. options kan angis for å kontrollere følgende alternativer:

  • ApiVersion: Et tall (14 eller 15) eller teksten «Auto» som angir SharePoint-API-versjonen som skal brukes for dette området. Når det ikke er angitt, brukes API versjon 14. Når Auto er angitt, oppdages serverversjonen automatisk hvis det er mulig, ellers brukes 14 versjoner som standard. SharePoint-områder som ikke er engelske, krever minst versjon 15.
  • Implementation: Valgfritt. Angir hvilken versjon av SharePoint-koblingen som skal brukes. Godtatte verdier er 2,0 eller null. Hvis verdien er 2.0, brukes 2.0-implementeringen av SharePoint-koblingen. Hvis verdien er null, brukes den opprinnelige implementeringen av SharePoint-koblingen.

For SharePoint.Contentsstøtter ApiVersion den opprinnelige implementeringen verdiene 14, 15 og "Auto". Hvis ApiVersion ikke er angitt, brukes versjon 14. Med implementering 2.0 ApiVersion trenger du ikke å angis fordi API versjon 15 brukes automatisk. API versjon 14 støttes ikke med implementering 2.0.

Eksempel 1

Returner innholdet på øverste nivå SharePoint ved hjelp av den opprinnelige implementeringen. Siden ingen alternativer er angitt, brukes API versjon 14.

Forbruk

SharePoint.Contents("https://contoso.sharepoint.com/sites/Contoso")

Utdata

A hierarchical table containing the top-level folders and files in the site.

Eksempel 2

Bruk den opprinnelige implementeringen med automatisk API-valg for å returnere hver .xlsx fil i biblioteket delte dokumenter. Utvidelsessammenligningen skilles ikke mellom store og små bokstaver.

Forbruk

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    ExcelWorkbooks = Table.SelectRows(
        SharedDocuments,
        each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
in
    ExcelWorkbooks

Utdata

A table containing only the files in the Shared Documents library whose Extension value is .xlsx.

Eksempel 3

Bruk implementering 2.0 til å returnere det umiddelbare innholdet i Rapporter-mappen i biblioteket delte dokumenter. Implementation 2.0 bruker API versjon 15 som standard.

Forbruk

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content]
in
    Reports

Utdata

A hierarchical table containing the immediate folders and files in the Reports folder.

Eksempel 4

Returner det binære innholdet i Budget.xlsx ved å navigere i det hierarkiske innholdet på nettstedet.

Forbruk

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content],
    Budget = Reports{[Name = "Budget.xlsx"]}[Content]
in
    Budget

Utdata

The binary content of Budget.xlsx.

  • Sist oppdatert