Tworzenie wizualizacji mapy kształtów w Power BI

Dotyczy:✅ Power BI Desktop i usługa Power BI

Wizualizacja mapy kształtów umożliwia wyświetlanie danych na dowolnym kształcie, które można zdefiniować — kraje, regiony, plany pomieszczeń, wykresy miejsc siedzących lub niestandardowe granice. Kolorowanie każdego obszaru na podstawie danych w celu szybkiego zauważenia wzorców, porównywania wartości między regionami i wyróżniania obszarów wymagających uwagi. Wybierz jedną z wbudowanych map dla typowych regionów, przekaż własne pliki TopoJSON lub GeoJSON albo mapy referencyjne bezpośrednio za pośrednictwem adresu URL.

Tworzenie mapy kształtów

Możesz przetestować kontrolkę Mapa kształtu za pomocą wbudowanych map lub użyć własnej mapy niestandardowej, o ile spełnia ona wymagania opisane w poniższej sekcji o nazwie Użyj map niestandardowych. Wizualizacje mapy kształtów są oparte na mapach, które można znaleźć w Internecie, tworzyć samodzielnie lub konwertować na format TopoJSON lub GeoJSON. Przykłady map niestandardowych to: geograficzne, układy miejsc siedzących, plany pomieszczeń i inne.

Dodaj wizualizację mapy kształtu

1. Otwórz lub utwórz raport w programie Power BI Desktop lub w usłudze Power BI.
2. W okienku Wizualizacje wybierz ikonę Mapa kształtu , aby dodać pustą wizualizację do kanwy.
3. (Opcjonalnie) Zmień rozmiar wizualizacji, aby była wystarczająco duża, aby wyraźnie wyświetlić cieniowanie regionów.

Przykładowe dane do testowania

Aby wypróbować wizualizację mapy kształtów z przykładowymi danymi, możesz dodać ten skrypt TMDL do pustego pliku Power BI Desktop. Ten skrypt tworzy tabelę z stanami USA i stanami australijskimi i terytoriami wraz z losowymi wartościami w celach demonstracyjnych.

createOrReplace

	/// Table listing US states and Australian states and territories with random values, used for map visual demos.
	table Map

		/// Sum of RandomValue from the Map table, used for the map visual demo.
		measure 'Some value' = ```
				
				        SUM(Map[RandomValue])
				```
			formatString: #,0

		column RandomValue
			formatString: 0
			summarizeBy: sum
			isNameInferred
			sourceColumn: [RandomValue]

			annotation SummarizationSetBy = Automatic

		column 'Country or Region'
			dataCategory: Country
			summarizeBy: none
			isNameInferred
			sourceColumn: [Country or Region]

			annotation SummarizationSetBy = Automatic

		column 'State or Territory'
			dataCategory: StateOrProvince
			summarizeBy: none
			isNameInferred
			sourceColumn: [State or Territory]

			annotation SummarizationSetBy = Automatic

		partition Map = calculated
			mode: import
			source = ```
					
					VAR USAStates = 
					    DATATABLE(
					        "Country or Region", STRING,
					        "State or Territory", STRING,
					        {
					            {"USA", "Alabama"},
					            {"USA", "Alaska"},
					            {"USA", "Arizona"},
					            {"USA", "Arkansas"},
					            {"USA", "California"},
					            {"USA", "Colorado"},
					            {"USA", "Connecticut"},
					            {"USA", "Delaware"},
					            {"USA", "Florida"},
					            {"USA", "Georgia"},
					            {"USA", "Hawaii"},
					            {"USA", "Idaho"},
					            {"USA", "Illinois"},
					            {"USA", "Indiana"},
					            {"USA", "Iowa"},
					            {"USA", "Kansas"},
					            {"USA", "Kentucky"},
					            {"USA", "Louisiana"},
					            {"USA", "Maine"},
					            {"USA", "Maryland"},
					            {"USA", "Massachusetts"},
					            {"USA", "Michigan"},
					            {"USA", "Minnesota"},
					            {"USA", "Mississippi"},
					            {"USA", "Missouri"},
					            {"USA", "Montana"},
					            {"USA", "Nebraska"},
					            {"USA", "Nevada"},
					            {"USA", "New Hampshire"},
					            {"USA", "New Jersey"},
					            {"USA", "New Mexico"},
					            {"USA", "New York"},
					            {"USA", "North Carolina"},
					            {"USA", "North Dakota"},
					            {"USA", "Ohio"},
					            {"USA", "Oklahoma"},
					            {"USA", "Oregon"},
					            {"USA", "Pennsylvania"},
					            {"USA", "Rhode Island"},
					            {"USA", "South Carolina"},
					            {"USA", "South Dakota"},
					            {"USA", "Tennessee"},
					            {"USA", "Texas"},
					            {"USA", "Utah"},
					            {"USA", "Vermont"},
					            {"USA", "Virginia"},
					            {"USA", "Washington"},
					            {"USA", "West Virginia"},
					            {"USA", "Wisconsin"},
					            {"USA", "Wyoming"}
					        }
					    )
					VAR AustraliaStates = 
					    DATATABLE(
					        "Country", STRING,
					        "State", STRING,
					        {
					            {"Australia", "New South Wales"},
					            {"Australia", "Victoria"},
					            {"Australia", "Queensland"},
					            {"Australia", "Western Australia"},
					            {"Australia", "South Australia"},
					            {"Australia", "Tasmania"},
					            {"Australia", "Northern Territory"},
					            {"Australia", "Australian Capital Territory"}
					        }
					    )
					VAR AllStates = UNION(USAStates, AustraliaStates)
					RETURN
					    ADDCOLUMNS(
					        AllStates,
					        "RandomValue", RANDBETWEEN(1000, 1000000)
					    )
					```

