SharePoint.Contents

Syntaxis

SharePoint.Contents(url as text, optional options as nullable record) as table

Over

Retourneert een hiërarchische tabel met de mappen en bestanden die zijn gevonden op de opgegeven SharePoint site, url. De tabel bevat de items op het huidige niveau en retourneert niet recursief elk bestand op de site. Voor mappen bevat de Content kolom een geneste tabel die kan worden gebruikt om naar de inhoud van de map te navigeren. Voor bestanden bevat de Content kolom de bestandsinhoud als een binaire waarde. Als u een platte tabel wilt retourneren van alle bestanden op de site en de bijbehorende submappen, gebruikt u SharePoint.Files. Elke rij bevat ook de Namekolommen , , Extension, Date accessedDate modified, Date createden AttributesFolder Path kolommen. Maprijen hebben een lege Extension waarde. Date accessed is null voor zowel mappen als bestanden. De Folder Path waarde is de absolute URL van de map die het item bevat. De site-URL kan geen querytekenreeks of fragment bevatten. options kan worden opgegeven om de volgende opties te beheren:

  • ApiVersion: een getal (14 of 15) of de tekst 'Automatisch' waarmee de SharePoint API-versie wordt opgegeven die voor deze site moet worden gebruikt. Wanneer dit niet is opgegeven, wordt API-versie 14 gebruikt. Wanneer Automatisch is opgegeven, wordt de serverversie automatisch gedetecteerd indien mogelijk, anders wordt de versie standaard ingesteld op 14. Voor niet-Engelse SharePoint-sites is minimaal versie 15 vereist.
  • Implementation: optioneel. Hiermee geeft u op welke versie van de SharePoint-connector moet worden gebruikt. Geaccepteerde waarden zijn 2.0 of null. Als de waarde 2.0 is, wordt de 2.0-implementatie van de SharePoint-connector gebruikt. Als de waarde null is, wordt de oorspronkelijke implementatie van de SharePoint-connector gebruikt.

Voor SharePoint.Contentsde oorspronkelijke implementatie worden ApiVersion waarden 14, 15 en "Auto". Als ApiVersion dit niet is opgegeven, wordt versie 14 gebruikt. Bij implementatie 2.0 ApiVersion hoeft u niet op te geven omdat API-versie 15 automatisch wordt gebruikt. API-versie 14 wordt niet ondersteund met implementation 2.0.

Voorbeeld 1

Retourneer de inhoud op het hoogste niveau SharePoint met behulp van de oorspronkelijke implementatie. Omdat er geen opties zijn opgegeven, wordt API-versie 14 gebruikt.

Usage

SharePoint.Contents("https://contoso.sharepoint.com/sites/Contoso")

Uitvoer

A hierarchical table containing the top-level folders and files in the site.

Voorbeeld 2

Gebruik de oorspronkelijke implementatie met automatische API-selectie om elk .xlsx bestand in de bibliotheek Gedeelde documenten te retourneren. De extensievergelijking is niet hoofdlettergevoelig.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    ExcelWorkbooks = Table.SelectRows(
        SharedDocuments,
        each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
in
    ExcelWorkbooks

Uitvoer

A table containing only the files in the Shared Documents library whose Extension value is .xlsx.

Voorbeeld 3

Gebruik implementation 2.0 om de onmiddellijke inhoud van de map Rapporten in de bibliotheek Gedeelde documenten te retourneren. Implementation 2.0 maakt standaard gebruik van API-versie 15.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content]
in
    Reports

Uitvoer

A hierarchical table containing the immediate folders and files in the Reports folder.

Voorbeeld 4

Hiermee wordt de binaire inhoud van Budget.xlsx geretourneerd door de hiërarchische inhoud van de site te navigeren.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content],
    Budget = Reports{[Name = "Budget.xlsx"]}[Content]
in
    Budget

Uitvoer

The binary content of Budget.xlsx.

  • Laatst bijgewerkt om