Exportar o OpenTelemetry New Relic em Aplicativos de Contêiner do Azure

Este guia de configuração mostra como configurar Aplicativos de Contêiner do Azure para encaminhar logs, rastreamentos e métricas para o New Relic usando o agente OpenTelemetry gerenciado.

Para obter mais informações sobre o agente OpenTelemetry gerenciado, consulte Configurar agentes do OpenTelemetry no Aplicativos de Contêiner do Azure.

Neste guia, você aprenderá a:

  • Crie uma nova chave de ingestão do New Relic.
  • Configure um destino OTLP do New Relic usando Bicep ou o portal do Azure.
  • Configure as variáveis de ambiente de aplicativo necessárias.
  • Aplique atualizações de configuração ao seu ambiente e aplicativo de Aplicativos de Contêiner existentes.
  • Verifique a telemetria em New Relic.

Pré-requisitos

  • Uma assinatura Azure em que você pode atualizar os recursos de Aplicativos de Contêiner do Azure existentes.
  • Permissões para modificar o grupo de recursos de destino e o ambiente gerenciado.
  • Uma nova conta do Relic.
  • CLI do Azure instalada e conectada.
  • Extensão da CLI do Aplicativos de Contêiner do Azure instalada.
az extension add --name containerapp --upgrade

Criar uma nova chave de ingestão do New Relic

Use as orientações para criação de chaves de API para criar sua chave de API do New Relic: Chaves de API do New Relic. Escolha o tipo Ingestão – Chave de Licença ao criar a chave, pois esse tipo é usado para ingestão de dados.

Obtenha o valor da chave de licença de ingestão na sua conta:

  • Em Nova Relíquia, vá para Chaves de API.
  • Encontre a chave Ingest - License.
  • Copie o valor da chave para uso na configuração de destino.

Configurar destinos OpenTelemetry

Use uma das opções a seguir para configurar o New Relic como um endpoint OTel no seu ambiente do Container Apps.

Importante

Configurar um destino OpenTelemetry gerenciado não produz telemetria automaticamente. Seu aplicativo já deve ser instrumentado para emitir rastreamentos, métricas e logs usando um SDK do OpenTelemetry.

Defina variáveis da CLI para implantação:

$RESOURCE_GROUP = "<resource-group-name>"
$NEW_RELIC_OTLP_ENDPOINT = "https://otlp.nr-data.net:4318"
$NEW_RELIC_INGEST_KEY = "<new-relic-ingest-license-key>"

Use o ponto de extremidade base do New Relic OTLP (https://otlp.nr-data.net) com a porta OTLP apropriada:

  • HTTP: 4318
  • gRPC: 4317

Use este trecho de código no estilo de recurso do ambiente gerenciado para configurar o roteamento de destino:

var newRelicDestinationName = 'newrelic'
var newRelicAuthHeaderValue = newRelicIngestKey

@secure()
param newRelicIngestKey string
param newRelicOtlpEndpoint string = 'https://otlp.nr-data.net:4318'
@allowed([
  'http'
  'grpc'
])
param newRelicOtlpProtocol string = 'http'

resource environment 'Microsoft.App/managedEnvironments@2026-03-02-preview' = {
  name: '<managed-environment-name>'
  location: '<region>'
  properties: {
    openTelemetryConfiguration: {
      destinationsConfiguration: {
        otlpConfigurations: [
          {
            name: newRelicDestinationName
            endpoint: newRelicOtlpEndpoint
            protocol: newRelicOtlpProtocol
            insecure: false
            headers: [
              {
                key: 'api-key'
                value: newRelicAuthHeaderValue
              }
            ]
          }
        ]
      }
      tracesConfiguration: {
        destinations: [
          newRelicDestinationName
        ]
      }
      logsConfiguration: {
        destinations: [
          newRelicDestinationName
        ]
      }
      metricsConfiguration: {
        destinations: [
          newRelicDestinationName
        ]
      }
    }
  }
}

Use este snippet no estilo de recurso do aplicativo para definir as variáveis de ambiente de aplicativo necessárias:

resource app 'Microsoft.App/containerApps@2023-05-01' = {
  name: '<container-app-name>'
  location: '<region>'
  properties: {
    managedEnvironmentId: environment.id
    template: {
      containers: [
        {
          name: '<container-name>'
          image: '<image-name>'
          env: [
            {
              name: 'OTEL_SERVICE_NAME'
              value: '<service-name>'
            }
            {
              name: 'OTEL_TRACES_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_METRICS_EXPORTER'
              value: 'otlp'
            }
            {
              name: 'OTEL_LOGS_EXPORTER'
              value: 'otlp'
            }
          ]
        }
      ]
    }
  }
}

Aplique sua configuração do Bicep a partir da raiz do repositório:

az deployment group create `
  --resource-group $RESOURCE_GROUP `
  --template-file infra/main.bicep `
  --parameters @infra/main.parameters.json `
  --parameters newRelicOtlpEndpoint="$NEW_RELIC_OTLP_ENDPOINT" `
  --parameters newRelicIngestKey="$NEW_RELIC_INGEST_KEY"

Seu Aplicativo de Contêiner agora está configurado para enviar telemetria para o New Relic.

Verifique a telemetria em New Relic

Após a configuração, verifique se os logs, rastreamentos e métricas estão chegando do aplicativo em New Relic e estão associados à identidade de serviço esperada.

Use as experiências do New Relic que se ajustam ao fluxo de trabalho, como rastreamento distribuído, pesquisa de logs e exploração de métricas.

Para obter mais informações sobre exploração e análise no New Relic, consulte a documentação do New Relic.

  • Last updated on