Notatka
Dostęp do tej strony wymaga autoryzacji. Może spróbować zalogować się lub zmienić katalogi.
Dostęp do tej strony wymaga autoryzacji. Możesz spróbować zmienić katalogi.
Narzędzie Terraform umożliwia definiowanie, wyświetlanie wersji zapoznawczej i wdrażanie infrastruktury chmury. Za pomocą narzędzia Terraform tworzysz pliki konfiguracji przy użyciu składni HCL. Składnia listy HCL umożliwia określenie dostawcy chmury — takiego jak platforma Azure — oraz elementów tworzących infrastrukturę chmury. Po utworzeniu plików konfiguracji utworzysz plan wykonywania , który umożliwia wyświetlenie podglądu zmian infrastruktury przed ich wdrożeniem. Po zweryfikowaniu zmian należy zastosować plan wykonywania w celu wdrożenia infrastruktury.
Moduł AzAPI w wersji 2.0 lub nowszej zawiera zestaw funkcji provider do konstruowania i analizowania identyfikatorów zasobów Azure. Funkcje dostawcy są uruchamiane w czasie planowania w ramach konfiguracji programu Terraform i nie wymagają wyszukiwania źródła danych ani wywołania sieciowego. Zmniejszają złożoność kodu, gdy konfiguracja musi konstruować lub rozkładać identyfikatory zasobów.
Note
Funkcje dostawcy wymagają wersji Terraform 1.8 lub nowszej.
Dostępne funkcje dostawcy
| Function | Opis |
|---|---|
build_resource_id |
Tworzy identyfikator zasobu z identyfikatora nadrzędnego, typu zasobu i nazwy zasobu. Obsługuje zarówno zasoby najwyższego poziomu, jak i zagnieżdżone. |
extension_resource_id |
Tworzy identyfikator zasobu rozszerzenia z podstawowego identyfikatora zasobu, typu zasobu i nazw zasobów. |
management_group_resource_id |
Tworzy identyfikator zasobu dla grupy zarządzania. |
parse_resource_id |
Analizuje identyfikator zasobu Azure na jego składowe części (identyfikator subskrypcji, nazwa grupy zasobów, przestrzeń nazw dostawcy, nazwa zasobu i inne). |
resource_group_resource_id |
Tworzy identyfikator zasobu w zakresie grupy zasobów przy użyciu identyfikatora subskrypcji, nazwy grupy zasobów, typu zasobu i nazw zasobów. |
subscription_resource_id |
Tworzy identyfikator zasobu o zakresie subskrypcji. |
tenant_resource_id |
Tworzy identyfikator zasobu o zakresie dzierżawy. |
Wymagania wstępne
- Subskrypcja platformy Azure: jeśli nie masz subskrypcji platformy Azure, przed rozpoczęciem utwórz bezpłatne konto.
Skonfiguruj program Terraform: jeśli jeszcze tego nie zrobiono, skonfiguruj program Terraform przy użyciu jednej z następujących opcji:
Upewnij się, że konfiguracja deklaruje moduł AzAPI w wersji 2.0 lub nowszej oraz program Terraform 1.8 lub nowszy:
terraform {
required_version = ">= 1.8"
required_providers {
azapi = {
source = "Azure/azapi"
version = "~> 2.0"
}
azurerm = {
source = "hashicorp/azurerm"
version = "~> 4.0"
}
}
}
provider "azurerm" {
features {}
}
provider "azapi" {}
Analizowanie identyfikatora zasobu za pomocą elementu parse_resource_id
Użyj parse_resource_id, aby zdekompilować istniejący identyfikator zasobu Azure do poszczególnych składników. Funkcja jest przydatna, gdy potrzebujesz identyfikatora subskrypcji, nazwy grupy zasobów lub nazwy zasobu z zasobu zarządzanego w innym miejscu konfiguracji lub przekazanego jako zmienna.
locals {
storage_id_parts = provider::azapi::parse_resource_id(
"Microsoft.Storage/storageAccounts",
azurerm_storage_account.example.id
)
}
output "subscription_id" {
value = local.storage_id_parts.subscription_id
}
output "resource_group_name" {
value = local.storage_id_parts.resource_group_name
}
output "storage_account_name" {
value = local.storage_id_parts.name
}
Funkcja zwraca obiekt z następującymi polami:
-
id— pełny identyfikator zasobu -
name— nazwa zasobu -
parent_id— identyfikator zasobu nadrzędnego -
parts— mapa wszystkich segmentów identyfikatorów zasobów -
provider_namespace(na przykładMicrosoft.Storage) resource_group_nameresource_group_idsubscription_id-
type(na przykładMicrosoft.Storage/storageAccounts)
Konstruowanie identyfikatora o zakresie grupy zasobów za pomocą polecenia resource_group_resource_id
Użyj resource_group_resource_id polecenia , jeśli musisz odwołać się do identyfikatora zasobu, który nie jest zarządzany w programie Terraform (na przykład istniejący zasób przekazany jako zmienna) lub gdy chcesz utworzyć przewidywalny identyfikator przed utworzeniem zasobu.
variable "subscription_id" {
type = string
}
variable "existing_resource_group" {
type = string
}
variable "existing_storage_account" {
type = string
}
locals {
storage_account_id = provider::azapi::resource_group_resource_id(
var.subscription_id,
var.existing_resource_group,
"Microsoft.Storage/storageAccounts",
[var.existing_storage_account]
)
}
# Reference the pre-existing storage account without a data source lookup
resource "azapi_resource_action" "regenerate_key" {
type = "Microsoft.Storage/storageAccounts@2023-01-01"
resource_id = local.storage_account_id
action = "regenerateKey"
method = "POST"
body = {
keyName = "key1"
}
}
Parametr nazw zasobów akceptuje listę w celu obsługi zagnieżdżonych typów zasobów. Na przykład aby utworzyć identyfikator podsieci:
locals {
subnet_id = provider::azapi::resource_group_resource_id(
var.subscription_id,
var.resource_group_name,
"Microsoft.Network/virtualNetworks/subnets",
[var.vnet_name, var.subnet_name]
)
}
Skonstruuj identyfikator o zakresie subskrypcji za pomocą subscription_resource_id
Użyj subscription_resource_id dla zasobów o określonym zakresie na poziomie subskrypcji, takich jak grupy zasobów lub przypisania zasad:
locals {
resource_group_id = provider::azapi::subscription_resource_id(
var.subscription_id,
"Microsoft.Resources/resourceGroups",
[var.resource_group_name]
)
}
Utwórz identyfikator w zakresie grupy zarządzania za pomocą management_group_resource_id
Użyj management_group_resource_id dla zasobów w zakresie grupy zarządzania, takich jak przypisania zasad i przypisania ról.
locals {
mg_policy_id = provider::azapi::management_group_resource_id(
var.management_group_name,
"Microsoft.Authorization/policyAssignments",
[var.policy_assignment_name]
)
}
Skonstruuj identyfikator zasobu rozszerzenia z extension_resource_id
Użyj extension_resource_id dla zasobów rozszerzeń, które są dołączone do innego zasobu, takich jak blokady lub przypisania ról w odniesieniu do konkretnego zasobu:
locals {
lock_id = provider::azapi::extension_resource_id(
azurerm_storage_account.example.id,
"Microsoft.Authorization/locks",
[var.lock_name]
)
}
Tworzenie identyfikatora zasobu za pomocą polecenia build_resource_id
Użyj build_resource_id , gdy identyfikator zasobu nadrzędnego określa zakres i nie musisz oddzielnie określać subskrypcji ani grupy zasobów. Ta funkcja wywnioskuje zakres z identyfikatora nadrzędnego:
locals {
subnet_id = provider::azapi::build_resource_id(
azurerm_virtual_network.example.id,
"Microsoft.Network/virtualNetworks/subnets",
var.subnet_name
)
}
Porównaj z podejściami źródeł danych
Funkcje dostawcy są preferowane w przypadku źródeł danych na potrzeby budowy identyfikatorów i analizowania, ponieważ:
- Uruchamiaj całkowicie w czasie planowania bez wywołań sieciowych.
- Nie dodawaj zasobów do stanu programu Terraform.
- Są deterministyczne i nie wymagają
depends_onporządkowania.
Użyj azapi_resource źródła danych, gdy musisz odczytać właściwości na żywo zasobu, a nie tylko konstruować ani analizować jego identyfikatora.