OpenTelemetry New Relic exporteren in Azure Container Apps

Deze configuratiehandleiding laat zien hoe u Azure Container Apps configureert om logboeken, traceringen en metrische gegevens door te sturen naar New Relic met behulp van de beheerde OpenTelemetry-agent.

Zie Set up OpenTelemetry agents in Azure Container Apps voor meer informatie over de beheerde OpenTelemetry-agent.

In deze handleiding leert u het volgende:

  • Maak een New Relic-gegevensinvoersleutel.
  • Configureer een New Relic OTLP-doel met behulp van Bicep of de Azure-portal.
  • Configureer vereiste omgevingsvariabelen voor apps.
  • Pas configuratie-updates toe op uw bestaande Container Apps-omgeving en -app.
  • Controleer de telemetrie in New Relic.

Prerequisites

  • Een Azure-abonnement waarin u bestaande Azure Container Apps resources kunt bijwerken.
  • Machtigingen voor het wijzigen van de doelresourcegroep en beheerde omgeving.
  • Een New Relic-account.
  • Azure CLI is geïnstalleerd en aangemeld.
  • Azure Container Apps CLI-extensie geïnstalleerd.
az extension add --name containerapp --upgrade

Maak een nieuwe New Relic-invoersleutel

Gebruik de richtlijnen voor het maken van api-sleutels om uw New Relic API-sleutel te maken: New Relic API-sleutels. Kies bij het maken van de sleutel het type Inname - licentiesleutel, omdat dit type wordt gebruikt voor gegevensinname.

Haal de waarde van de inname-licentiesleutel op uit uw account:

  • Ga in New Relic naar API-sleutels.
  • Zoek de Ingest - License-sleutel.
  • Kopieer de sleutelwaarde voor gebruik in de doelconfiguratie.

OpenTelemetry-bestemmingen configureren

Gebruik een van de volgende opties om New Relic te configureren als een OTel-eindpunt in uw Container Apps-omgeving.

Important

Het configureren van een beheerde OpenTelemetry-bestemming produceert niet automatisch telemetrie. Uw toepassing moet al zijn geïnstrueerd om traceringen, metrische gegevens en logboeken te verzenden met behulp van een OpenTelemetry SDK.

CLI-variabelen instellen voor implementatie:

$RESOURCE_GROUP = "<resource-group-name>"
$NEW_RELIC_OTLP_ENDPOINT = "https://otlp.nr-data.net:4318"
$NEW_RELIC_INGEST_KEY = "<new-relic-ingest-license-key>"

Gebruik het New Relic OTLP-basiseindpunt (https://otlp.nr-data.net) met de juiste OTLP-poort:

  • HTTP: 4318
  • gRPC: 4317

Gebruik dit fragment in de resourcestijl van de beheerde omgeving om doelroutering te configureren:

var newRelicDestinationName = 'newrelic'
var newRelicAuthHeaderValue = newRelicIngestKey

@secure()
param newRelicIngestKey string
param newRelicOtlpEndpoint string = 'https://otlp.nr-data.net:4318'
@allowed([
  'http'
  'grpc'
])
param newRelicOtlpProtocol string = 'http'

resource environment 'Microsoft.App/managedEnvironments@2026-03-02-preview' = {
  name: '<managed-environment-name>'
  location: '<region>'
  properties: {
    openTelemetryConfiguration: {
      destinationsConfiguration: {
        otlpConfigurations: [
          {
            name: newRelicDestinationName
            endpoint: newRelicOtlpEndpoint
            protocol: newRelicOtlpProtocol
            insecure: false
            headers: [
              {
                key: 'api-key'
                value: newRelicAuthHeaderValue
              }
            ]
          }
        ]
      }
      tracesConfiguration: {
        destinations: [
          newRelicDestinationName
        ]
      }
      logsConfiguration: {
        destinations: [
          newRelicDestinationName
        ]
      }
      metricsConfiguration: {
        destinations: [
          newRelicDestinationName
        ]
      }
    }
  }
}

Gebruik dit codefragment in de resourcestijl van de app om vereiste omgevingsvariabelen voor apps in te stellen:

resource app 'Microsoft.App/containerApps@2023-05-01' = {
  name: '<container-app-name>'
  location: '<region>'
  properties: {
    managedEnvironmentId: environment.id
    template: {
      containers: [
        {
          name: '<container-name>'
          image: '<image-name>'
          env: [
            {
              name: 'OTEL_SERVICE_NAME'
              value: '<service-name>'
            }
            {
              name: 'OTEL_TRACES_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_METRICS_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_LOGS_EXPORTER'
              value: 'otlp'
            }
          ]
        }
      ]
    }
  }
}

Pas uw Bicep-configuratie toe vanuit de hoofdmap van de repository:

az deployment group create `
  --resource-group $RESOURCE_GROUP `
  --template-file infra/main.bicep `
  --parameters @infra/main.parameters.json `
  --parameters newRelicOtlpEndpoint="$NEW_RELIC_OTLP_ENDPOINT" `
  --parameters newRelicIngestKey="$NEW_RELIC_INGEST_KEY"

Uw container-app is nu geconfigureerd voor het verzenden van telemetrie naar New Relic.

Telemetrie controleren in New Relic

Controleer na de configuratie of logboeken, traceringen en metrische gegevens binnenkomen vanuit uw toepassing in New Relic en zijn gekoppeld aan de verwachte service-id.

Gebruik de New Relic-ervaringen die passen bij uw werkstroom, zoals gedistribueerde tracering, zoeken in logboeken en het verkennen van metrische gegevens.

Zie de documentatie van New Relic voor meer informatie over verkenning en analyse in New Relic.

  • Last updated on