Configuração típica do projeto lakebase com o Terraform

Importante

O suporte ao Terraform para Lakebase está em Beta.

Esta página mostra uma configuração completa do Terraform para um projeto Lakebase pronto para produção com os recursos mais comumente usados:

  • Ramificação de produção protegida
  • Ponto de extremidade de leitura e gravação de alta disponibilidade (HA) com secundários legíveis
  • Entidade de serviço com DATABRICKS_SUPERUSER privilégios de banco de dados
  • Banco de dados Postgres de propriedade do aplicativo
  • Banco de dados Postgres registrado no Unity Catalog para consultas do Lakehouse Federation no Databricks SQL e em notebooks
  • Streaming contínuo de tabela sincronizada no Unity Catalog
  • Aplicativo Databricks conectado ao projeto lakebase

Para obter uma introdução passo a passo ao Terraform com o Lakebase, consulte Introdução ao Terraform para Lakebase.

Pré-requisitos

Antes de começar, você deverá ter o seguinte:

Concluir a configuração

Quando você cria um projeto, o Azure Databricks cria automaticamente uma production ramificação, um endpoint de leitura e gravação primary, uma função de proprietário do Postgres vinculada à sua identidade e um banco de dados databricks_postgres. Para configurar esses recursos criados implicitamente, declare-os no Terraform com replace_existing = true. Para obter mais detalhes, consulte databricks_postgres_branch, databricks_postgres_endpoint, databricks_postgres_rolee databricks_postgres_database.

Warning

Essa configuração define is_protected = true no ramo production e inclui uma variável unprotect_for_destroy integrada à especificação do ramo. O Terraform não pode excluir um projeto com branches protegidas, e a branch production não pode ser excluída diretamente porque o ciclo de vida dela é controlado pelo projeto. Para destruir os recursos de forma limpa, use uma destruição em duas etapas:

# Step 1: unprotect the branch
terraform apply -var="unprotect_for_destroy=true"

# Step 2: destroy all resources
terraform destroy -var="unprotect_for_destroy=true"

Após executar terraform destroy, o projeto é excluído temporariamente e retido por 7 dias antes de ser excluído permanentemente. Para excluí-lo imediatamente de forma permanente, defina purge_on_delete = true no recurso databricks_postgres_project antes de executar destroy.

variable "admin_sp_app_id" {
  description = "Application ID of the service principal to grant admin access"
  type        = string
}

variable "unprotect_for_destroy" {
  description = "Set to true before destroy to unprotect the production branch"
  type        = bool
  default     = false
}

# Project — top-level container for branches, endpoints, databases, and roles.
resource "databricks_postgres_project" "this" {
  project_id = "my-lakebase-project"
  # purge_on_delete = true  # Uncomment to permanently delete on destroy (default: soft delete, 7-day retention).
  spec = {
    pg_version   = 17
    display_name = "My Lakebase Project"
    default_endpoint_settings = {
      autoscaling_limit_min_cu = 0.5
      autoscaling_limit_max_cu = 4.0
      suspend_timeout_duration = "300s"
    }
  }
}

# Configure the implicitly created production branch as protected.
resource "databricks_postgres_branch" "production" {
  branch_id = "production"
  parent    = databricks_postgres_project.this.name
  spec = {
    no_expiry    = true
    is_protected = var.unprotect_for_destroy ? false : true
  }
  replace_existing = true
}

# Configure the implicitly created primary endpoint with HA.
# HA requires no_suspension = true. group.min = 2 adds a standby for automatic failover.
resource "databricks_postgres_endpoint" "primary" {
  endpoint_id = "primary"
  parent      = databricks_postgres_branch.production.name
  spec = {
    endpoint_type            = "ENDPOINT_TYPE_READ_WRITE"
    autoscaling_limit_min_cu = 0.5
    autoscaling_limit_max_cu = 4.0
    no_suspension            = true
    group = {
      min                         = 2
      max                         = 2
      enable_readable_secondaries = true
    }
  }
  replace_existing = true
}

# Grant workspace-level CAN_MANAGE on the project to the service principal.
# Use status.project_id (bare ID) not .name (full resource path) — the permissions
# API rejects the full path with a "resource type not found" error.
resource "databricks_permissions" "project" {
  database_project_name = databricks_postgres_project.this.status.project_id
  access_control {
    service_principal_name = var.admin_sp_app_id
    permission_level       = "CAN_MANAGE"
  }
}