Tworzenie mapy kształtów

1. Wybierz pustą wizualizację mapy kształtów.

2. W panelu Dane przeciągnij pole geograficzne do pola Lokalizacja (na przykład stan, region lub okręg).

   Wskazówka

   Kolumnę można oznaczyć jako geograficzną, ustawiając właściwość Kategoria danych podczas edytowania modelu semantycznego.

3. Przeciągnij miarę liczbową (na przykład Sprzedaż, Populacja) do obszaru Nasycenie koloru.

4. Po wybraniu wizualizacji w okienku Wizualizacje wybierz pozycję Formatuj wizualizację i rozwiń pozycję Ustawienia mapy.

5. Wybierz typ mapy (na przykład Włochy, Meksyk, USA) z listy rozwijanej.

6. Aby wyświetlić klucze mapy aktualnie wybranej mapy, wybierz pozycję Wyświetl klucz typu mapy.

7. Wybierz sposób wyświetlania obiektu trójwymiarowego (ziemi) jako mapy dwuwymiarowej przy użyciu listy rozwijanej Projekcja .

   • Równokątne: projekcja walcowa, która konwertuje globus na siatkę z każdą prostokątną komórką o takim samym rozmiarze, kształcie i obszarze.
   • Mercator: Projekcja walcowa z równikiem przedstawiona jako linia tangencji. Obszary polarne są bardziej zniekształcone niż projekcje równoczesne.
   • Orthographic: Projekcja z nieskończonego punktu, jakby z głębokiej przestrzeni. Daje to iluzję trójwymiarowego świata.

   Aby uzyskać bardziej szczegółowe informacje, zobacz Esri map projections reference.

8. (Opcjonalnie) Dodaj pole kategorii do legendy , aby sklasyfikować regiony mapy według kategorii.

9. (Opcjonalnie) W okienku Wizualizacje rozwiń węzeł Kolory , aby dostosować paletę i inne ustawienia kolorów.

Korzystanie z map niestandardowych

Możesz użyć wbudowanych typów map lub własnej mapy niestandardowej, o ile spełnia wymagania opisane w temacie Ładowanie mapy niestandardowej. Wizualizacje mapy kształtów są oparte na mapach, które można znaleźć, utworzyć lub przekonwertować na format TopoJSON lub GeoJSON (na przykład: regiony geograficzne, układy miejsc siedzących, plany pomieszczeń).

Ładowanie mapy niestandardowej

Mapę niestandardową można załadować, przekazując plik lub podając adres URL.

Przekazywanie pliku mapy

1. Dodaj lub wybierz wizualizację mapy kształtu.
2. W okienku Wizualizacje wybierz pozycję Formatuj wizualizację i rozwiń pozycję Ustawienia mapy.
3. W Typ mapy wybierz Mapę niestandardową.
4. Wybierz pozycję Dodaj typ mapy.
5. Przejdź do pliku topojson lub geojson i wybierz go, a następnie wybierz pozycję Otwórz.
6. (Opcjonalnie) Wybierz pozycję Wyświetl klucz typu mapy , aby sprawdzić, czy nazwy regionów lub identyfikatory są zgodne z wartościami pól Lokalizacja .

