Quickstart: Een Azure-app Configuratiearchief maken met Bicep

In deze quickstart wordt beschreven hoe u Bicep kunt gebruiken om:

• Implementeer een App Configuration-store.
• Sleutelwaarden maken in een App Configuration-archief.
• Sleutel-waardeparen lezen in een App Configuration-store.

Bicep is een domeinspecifieke taal (DSL) die declaratieve syntaxis gebruikt om Azure-resources te implementeren. Deze taal voorziet in een beknopte syntaxis, betrouwbare typeveiligheid en ondersteuning voor hergebruik van code. Bicep biedt de beste ontwerpervaring voor uw infrastructuur als code-oplossingen in Azure.

Vereisten

Als u geen Azure-abonnement hebt, maakt u een gratis account voordat u begint.

Autorisatie

Voor het beheren van een Azure-app Configuratieresource met Bicep-bestand is een Azure Resource Manager-rol vereist, zoals inzender of eigenaar. Voor toegang tot Azure App Configuration-gegevens (sleutel-waardeparen, momentopnamen) zijn een Azure Resource Manager-rol en een extra Azure App Configuration-gegevensvlakrol vereist wanneer de ARM-verificatiemodus van de configuratieopslag is ingesteld op de pass-through-ARM-verificatiemodus.

Controleer het Bicep-bestand

Het Bicep-bestand dat in deze quickstart wordt gebruikt, is afkomstig van Azure-quickstartsjablonen.

@description('Specifies the name of the App Configuration store.')
param configStoreName string = 'appconfig${uniqueString(resourceGroup().id)}'

@description('Specifies the Azure location where the app configuration store should be created.')
param location string = resourceGroup().location

@description('Specifies the names of the key-value resources. The name is a combination of key and label with $ as delimiter. The label is optional.')
param keyValueNames array = [
  'myKey'
  'myKey$myLabel'
]

@description('Specifies the values of the key-value resources. It\'s optional')
param keyValueValues array = [
  'Key-value without label'
  'Key-value with label'
]

@description('Specifies the content type of the key-value resources. For feature flag, the value should be application/vnd.microsoft.appconfig.ff+json;charset=utf-8. For Key Value reference, the value should be application/vnd.microsoft.appconfig.keyvaultref+json;charset=utf-8. Otherwise, it\'s optional.')
param contentType string = 'the-content-type'

@description('Adds tags for the key-value resources. It\'s optional')
param tags object = {
  tag1: 'tag-value-1'
  tag2: 'tag-value-2'
}

resource configStore 'Microsoft.AppConfiguration/configurationStores@2024-05-01' = {
  name: configStoreName
  location: location
  sku: {
    name: 'standard'
  }
}

resource configStoreKeyValue 'Microsoft.AppConfiguration/configurationStores/keyValues@2024-05-01' = [for (item, i) in keyValueNames: {
  parent: configStore
  name: item
  properties: {
    value: keyValueValues[i]
    contentType: contentType
    tags: tags
  }
}]

output reference_key_value_value string = configStoreKeyValue[0].properties.value
output reference_key_value_object object = {
  name: configStoreKeyValue[1].name
  properties: configStoreKeyValue[1].properties
}

Er worden twee Azure-resources gedefinieerd in het Bicep-bestand:

• Microsoft.AppConfiguration/configurationStores: een App Configuration-opslag maken.
• Microsoft.AppConfiguration/configurationStores/keyValues: maak een sleutel-waarde in de App Configuration-opslag.

Met dit Bicep-bestand maken we één sleutel met twee verschillende waarden, waarvan één een uniek label heeft.

Het Bicep-bestand implementeren

1. Sla het Bicep-bestand op als main.bicep op uw lokale computer.

2. Implementeer het Bicep-bestand met behulp van Azure CLI of Azure PowerShell.

   Vervangt u in de volgende voorbeelden <ResourceGroupName> door een naam voor uw resourcegroep en <AppConfigurationStoreName> door een unieke naam voor uw configuratieopslag.

   • CLI
   • Powershell

   az group create --name <ResourceGroupName> --location eastus
   az deployment group create --resource-group <ResourceGroupName> --template-file main.bicep --parameters configStoreName=<AppConfigurationStoreName>
   

   Wanneer de implementatie is voltooid, ziet u een bericht waarin wordt aangegeven dat de implementatie is voltooid.

Geïmplementeerde resources bekijken

Gebruik Azure CLI of Azure PowerShell om de geïmplementeerde resources in de resourcegroep weer te geven.

az resource list --resource-group <ResourceGroupName>

Get-AzResource -ResourceGroupName <ResourceGroupName>

U kunt azure Portal ook gebruiken om de resources weer te geven:

1. Meld u aan bij het Azure-portaal.
2. Voer in het zoekvak App Configuration in en selecteer vervolgens App Configuration in de lijst.
3. Selecteer de zojuist gemaakte App Configuration-resource.
4. Selecteer Configuratieverkenner onder Bewerkingen.
5. Controleer of er twee sleutelwaarden bestaan.

Resources opruimen

Wanneer u de resourcegroep en de resources ervan niet meer nodig hebt, gebruikt u Azure CLI of Azure PowerShell om deze te verwijderen.

az group delete --name <ResourceGroupName>

Remove-AzResourceGroup -Name <ResourceGroupName>

U kunt azure Portal ook gebruiken om de resourcegroep te verwijderen:

1. Navigeer naar uw resourcegroep.
2. Selecteer Resourcegroep verwijderen.
3. Er wordt een tabblad weergegeven. Voer de naam van de resourcegroep in en selecteer Verwijderen.

Volgende stappen

Bekijk de ARM-sjabloonvoorbeelden voor meer informatie over het toevoegen van functievlag en Key Vault-verwijzing naar een App Configuration-archief.

• app-configuration-store-ff
• app-configuration-store-keyvaultref