SharePoint.Contents

Składnia

SharePoint.Contents(url as text, optional options as nullable record) as table

Informacje

Zwraca tabelę hierarchiczną zawierającą foldery i pliki znalezione w określonej lokacji SharePoint. url Tabela przedstawia elementy na bieżącym poziomie i nie zwraca cyklicznie każdego pliku w witrynie. W przypadku folderów kolumna Content zawiera zagnieżdżona tabelę, która może służyć do przechodzenia do zawartości folderu. W przypadku plików kolumna Content zawiera zawartość pliku jako wartość binarną. Aby zwrócić płaską tabelę wszystkich plików w witrynie i jej podfolderach, użyj polecenia SharePoint.Files. Każdy wiersz zawiera Namerównież kolumny , , Date modifiedDate createdAttributesExtensionDate accessed, i .Folder Path Wiersze folderów mają pustą Extension wartość. Date accessed jest null przeznaczony zarówno dla folderów, jak i plików. Wartość Folder Path jest bezwzględnym adresem URL folderu, który zawiera element. Adres URL witryny nie może zawierać ciągu zapytania ani fragmentu. options można określić w celu kontrolowania następujących opcji:

  • ApiVersion: liczba (14 lub 15) lub tekst "Auto", który określa wersję interfejsu API programu SharePoint do użycia dla tej witryny. Jeśli nie określono wersji API, używana jest wersja 14. Po określeniu opcji Auto wersja serwera zostanie automatycznie odnaleziona, jeśli to możliwe, w przeciwnym razie zostanie ustawiona domyślna wersja na 14. Witryny programu SharePoint inne niż angielskie wymagają co najmniej wersji 15.
  • Implementation: opcjonalne. Określa, która wersja łącznika programu SharePoint ma być używana. Zaakceptowane wartości to "2.0" lub null. Jeśli wartość to "2.0", zostanie użyta implementacja łącznika programu SharePoint w wersji 2.0. Jeśli wartość ma wartość null, zostanie użyta oryginalna implementacja łącznika programu SharePoint.

W przypadku SharePoint.Contentselementu oryginalna implementacja obsługuje ApiVersion wartości 14, 15 i "Auto". Jeśli ApiVersion nie zostanie określony, używana jest wersja 14. W przypadku implementacji 2.0 nie trzeba określać, ApiVersion ponieważ interfejs API w wersji 15 jest używany automatycznie. Interfejs API w wersji 14 nie jest obsługiwany z implementacją 2.0.

Przykład 1

Zwróć zawartość SharePoint najwyższego poziomu przy użyciu oryginalnej implementacji. Ponieważ nie określono żadnych opcji, używany jest interfejs API w wersji 14.

Użycie

SharePoint.Contents("https://contoso.sharepoint.com/sites/Contoso")

Output

A hierarchical table containing the top-level folders and files in the site.

Przykład 2

Użyj oryginalnej implementacji z automatycznym wyborem interfejsu API, aby zwrócić każdy .xlsx plik w bibliotece Dokumenty udostępnione. Porównanie rozszerzeń jest bez uwzględniania wielkości liter.

Użycie

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    ExcelWorkbooks = Table.SelectRows(
        SharedDocuments,
        each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
in
    ExcelWorkbooks

Output

A table containing only the files in the Shared Documents library whose Extension value is .xlsx.

Przykład 3

Użyj implementacji 2.0, aby zwrócić natychmiastową zawartość folderu Raporty w bibliotece Dokumentów udostępnionych. Implementacja 2.0 domyślnie używa interfejsu API w wersji 15.

Użycie

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content]
in
    Reports

Output

A hierarchical table containing the immediate folders and files in the Reports folder.

Przykład 4

Zwróć zawartość binarną Budget.xlsx, przechodząc do hierarchicznej zawartości witryny.

Użycie

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content],
    Budget = Reports{[Name = "Budget.xlsx"]}[Content]
in
    Budget

Output

The binary content of Budget.xlsx.

  • Last updated on