Dodawanie mapy z adresu URL

Możesz również odwołać się do pliku mapy hostowanego w trybie online:

1. Dodaj lub wybierz wizualizację mapy kształtu.
2. W okienku Wizualizacje wybierz pozycję Formatuj wizualizację i rozwiń pozycję Ustawienia mapy.
3. W polu Typ wybierz pozycję Adres URL.
4. Wklej adres URL do pliku TopoJSON lub GeoJSON do wprowadź adres URL lub użyj przycisku Fx , aby wskazać miarę zawierającą adres URL.

Takie podejście jest przydatne, gdy chcesz udostępnić mapę wielu raportom lub użyć mapy hostowanej w centralnej lokalizacji.

Pobieranie i edytowanie mapy niestandardowej

Jeśli wcześniej przesłałeś(-aś) niestandardową mapę i chcesz wprowadzić zmiany, możesz ją pobrać:

1. Wybierz wizualizację Mapy kształtów używającą mapy niestandardowej.
2. Otwórz okienko Format i rozszerz Ustawienia mapy.
3. Wybierz pozycję Pobierz mapę.
4. Edytuj pobrany plik zgodnie z potrzebami przy użyciu edytora tekstów lub narzędzia GIS.
5. Przekaż zaktualizowany plik, wykonując kroki opisane w temacie Przekazywanie pliku mapy.

Przykładowa mapa niestandardowa

Biura Prokuratorów Stanów Zjednoczonych publikują coroczny raport za rok budżetowy dotyczący prowadzonych przez nie postępowań sądowych oraz danych dotyczących liczby prowadzonych spraw. Przekonwertujemy niektóre dane regionalne na pliki .json i dodamy je do tego przykładowego pliku PBIX.

Pokaz niestandardowej mapy kształtów. Plik PBIX

Jeśli chcesz eksperymentować z mapami niestandardowymi, pobierz ten plik PBIX i postępuj zgodnie z instrukcjami.

1. W programie Power BI Desktop wybierz pozycję Plik > Otwórz raport.
2. Ponieważ stany można podzielić na wiele okręgów, należy użyć mapy niestandardowego kształtu dla tych okręgów. Importując mapę TopoJSON okręgów sądowych USA do programu Power BI Desktop, możesz zwizualizować roczne dane prokuratora okręgowego.

Obsługiwane formaty mapy

Mapa kształtu obsługuje dwa formaty plików mapy:

• TopoJSON: rozszerzenie pliku GeoJSON, które koduje topologię. Pliki TopoJSON są zwykle mniejsze niż pliki GeoJSON, ponieważ granice udostępnione są przechowywane tylko raz.
• GeoJSON: otwarty standardowy format kodowania struktur danych geograficznych.

Oba formaty współpracują z Shape map. Użyj formatu TopoJSON, aby uzyskać mniejsze pliki, lub GeoJSON, jeśli taki format generują Twoje narzędzia do tworzenia map.

Opcje formatowania kolorów

Sekcja Kolory w opcjach formatowania wizualizacji dostosowuje się na podstawie konfiguracji danych:

• Tylko położenie: ustaw kolory za pomocą formatowania warunkowego lub indywidualnie dla każdego regionu.
• Lokalizacja i legenda: ustaw oddzielny kolor dla każdej wartości legendy.
• Nasycenie kolorów: wybierz kolory gradientu na podstawie wartości w polu Nasycenie koloru.

Możesz również dostosować kolor pustego obszaru dla regionów, które nie pasują do danych, i dostosować kolor i grubość obramowania .

Przykład: Kolory gradientu według regionu

Jeśli używasz tylko pola Lokalizacja (bez pól Legenda i Nasycenie koloru), możesz użyć formatowania warunkowego z miarą DAX, aby uzyskać efekt gradientu w obrębie każdego regionu. Poniższa miara oblicza kod koloru szesnastkowego na podstawie łącznej sprzedaży, przy czym każdy region korzysta z własnej palety kolorów. Stany o wyższej sprzedaży wydają się bardziej nasycone, podczas gdy stany o niższej sprzedaży wydają się lżejsze.

Region Gradient Color = 
VAR ScaleWithinRegion = TRUE
VAR CurrentSales = [Total Sales]

VAR ScopeMin =
    IF (
        ScaleWithinRegion,
        CALCULATE (
            MINX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALLEXCEPT ( StateRegion, StateRegion[Region] )
        ),
        CALCULATE (
            MINX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALL ( StateRegion )
        )
    )