# Create a Postgres role backed by the service principal with full database privileges.
# depends_on serializes creation — Lakebase processes one branch operation at a time.
resource "databricks_postgres_role" "admin_sp" {
  role_id = "admin-sp"
  parent  = databricks_postgres_branch.production.name
  spec = {
    identity_type    = "SERVICE_PRINCIPAL"
    postgres_role    = var.admin_sp_app_id
    auth_method      = "LAKEBASE_OAUTH_V1"
    membership_roles = ["DATABRICKS_SUPERUSER"]
    attributes = {
      createdb   = true
      createrole = true
      bypassrls  = true
    }
  }
  depends_on = [databricks_postgres_endpoint.primary]
}

# Create a Postgres database owned by the admin SP role.
resource "databricks_postgres_database" "app" {
  database_id = "app"
  parent      = databricks_postgres_branch.production.name
  spec = {
    postgres_database = "app"
    role              = databricks_postgres_role.admin_sp.name
  }
}

# Register the Postgres database in Unity Catalog. This makes the database queryable
# from Databricks SQL and notebooks through Lakehouse Federation, and serves as the
# parent namespace for synced tables that live inside the Lakebase Catalog.
# create_database_if_missing is set explicitly because the database is managed by
# the databricks_postgres_database resource above.
resource "databricks_postgres_catalog" "app_catalog" {
  catalog_id = "app_catalog"
  spec = {
    postgres_database          = databricks_postgres_database.app.status.postgres_database
    branch                     = databricks_postgres_branch.production.name
    create_database_if_missing = false
  }
}

# Sync a Unity Catalog Delta table into the Lakebase database continuously.
# Prefixing synced_table_id with the Lakebase Catalog name places the synced table
# inside the catalog so it's discoverable alongside the rest of the catalog's contents.
# postgres_database references the catalog's status, which implicitly orders this
# resource after the catalog without an explicit depends_on.
resource "databricks_postgres_synced_table" "orders" {
  synced_table_id = "app_catalog.default.orders_synced"
  spec = {
    branch                             = databricks_postgres_branch.production.name
    postgres_database                  = databricks_postgres_catalog.app_catalog.status.postgres_database
    source_table_full_name             = "my_catalog.default.orders"
    primary_key_columns                = ["order_id"]
    scheduling_policy                  = "CONTINUOUS"
    create_database_objects_if_missing = true
    new_pipeline_spec = {
      storage_catalog = "my_catalog"
      storage_schema  = "default"
    }
  }
}

# Databricks App connected to the Lakebase project.
# database must be the full resource name (databricks_postgres_database.app.name),
# not the Postgres database name. permission must be "CAN_CONNECT_AND_CREATE".
resource "databricks_app" "this" {
  name        = "my-lakebase-app"
  description = "App backed by Lakebase autoscaling project"
  depends_on  = [databricks_postgres_database.app]
  resources = [{
    name = "lakebase-db"
    postgres = {
      branch     = databricks_postgres_branch.production.name
      database   = databricks_postgres_database.app.name
      permission = "CAN_CONNECT_AND_CREATE"
    }
  }]
}

Note

Essa configuração cria uma função separada (admin_sp) e um banco de dados (app) em vez de gerenciar a função de proprietário implícita e databricks_postgres o banco de dados. Para colocar esses recursos implícitos sob o gerenciamento do Terraform, em vez disso, declare-os usando replace_existing = true com seus IDs existentes. A ID do banco de dados é sempre databricks-postgres. O ID da função é derivada da identidade que criou a ramificação: a parte do email anterior @ (caracteres não alfanuméricos em letras minúsculas substituídas por hifens) para um usuário ou sp-<application-id> para uma entidade de serviço. Se você não tiver certeza do valor exato, obtenha-o no aplicativo Lakebase ou na API do Postgres, em vez de calculá-lo manualmente.

spec.membership_roles substitui as associações da função em cada aplicação em vez de mesclar com elas. Mantenha DATABRICKS_SUPERUSER na lista; deixá-lo de fora remove todas as associações dessa função.

resource "databricks_postgres_role" "owner" {
  role_id = "jane-doe" # normalized login of the creating identity
  parent  = databricks_postgres_branch.production.name
  spec = {
    postgres_role    = "jane.doe@databricks.com" # the raw login
    membership_roles = ["DATABRICKS_SUPERUSER"]
    attributes = {
      createdb   = true
      createrole = true
      bypassrls  = true
    }
  }
  replace_existing = true
}

resource "databricks_postgres_database" "databricks_postgres" {
  database_id = "databricks-postgres"
  parent      = databricks_postgres_branch.production.name
  spec = {
    postgres_database = "databricks_postgres"
    # spec.role is omitted, so the database keeps its existing owner.
  }
  replace_existing = true
}

Recursos adicionais

  • Last updated on