VAR ScopeMax =
    IF (
        ScaleWithinRegion,
        CALCULATE (
            MAXX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALLEXCEPT ( StateRegion, StateRegion[Region] )
        ),
        CALCULATE (
            MAXX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALL ( StateRegion )
        )
    )

VAR Ratio =
    DIVIDE ( CurrentSales - ScopeMin, ScopeMax - ScopeMin )

VAR Region = SELECTEDVALUE ( StateRegion[Region] )

VAR EndR = SWITCH ( Region,
    "Northwest", 17,  "Northeast", 216, "Southeast", 116,
    "Southwest", 224, "Alaska", 17,     "Hawaii", 17,    128 )
VAR EndG = SWITCH ( Region,
    "Northwest", 141, "Northeast", 106, "Southeast", 78,
    "Southwest", 68,  "Alaska", 141,    "Hawaii", 141,   128 )
VAR EndB = SWITCH ( Region,
    "Northwest", 255, "Northeast", 44,  "Southeast", 194,
    "Southwest", 68,  "Alaska", 255,    "Hawaii", 255,   128 )

VAR TintStrength = 0.15
VAR StartR = 255 - ( 255 - EndR ) * TintStrength
VAR StartG = 255 - ( 255 - EndG ) * TintStrength
VAR StartB = 255 - ( 255 - EndB ) * TintStrength

VAR R01 = MIN ( 1, MAX ( 0, Ratio ) )

VAR R = INT ( StartR + ( EndR - StartR ) * R01 )
VAR G = INT ( StartG + ( EndG - StartG ) * R01 )
VAR B = INT ( StartB + ( EndB - StartB ) * R01 )

VAR HexChars = "0123456789ABCDEF"
VAR Hex =
    "#" &
    MID ( HexChars, QUOTIENT ( R, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( R, 16 ) + 1, 1 ) &
    MID ( HexChars, QUOTIENT ( G, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( G, 16 ) + 1, 1 ) &
    MID ( HexChars, QUOTIENT ( B, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( B, 16 ) + 1, 1 )

RETURN
    IF ( ISBLANK ( CurrentSales ), "#FFFFFF", Hex )

Aby użyć tej miary:

1. Dodaj miarę do modelu semantycznego.
2. W wizualizacji Mapy kształtów dodaj swoje pole lokalizacji do pola Lokalizacja.
3. W okienku Formatowania rozwiń Kolory>Lokalizacja.
4. Wybierz przycisk Fx obok pozycji Domyślne.
5. Ustaw Styl formatu na Wartość pola i wybierz miarę Region Gradient Color.

Każdy stan jest wyświetlany z intensywnością koloru na podstawie poziomu swojej sprzedaży w porównaniu z innymi stanami w tym samym regionie.

Pobieranie danych mapy

Aby szybko uzyskać dane do modelu w celu przetestowania mapy kształtów, skopiuj jedną z tabel na końcu tego artykułu, a następnie wybierz pozycję Wprowadź dane na wstążce Narzędzia główne.

Górny wiersz jest automatycznie identyfikowany jako nagłówek. Wprowadź nową kolumnę, wpisując nową nazwę kolumny w pustej kolumnie po prawej stronie. Dodaj wartości w każdej komórce tak samo jak w programie Excel. Po zakończeniu wybierz pozycję Załaduj. Tabela jest dodawana do modelu danych.

Uwagi i ograniczenia

Podczas korzystania z mapy kształtów należy wziąć pod uwagę następujące kwestie:

• Aby klasyfikacja Legenda działała prawidłowo, pole Nasycenie koloru musi być ustawione.
• Wizualizacja mapy kształtów wykreśli maksymalnie 1500 punktów danych.

Klucze regionów

Użyj następujących kluczy regionów , aby przetestować mapę kształtów.

Australia: Stany

Austria: Państwa

Brazylia: Stany

Kanada: prowincje

Francja: Regiony

Niemcy: Stany

Irlandia: Hrabstwa

Włochy: Regiony

Meksyk: Stany

Holandia: prowincje

Wielka Brytania: Kraje/regiony

USA: Stany

Treści powiązane

• Wizualizacje mapy w usłudze Power BI
• Mapy wypełnione (choropleths) w Power BI
• Porady i wskazówki dotyczące wizualizacji map
• Formatowanie warunkowe w usłudze Power BI
• Typy wizualizacji w usłudze Power BI